1project('phosphor-dbus-interfaces', 'cpp',
2    meson_version: '>= 0.57.0',
3    default_options: [
4        'buildtype=debugoptimized',
5        'cpp_std=c++20',
6        'warning_level=3',
7        'werror=true',
8    ],
9    version: '1.0.0',
10)
11
12# Get sdbusplus dependency.
13sdbusplus_dep = dependency('sdbusplus', required: false)
14if sdbusplus_dep.found()
15    sdbusplusplus_prog = find_program('sdbus++')
16    sdbuspp_gen_meson_prog = find_program('sdbus++-gen-meson')
17else
18    sdbusplus_proj = subproject('sdbusplus', required: true)
19    sdbusplus_dep = sdbusplus_proj.get_variable('sdbusplus_dep')
20    sdbusplusplus_prog = sdbusplus_proj.get_variable('sdbusplusplus_prog')
21    sdbuspp_gen_meson_prog = sdbusplus_proj.get_variable(
22        'sdbuspp_gen_meson_prog'
23    )
24endif
25
26realpath_prog = find_program('realpath')
27
28# Parse options to determine appropriate subdirectories to support.
29selected_subdirs = []
30if get_option('data_com_ibm')
31    selected_subdirs += 'com/ibm'
32endif
33if get_option('data_org_open_power')
34    selected_subdirs += 'org/open_power'
35endif
36if get_option('data_xyz_openbmc_project')
37    selected_subdirs += 'xyz/openbmc_project'
38endif
39
40# Install the selected YAML files.
41inst_yaml_dir = get_option('datadir') / 'phosphor-dbus-yaml/yaml'
42foreach d : selected_subdirs
43    install_subdir(
44        d,
45        install_dir: inst_yaml_dir / d,
46        strip_directory: true,
47    )
48endforeach
49
50# If libphosphor_dbus was not enabled, exit out from here.  We installed
51# the YAML which is all we are asked to do.
52if not get_option('libphosphor_dbus')
53    subdir_done()
54endif
55
56generated_root = meson.current_build_dir() / 'gen'
57generated_sources = []
58generated_others = []
59yaml_sources = []
60
61# Source the generated meson files.
62subdir('gen')
63foreach d : selected_subdirs
64  subdir('gen' / d)
65endforeach
66
67# Parse through the list from sdbus++-gendir and put into sets.
68generated_headers = []
69generated_cpp = []
70generated_others_files = []
71
72foreach g : generated_sources generated_others
73    foreach f : g.to_list()
74        rel_path = run_command(
75            realpath_prog,
76            '--relative-to', generated_root,
77            f.full_path(),
78        ).stdout().strip().split('\n')[-1]
79
80        if rel_path.endswith('.hpp')
81            generated_headers += rel_path
82        elif rel_path.endswith('.cpp')
83            generated_cpp += rel_path
84        else
85            generated_others_files += rel_path
86        endif
87    endforeach
88endforeach
89
90# Install the generated header files.
91install_subdir(
92    generated_root,
93    exclude_files: [ generated_cpp, generated_others_files ],
94    install_dir: get_option('includedir'),
95    strip_directory: true,
96)
97
98# Install the generated markdown files.
99install_subdir(
100    generated_root,
101    exclude_files: [ generated_headers, generated_cpp ],
102    install_dir: get_option('datadir') / 'doc' / meson.project_name(),
103    strip_directory: true,
104)
105
106# Define and build libphosphor_dbus.so from the C++ files.
107libphosphor_dbus = library(
108    'phosphor_dbus',
109    generated_sources,
110    include_directories: include_directories('gen'),
111    dependencies: sdbusplus_dep,
112    version: meson.project_version(),
113    install: true,
114)
115
116import('pkgconfig').generate(
117    libphosphor_dbus,
118    name: meson.project_name(),
119    version: meson.project_version(),
120    description: 'Generated sdbusplus bindings for phosphor-dbus-interfaces',
121    variables: ['yamldir=' + '${pc_sysrootdir}${prefix}' / inst_yaml_dir],
122)
123
124phosphor_dbus_interfaces_dep = declare_dependency(
125    include_directories: include_directories('gen'),
126    link_with: libphosphor_dbus,
127    dependencies: sdbusplus_dep,
128    variables: ['yamldir=' + meson.project_source_root()],
129)
130