xref: /openbmc/phosphor-networkd/meson.build (revision a6c07570) 
1project(
2  'phosphor-networkd',
3  'cpp',
4  version: '0.1',
5  meson_version: '>=0.57.0',
6  default_options: [
7    'warning_level=3',
8    'cpp_std=c++20',
9  ])
10
11default_busname = 'xyz.openbmc_project.Network'
12
13conf_data = configuration_data()
14conf_data.set_quoted('DEFAULT_BUSNAME', default_busname)
15conf_data.set('HAVE_UBOOT_ENV', get_option('uboot-env'))
16conf_data.set(
17  'LINK_LOCAL_AUTOCONFIGURATION',
18  get_option('default-link-local-autoconf'))
19conf_data.set(
20  'ENABLE_IPV6_ACCEPT_RA',
21  get_option('default-ipv6-accept-ra'))
22conf_data.set('NIC_SUPPORTS_ETHTOOL', get_option('nic-ethtool'))
23conf_data.set('SYNC_MAC_FROM_INVENTORY', get_option('sync-mac'))
24conf_data.set('PERSIST_MAC', get_option('persist-mac'))
25
26sdbusplus_dep = dependency('sdbusplus')
27sdbusplusplus_prog = find_program('sdbus++', native: true)
28sdbuspp_gen_meson_prog = find_program('sdbus++-gen-meson', native: true)
29
30generated_sources = []
31generated_others = []
32yaml_sources = []
33subdir('gen')
34subdir('gen/xyz')
35networkd_dbus_includes = include_directories('gen')
36
37phosphor_dbus_interfaces_dep = dependency('phosphor-dbus-interfaces')
38
39networkd_dbus_deps = [
40  phosphor_dbus_interfaces_dep,
41  sdbusplus_dep,
42]
43
44networkd_dbus_lib = static_library(
45  'networkd_dbus',
46  generated_sources,
47  implicit_include_directories: false,
48  include_directories: networkd_dbus_includes,
49  dependencies: networkd_dbus_deps)
50
51generated_files_headers = []
52foreach s : generated_sources
53    foreach f : s.to_list()
54        p = f.full_path()
55        if p.endswith('.hpp')
56            generated_files_headers += f
57        endif
58    endforeach
59endforeach
60
61networkd_dbus_dep = declare_dependency(
62  sources: generated_files_headers,
63  include_directories: networkd_dbus_includes,
64  link_with: networkd_dbus_lib,
65  dependencies: networkd_dbus_deps)
66
67subdir('src')
68
69configure_file(
70  input: 'xyz.openbmc_project.Network.service.in',
71  output: 'xyz.openbmc_project.Network.service',
72  configuration: {
73    'SYSTEMD_TARGET': 'multi-user.target',
74    'DEFAULT_BUSNAME': default_busname,
75  },
76  install: true,
77  install_dir: dependency('systemd').get_variable(
78    pkgconfig: 'systemdsystemunitdir'))
79
80configure_file(
81  input: 'xyz.openbmc_project.Network.conf.in',
82  output: 'xyz.openbmc_project.Network.conf',
83  configuration: {'DEFAULT_BUSNAME': default_busname},
84  install: true,
85  install_dir: get_option('datadir') / 'dbus-1' / 'system.d')
86
87if not get_option('tests').disabled()
88  subdir('test')
89endif
90