xref: /openbmc/phosphor-power/meson.build (revision 328ca312) 
1project(
2    'phosphor-power',
3    'cpp',
4    default_options: [
5        'warning_level=3',
6        'werror=true',
7        'cpp_std=c++23',
8        'buildtype=debugoptimized',
9        'prefix=/usr'
10    ],
11    license: 'Apache-2.0',
12    version: '1.0',
13    meson_version: '>=1.1.1',
14)
15
16cxx = meson.get_compiler('cpp')
17
18build_tests = get_option('tests')
19
20if get_option('oe-sdk').enabled()
21  # Setup OE SYSROOT
22  OECORE_TARGET_SYSROOT = run_command('sh', '-c', 'echo $OECORE_TARGET_SYSROOT').stdout().strip()
23  if OECORE_TARGET_SYSROOT == ''
24    error('Unable to get $OECORE_TARGET_SYSROOT, check your environment.')
25  endif
26  message('OE_SYSROOT: ' + OECORE_TARGET_SYSROOT)
27  rpath = ':'.join([OECORE_TARGET_SYSROOT + '/lib', OECORE_TARGET_SYSROOT + '/usr/lib'])
28  ld_so = run_command('sh', '-c', 'find ' + OECORE_TARGET_SYSROOT + '/lib/ld-*.so | sort -r -n | head -n1').stdout().strip()
29  dynamic_linker = ['-Wl,-dynamic-linker,' + ld_so]
30else
31  dynamic_linker = []
32endif
33
34
35gmock = dependency('gmock', disabler: true, required: build_tests)
36gtest = dependency('gtest', main: true, disabler: true, required: build_tests)
37phosphor_dbus_interfaces = dependency('phosphor-dbus-interfaces')
38phosphor_logging = dependency('phosphor-logging')
39prog_python = import('python').find_installation('python3')
40sdbusplus = dependency('sdbusplus')
41sdbuspp = find_program('sdbus++')
42sdeventplus = dependency('sdeventplus')
43pthread = dependency('threads')
44stdplus = dependency('stdplus')
45boost = dependency('boost')
46fmt = dependency('fmt')
47libgpiodcxx = dependency('libgpiodcxx',
48    default_options: ['bindings=cxx'])
49
50if cxx.has_header('nlohmann/json.hpp')
51    nlohmann_json_dep = declare_dependency()
52else
53    subproject('nlohmann', required: false)
54    nlohmann_json_dep = declare_dependency(
55        include_directories: [
56            'subprojects/nlohmann-json/single_include',
57            'subprojects/nlohmann-json/single_include/nlohmann',
58        ]
59    )
60endif
61
62if cxx.has_header('CLI/CLI.hpp')
63    cli11_dep = declare_dependency()
64else
65    cli11_dep = dependency('CLI11')
66endif
67
68systemd = dependency('systemd')
69servicedir = systemd.get_variable('systemdsystemunitdir')
70
71services = [
72    ['supply-monitor', 'power-supply-monitor@.service'],
73    ['sequencer-monitor', 'pseq-monitor-pgood.service'],
74    ['sequencer-monitor', 'pseq-monitor.service'],
75    ['supply-monitor-ng', 'phosphor-psu-monitor.service'],
76    ['regulators', 'phosphor-regulators.service'],
77    ['regulators', 'phosphor-regulators-config.service'],
78    ['regulators', 'phosphor-regulators-monitor-enable.service'],
79    ['regulators', 'phosphor-regulators-monitor-disable.service'],
80    ['power-control', 'phosphor-power-control.service'],
81]
82
83foreach service : services
84    if get_option(service[0])
85        configure_file(input: 'services/' + service[1],
86                 output: service[1],
87                 copy: true,
88                 install_dir: servicedir)
89    endif
90endforeach
91
92# Get the power sequencer class name
93sequencer = get_option('power_sequencer')
94if sequencer == 'ucd90160'
95    sequencer_class = 'UCD90160'
96elif sequencer == 'mihawk-cpld'
97    sequencer_class = 'MihawkCPLD'
98else
99    # power sequencer is incorrect
100    error('power sequencer is incorrect')
101endif
102
103conf = configuration_data()
104conf.set_quoted(
105    'INPUT_HISTORY_BUSNAME_ROOT', get_option('input-history-busname-root'))
106conf.set_quoted(
107    'INPUT_HISTORY_SENSOR_ROOT', get_option('input-history-sensor-root'))
108conf.set_quoted(
109    'INPUT_HISTORY_SYNC_GPIO', get_option('input-history-sync-gpio'))
110conf.set_quoted(
111    'PSU_JSON_PATH', '/usr/share/phosphor-power/psu.json')
112conf.set(
113    'SEQUENCER', sequencer_class)
114conf.set10(
115    'DEVICE_ACCESS', get_option('device-access'))
116conf.set10('IBM_VPD', get_option('ibm-vpd'))
117
118configure_file(output: 'config.h', configuration: conf)
119
120# Ensure the generated header here winds up in the correct path in the build
121# tree such that it actually get used and doesn't get found in the sysroot
122# somewhere.  Meson doesn't allow path elements (rightfully so) when specifying
123# the output filename of a target definition so the target must be defined in
124# the directory where the artifacts need to be placed.  Do that now, because
125# the generated source (cpp) is needed to define the library target.
126subdir('org/open_power/Witherspoon/Fault')
127
128libpower = static_library(
129    'power',
130    error_cpp,
131    error_hpp,
132    'gpio.cpp',
133    'pmbus.cpp',
134    'utility.cpp',
135    dependencies: [
136        nlohmann_json_dep,
137        phosphor_dbus_interfaces,
138        phosphor_logging,
139        sdbusplus,
140        sdeventplus,
141    ],
142)
143
144libpower_inc = include_directories('.')
145
146# Build the tools/i2c sub-directory first.  Other sub-directories depend on
147# Meson variables defined there.
148subdir('tools/i2c')
149
150if get_option('regulators')
151    subdir('phosphor-regulators')
152endif
153if get_option('sequencer-monitor')
154    subdir('power-sequencer')
155endif
156if get_option('power-control')
157    subdir('phosphor-power-sequencer')
158endif
159if get_option('supply-monitor')
160    subdir('power-supply')
161endif
162if get_option('supply-monitor-ng')
163    subdir('phosphor-power-supply')
164endif
165if get_option('utils')
166    subdir('tools/power-utils')
167endif
168if get_option('tests').enabled()
169    subdir('test')
170endif
171if get_option('cold-redundancy')
172    subdir('cold-redundancy')
173endif
174