1gtest = dependency('gtest', main: true, disabler: true, required: false)
2gmock = dependency('gmock', disabler: true, required: false)
3if not gtest.found() or not gmock.found()
4  gtest_opts = import('cmake').subproject_options()
5  gtest_opts.add_cmake_defines({'CMAKE_CXX_FLAGS': '-Wno-pedantic'})
6  gtest_proj = import('cmake').subproject(
7    'googletest',
8    options: gtest_opts,
9    required: false)
10  if gtest_proj.found()
11    gtest = declare_dependency(
12      dependencies: [
13        dependency('threads'),
14        gtest_proj.dependency('gtest'),
15        gtest_proj.dependency('gtest_main'),
16      ])
17    gmock = gtest_proj.dependency('gmock')
18  else
19    assert(not get_option('tests').enabled(), 'Googletest is required')
20  endif
21endif
22
23test_headers = include_directories('.')
24
25test_deps = [
26  meson.get_compiler('cpp').find_library('dl'),
27  networkd_dep,
28  gtest,
29  gmock,
30  dependency('stdplus-gtest'),
31]
32
33test_lib = static_library(
34  'networkd-test',
35  'mock_syscall.cpp',
36  implicit_include_directories: false,
37  include_directories: test_headers,
38  dependencies: test_deps)
39
40test_dep = declare_dependency(
41  dependencies: test_deps,
42  include_directories: test_headers,
43  link_with: test_lib)
44
45tests = [
46  'config_parser',
47  'ethernet_interface',
48  'netlink',
49  'network_manager',
50  'rtnetlink',
51  'types',
52  'util',
53]
54
55run_with_tmp = find_program('run_with_tmp', native: true)
56
57add_test_setup(
58  'networkd',
59  exe_wrapper: run_with_tmp,
60  env: {'TMPTMPL': 'phosphor-networkd-test.XXXXXXXXXX'},
61  is_default: true)
62
63add_test_setup(
64  'valgrind',
65  exe_wrapper: [run_with_tmp, 'valgrind'],
66  env: {'TMPTMPL': 'phosphor-networkd-test.XXXXXXXXXX'})
67
68foreach t : tests
69  test(
70    t,
71    executable(
72      t.underscorify(),
73      'test_' + t + '.cpp',
74      implicit_include_directories: false,
75      dependencies: test_dep))
76endforeach
77
78if (get_option('hyp-nw-config') == true)
79  subdir('ibm/hypervisor-network-mgr-test')
80endif
81