1ipmid_pre = [
2  boost_coroutine,
3  phosphor_dbus_interfaces_dep,
4  phosphor_logging_dep,
5  sdbusplus_dep,
6  systemd,
7]
8
9entity_map_json_lib = static_library(
10  'entity_map_json',
11  'entity_map_json.cpp',
12  include_directories: root_inc,
13  dependencies: [nlohmann_json_dep, sdbusplus_dep],
14  implicit_include_directories: false)
15
16entity_map_json_dep = declare_dependency(link_with: entity_map_json_lib)
17
18libipmid = library(
19  'ipmid',
20  'sdbus-asio.cpp',
21  'signals.cpp',
22  'systemintf-sdbus.cpp',
23  'utils.cpp',
24  dependencies: [ipmid_pre, entity_map_json_dep],
25  version: meson.project_version(),
26  include_directories: root_inc,
27  install: true,
28  install_dir: get_option('libdir'),
29  override_options: ['b_lundef=false'])
30
31ipmid_dep = declare_dependency(
32  dependencies: ipmid_pre,
33  include_directories: root_inc,
34  link_with: libipmid)
35
36import('pkgconfig').generate(
37  libipmid,
38  name: 'libipmid',
39  version: meson.project_version(),
40  description: 'ipmid')
41