xref: /openbmc/phosphor-led-manager/meson.build (revision 9bd334ff17997965f1be66e75471e3256880d5b6) 
1project(
2    'phosphor-ledmanager', 'cpp',
3    version : '1.0.0',
4    meson_version: '>=0.57.0',
5    default_options: [
6        'warning_level=3',
7        'werror=true',
8        'cpp_std=c++20',
9        'buildtype=debugoptimized',
10    ]
11)
12
13conf_data = configuration_data()
14conf_data.set_quoted('BUSNAME', 'xyz.openbmc_project.LED.GroupManager')
15conf_data.set_quoted('OBJPATH', '/xyz/openbmc_project/led/groups')
16conf_data.set_quoted('LED_JSON_FILE', '/usr/share/phosphor-led-manager/led-group-config.json')
17conf_data.set_quoted('SAVED_GROUPS_FILE', '/var/lib/phosphor-led-manager/savedGroups')
18conf_data.set_quoted('CALLOUT_FWD_ASSOCIATION', 'callout')
19conf_data.set_quoted('CALLOUT_REV_ASSOCIATION', 'fault')
20conf_data.set_quoted('ELOG_ENTRY', 'entry')
21conf_data.set_quoted('LED_FAULT', 'fault')
22
23conf_data.set('CLASS_VERSION', 1)
24conf_data.set('LED_USE_JSON', get_option('use-json').enabled())
25conf_data.set('USE_LAMP_TEST', get_option('use-lamp-test').enabled())
26conf_data.set('MONITOR_OPERATIONAL_STATUS', get_option('monitor-operational-status').enabled())
27
28sdbusplus_dep = dependency('sdbusplus')
29
30sdeventplus_dep = dependency(
31    'sdeventplus',
32    fallback: [
33        'sdeventplus',
34        'sdeventplus_dep'
35    ],
36)
37phosphor_logging_dep = dependency(
38    'phosphor-logging',
39    fallback: [
40        'phosphor-logging',
41        'phosphor_logging_dep'
42    ],
43)
44phosphor_dbus_interfaces_dep = dependency(
45    'phosphor-dbus-interfaces',
46    fallback: [
47        'phosphor-dbus-interfaces',
48        'phosphor_dbus_interfaces_dep'
49    ],
50)
51prog_python = find_program('python3', required: true)
52realpath_prog = find_program('realpath')
53
54cpp = meson.get_compiler('cpp')
55if cpp.has_header('nlohmann/json.hpp')
56    nlohmann_json_dep = declare_dependency()
57else
58    subproject('nlohmann', required: false)
59    nlohmann_json_dep = declare_dependency(
60        include_directories: [
61            'subprojects/nlohmann/single_include',
62            'subprojects/nlohmann/single_include/nlohmann',
63        ]
64    )
65endif
66
67# Get Cereal dependency.
68cereal_dep = dependency('cereal', required: false)
69has_cereal = cpp.has_header_symbol(
70    'cereal/cereal.hpp',
71    'cereal::specialize',
72    dependencies: cereal_dep,
73    required: false)
74if not has_cereal
75    cereal_opts = import('cmake').subproject_options()
76    cereal_opts.add_cmake_defines({'BUILD_TESTS': 'OFF'})
77    cereal_proj = import('cmake').subproject(
78        'cereal',
79        options: cereal_opts,
80        required: false)
81    assert(cereal_proj.found(), 'cereal is required')
82    cereal_dep = cereal_proj.dependency('cereal')
83endif
84
85deps = [
86    sdbusplus_dep,
87    sdeventplus_dep,
88    phosphor_logging_dep,
89    phosphor_dbus_interfaces_dep,
90    nlohmann_json_dep,
91    cereal_dep,
92]
93
94sources = [
95    'group.cpp',
96    'led-main.cpp',
97    'manager.cpp',
98    'serialize.cpp',
99    'utils.cpp',
100]
101
102if get_option('use-json').disabled()
103    led_gen_hpp = custom_target(
104        'led-gen.hpp',
105        command : [
106            prog_python,
107            meson.project_source_root() + '/parse_led.py',
108            '-i', meson.project_source_root(),
109            '-o', meson.current_build_dir(),
110        ],
111        output : 'led-gen.hpp')
112    sources += [led_gen_hpp]
113endif
114
115if get_option('use-lamp-test').enabled()
116    conf_data.set_quoted('LAMP_TEST_OBJECT', '/xyz/openbmc_project/led/groups/lamp_test')
117    conf_data.set_quoted('HOST_LAMP_TEST_OBJECT', '/xyz/openbmc_project/led/groups/host_lamp_test')
118    conf_data.set_quoted('LAMP_TEST_LED_OVERRIDES_JSON', '/usr/share/phosphor-led-manager/lamp-test-led-overrides.json')
119    conf_data.set('LAMP_TEST_TIMEOUT_IN_SECS', 240)
120
121    sources += ['lamptest.cpp']
122endif
123
124configure_file(output: 'config.h',
125    configuration: conf_data
126)
127
128install_data(
129    'scripts/led-set-all-groups-asserted.sh',
130    install_dir: get_option('bindir')
131)
132
133executable(
134    'phosphor-ledmanager',
135    sources,
136    implicit_include_directories: true,
137    dependencies: deps,
138    install: true,
139    install_dir: get_option('bindir')
140)
141subdir('fault-monitor')
142
143build_tests = get_option('tests')
144if not build_tests.disabled()
145  subdir('test')
146endif
147
148install_subdir('configs',
149    install_dir: get_option('datadir') / 'phosphor-led-manager',
150    strip_directory: true)
151