xref: /openbmc/phosphor-power/meson.build (revision 13e03339) 
1project(
2    'phosphor-power',
3    'cpp',
4    default_options: [
5        'warning_level=3',
6        'werror=true',
7        'cpp_std=c++17',
8        'prefix=/usr'
9    ],
10    license: 'Apache-2.0',
11    version: '1.0',
12)
13
14build_tests = get_option('tests')
15
16if get_option('oe-sdk').enabled()
17  # Setup OE SYSROOT
18  OECORE_TARGET_SYSROOT = run_command('sh', '-c', 'echo $OECORE_TARGET_SYSROOT').stdout().strip()
19  if OECORE_TARGET_SYSROOT == ''
20    error('Unable to get $OECORE_TARGET_SYSROOT, check your environment.')
21  endif
22  message('OE_SYSROOT: ' + OECORE_TARGET_SYSROOT)
23  rpath = ':'.join([OECORE_TARGET_SYSROOT + '/lib', OECORE_TARGET_SYSROOT + '/usr/lib'])
24  ld_so = run_command('sh', '-c', 'find ' + OECORE_TARGET_SYSROOT + '/lib/ld-*.so | sort -r -n | head -n1').stdout().strip()
25  dynamic_linker = ['-Wl,-dynamic-linker,' + ld_so]
26else
27  dynamic_linker = []
28endif
29
30
31cppfs = meson.get_compiler('cpp').find_library('stdc++fs')
32gmock = dependency('gmock', disabler: true, required: build_tests)
33gtest = dependency('gtest', main: true, disabler: true, required: build_tests)
34phosphor_dbus_interfaces = dependency('phosphor-dbus-interfaces')
35phosphor_logging = dependency('phosphor-logging')
36prog_python = import('python').find_installation('python3')
37sdbusplus = dependency('sdbusplus')
38sdbuspp = find_program('sdbus++')
39sdeventplus = dependency('sdeventplus')
40pthread = dependency('threads')
41stdplus = dependency('stdplus')
42boost = dependency('boost')
43
44systemd = dependency('systemd')
45servicedir = systemd.get_pkgconfig_variable('systemdsystemunitdir')
46
47services = [
48    ['supply-monitor', 'power-supply-monitor@.service'],
49    ['sequencer-monitor', 'pseq-monitor-pgood.service'],
50    ['sequencer-monitor', 'pseq-monitor.service'],
51    ['supply-monitor-ng', 'phosphor-psu-monitor.service'],
52    ['regulators', 'phosphor-regulators.service'],
53    ['regulators', 'phosphor-regulators-config.service'],
54    ['regulators', 'phosphor-regulators-monitor-enable.service'],
55    ['regulators', 'phosphor-regulators-monitor-disable.service'],
56]
57
58foreach service : services
59    if get_option(service[0])
60        configure_file(input: 'services/' + service[1],
61                 output: service[1],
62                 copy: true,
63                 install_dir: servicedir)
64    endif
65endforeach
66
67# Get the power sequencer class name
68sequencer = get_option('power_sequencer')
69if sequencer == 'ucd90160'
70    sequencer_class = 'UCD90160'
71elif sequencer == 'mihawk-cpld'
72    sequencer_class = 'MihawkCPLD'
73else
74    # power sequencer is incorrect
75    error('power sequencer is incorrect')
76endif
77
78conf = configuration_data()
79conf.set_quoted(
80    'INPUT_HISTORY_BUSNAME_ROOT', get_option('input-history-busname-root'))
81conf.set_quoted(
82    'INPUT_HISTORY_SENSOR_ROOT', get_option('input-history-sensor-root'))
83conf.set_quoted(
84    'PSU_JSON_PATH', '/usr/share/phosphor-power/psu.json')
85conf.set(
86    'SEQUENCER', sequencer_class)
87conf.set10(
88    'DEVICE_ACCESS', get_option('device-access'))
89conf.set10('IBM_VPD', get_option('ibm-vpd'))
90
91configure_file(output: 'config.h', configuration: conf)
92
93# Ensure the generated header here winds up in the correct path in the build
94# tree such that it actually get used and doesn't get found in the sysroot
95# somewhere.  Meson doesn't allow path elements (rightfully so) when specifying
96# the output filename of a target definition so the target must be defined in
97# the directory where the artifacts need to be placed.  Do that now, because
98# the generated source (cpp) is needed to define the library target.
99subdir('org/open_power/Witherspoon/Fault')
100
101libpower = static_library(
102    'power',
103    error_cpp,
104    error_hpp,
105    'gpio.cpp',
106    'pmbus.cpp',
107    'utility.cpp',
108    dependencies: [
109        cppfs,
110        phosphor_dbus_interfaces,
111        phosphor_logging,
112        sdbusplus,
113        sdeventplus,
114    ],
115)
116
117libpower_inc = include_directories('.')
118
119# Build the tools/i2c sub-directory first.  Other sub-directories depend on
120# Meson variables defined there.
121subdir('tools/i2c')
122
123if get_option('regulators')
124    subdir('phosphor-regulators')
125endif
126if get_option('sequencer-monitor')
127    subdir('power-sequencer')
128endif
129if get_option('supply-monitor')
130    subdir('power-supply')
131endif
132if get_option('supply-monitor-ng')
133    subdir('phosphor-power-supply')
134endif
135if get_option('utils')
136    subdir('tools/power-utils')
137endif
138if get_option('tests').enabled()
139    subdir('test')
140endif
141if get_option('cold-redundancy')
142    subdir('cold-redundancy')
143endif
144