xref: /openbmc/phosphor-buttons/meson.build (revision 395c764c) 
1project(
2    'phosphor-buttons', 'cpp',
3    version: '1.0.0',
4    meson_version: '>=0.58.0',
5    default_options: [
6        'warning_level=3',
7        'werror=true',
8        'cpp_std=c++20',
9    ]
10)
11
12conf_data = configuration_data()
13conf_data.set_quoted('POWER_DBUS_OBJECT_NAME',
14                 '/xyz/openbmc_project/Chassis/Buttons/Power0')
15conf_data.set_quoted('RESET_DBUS_OBJECT_NAME',
16                 '/xyz/openbmc_project/Chassis/Buttons/Reset0')
17conf_data.set_quoted('ID_DBUS_OBJECT_NAME',
18                 '/xyz/openbmc_project/Chassis/Buttons/ID0')
19conf_data.set_quoted('HS_DBUS_OBJECT_NAME',
20                 '/xyz/openbmc_project/Chassis/Buttons/HostSelector')
21conf_data.set_quoted('DBG_HS_DBUS_OBJECT_NAME',
22                 '/xyz/openbmc_project/Chassis/Buttons/DebugHostSelector')
23conf_data.set_quoted('SERIAL_CONSOLE_MUX_DBUS_OBJECT_NAME',
24                 '/xyz/openbmc_project/Chassis/Buttons/SerialUartMux')
25conf_data.set_quoted('GPIO_BASE_LABEL_NAME', '1e780000.gpio')
26conf_data.set_quoted('CHASSIS_STATE_OBJECT_NAME',
27                 '/xyz/openbmc_project/state/chassis')
28conf_data.set_quoted('CHASSISSYSTEM_STATE_OBJECT_NAME',
29                 '/xyz/openbmc_project/state/chassis_system')
30conf_data.set_quoted('HOST_STATE_OBJECT_NAME',
31                 '/xyz/openbmc_project/state/host')
32conf_data.set_quoted('ID_LED_GROUP', get_option('id-led-group'))
33
34conf_data.set('LONG_PRESS_TIME_MS', get_option('long-press-time-ms'))
35conf_data.set('LOOKUP_GPIO_BASE', get_option('lookup-gpio-base').enabled())
36
37configure_file(output: 'config.h',
38    configuration: conf_data
39)
40
41sdbusplus_dep = dependency('sdbusplus')
42phosphor_dbus_interfaces_dep = dependency('phosphor-dbus-interfaces')
43phosphor_logging_dep = dependency('phosphor-logging')
44gpioplus_dep = dependency('gpioplus')
45
46cpp = meson.get_compiler('cpp')
47if cpp.has_header_symbol(
48        'nlohmann/json.hpp',
49        'nlohmann::json::string_t',
50        required:false)
51    nlohmann_json_dep = declare_dependency()
52else
53    nlohmann_json_dep = dependency('nlohmann-json')
54endif
55
56deps = [
57    sdbusplus_dep,
58    phosphor_dbus_interfaces_dep,
59    phosphor_logging_dep,
60    nlohmann_json_dep,
61    gpioplus_dep,
62]
63
64sources_buttons = [
65    'src/gpio.cpp',
66    'src/hostSelector_switch.cpp',
67    'src/debugHostSelector_button.cpp',
68    'src/serial_uart_mux.cpp',
69    'src/id_button.cpp',
70    'src/main.cpp',
71    'src/power_button.cpp',
72    'src/reset_button.cpp',
73]
74
75sources_handler = [
76    'src/button_handler_main.cpp',
77    'src/button_handler.cpp',
78]
79
80executable(
81    'buttons',
82    sources_buttons,
83    implicit_include_directories: true,
84    include_directories: ['inc'],
85    dependencies: deps,
86    install: true,
87    install_dir: get_option('bindir')
88)
89
90executable(
91    'button-handler',
92    sources_handler,
93    implicit_include_directories: true,
94    include_directories: ['inc'],
95    dependencies: deps,
96    install: true,
97    install_dir: get_option('bindir')
98)
99
100systemd = dependency('systemd')
101systemd_system_unit_dir = systemd.get_variable(
102        'systemdsystemunitdir',
103        pkgconfig_define: ['prefix', get_option('prefix')])
104
105configure_file(input: 'service_files/phosphor-button-handler.service',
106                output: 'phosphor-button-handler.service',
107                copy: true,
108                install_dir: systemd_system_unit_dir)
109
110configure_file(input: 'service_files/xyz.openbmc_project.Chassis.Buttons.service',
111                output: 'xyz.openbmc_project.Chassis.Buttons.service',
112                copy: true,
113                install_dir: systemd_system_unit_dir)
114