xref: /openbmc/openpower-proc-control/meson.build (revision bbb53393c5e2eb2ad4d3ef8401f8481732b84ed0) 
1project(
2    'openpower-proc-control',
3    'cpp',
4    default_options: [
5        'warning_level=3',
6        'werror=true',
7        'cpp_std=c++20',
8        'buildtype=debugoptimized',
9        'b_ndebug=if-release',
10    ],
11    license: 'Apache-2.0',
12    version: '1.0',
13    meson_version: '>=0.57.0',
14)
15add_project_arguments('-Wno-psabi', language: 'cpp')
16
17if get_option('cpp_std') != 'c++20'
18    error('This project requires c++20')
19endif
20
21if(get_option('buildtype') == 'minsize')
22    add_project_arguments('-DNDEBUG', language : 'cpp')
23endif
24
25cxx = meson.get_compiler('cpp')
26
27extra_sources = []
28extra_dependencies = []
29extra_unit_files = []
30
31# Configuration header file(config.h) generation
32conf_data = configuration_data()
33
34conf_data.set_quoted('DEVTREE_EXPORT_FILTER_FILE', get_option('DEVTREE_EXPORT_FILTER_FILE'),
35                      description : 'Path to the phal devtree export filter file'
36                    )
37
38conf_data.set_quoted('DEVTREE_EXP_FILE', get_option('DEVTREE_EXP_FILE'),
39                      description : 'Path to the devtree export copy file'
40                    )
41
42conf_data.set_quoted('CEC_DEVTREE_RW_PATH', get_option('CEC_DEVTREE_RW_PATH'),
43                      description : 'Path to the devtree file r/w version'
44                    )
45
46conf_data.set_quoted('CEC_DEVTREE_RO_BASE_PATH', get_option('CEC_DEVTREE_RO_BASE_PATH'),
47                      description : 'Base path to the devtree file read only version'
48                    )
49conf_data.set_quoted('CEC_INFODB_PATH', get_option('CEC_INFODB_PATH'),
50                      description : 'Path to the devtree attributes based database path'
51                    )
52
53conf_data.set_quoted('DEVTREE_REINIT_ATTRS_LIST', get_option('DEVTREE_REINIT_ATTRS_LIST'),
54                      description : 'Path to the phal devtree reinit attribute list file'
55                    )
56
57configure_file(configuration : conf_data,
58               output : 'config.h'
59              )
60
61unit_subs = configuration_data()
62unit_subs.set('bindir', join_paths(get_option('prefix'), get_option('bindir')))
63unit_subs.set('ENABLE_PHAL_TRUE', '#')
64unit_subs.set('CEC_DEVTREE_RW_PATH', get_option('CEC_DEVTREE_RW_PATH'),
65               description : 'Path to the devtree file r/w version'
66             )
67
68if get_option('phal').enabled() and get_option('p9').enabled()
69    error('phal and p9 cannot be selected at the same time')
70endif
71
72build_p9 = not get_option('p9').disabled()
73build_openfsi = not get_option('openfsi').disabled()
74build_phal = get_option('phal').enabled()
75
76if get_option('phal').enabled() and not get_option('p9').disabled()
77    build_p9 = false
78endif
79
80summary('building p9', build_p9)
81summary('building openfsi', build_openfsi)
82summary('building phal', build_phal)
83
84if build_p9
85    extra_sources += [
86        'procedures/p9/cleanup_pcie.cpp',
87        'procedures/p9/set_sync_fsi_clock_mode.cpp',
88        'procedures/p9/start_host.cpp',
89        'procedures/p9/start_host_mpreboot.cpp',
90        'procedures/p9/enter_mpreboot.cpp',
91        'procedures/p9/thread_stopall.cpp',
92    ]
93endif
94if build_openfsi
95    extra_sources += [
96        'procedures/openfsi/scan.cpp',
97    ]
98endif
99if build_phal
100    extra_sources += [
101        'procedures/phal/start_host.cpp',
102        'procedures/phal/set_SPI_mux.cpp',
103        'procedures/phal/proc_pre_poweroff.cpp',
104        'procedures/phal/check_host_running.cpp',
105        'procedures/phal/import_devtree.cpp',
106        'procedures/phal/enter_mpreboot.cpp',
107        'procedures/phal/reinit_devtree.cpp',
108        'procedures/phal/thread_stopall.cpp',
109        'extensions/phal/common_utils.cpp',
110        'extensions/phal/pdbg_utils.cpp',
111        'extensions/phal/create_pel.cpp',
112        'extensions/phal/phal_error.cpp',
113        'extensions/phal/dump_utils.cpp',
114        'temporary_file.cpp',
115    ]
116    extra_dependencies += [
117        dependency('libdt-api'),
118        cxx.find_library('ekb'),
119        cxx.find_library('ipl'),
120        cxx.find_library('phal'),
121        cxx.find_library('dtree'),
122    ]
123    extra_unit_files = [
124        'service_files/set-spi-mux.service',
125        'service_files/phal-reinit-devtree.service',
126        'service_files/proc-pre-poweroff@.service',
127        'service_files/op-reset-host-check@.service',
128        'service_files/op-reset-host-clear.service',
129        'service_files/phal-import-devtree@.service',
130        'service_files/phal-export-devtree@.service',
131    ]
132    unit_subs.set('ENABLE_PHAL_TRUE', '')
133endif
134
135executable(
136    'openpower-proc-control',
137    [
138        'cfam_access.cpp',
139        'ext_interface.cpp',
140        'filedescriptor.cpp',
141        'proc_control.cpp',
142        'targeting.cpp',
143        'procedures/common/cfam_overrides.cpp',
144        'procedures/common/cfam_reset.cpp',
145        'procedures/common/collect_sbe_hb_data.cpp',
146        'util.cpp',
147    ] + extra_sources,
148    dependencies: [
149        dependency('libgpiodcxx'),
150        cxx.find_library('pdbg'),
151        dependency('phosphor-dbus-interfaces'),
152        dependency('phosphor-logging'),
153        dependency('sdbusplus'),
154        dependency('threads'),
155        dependency('fmt'),
156    ] + extra_dependencies,
157    install: true
158)
159
160executable(
161    'openpower-proc-nmi',
162    [
163        'nmi_main.cpp',
164        'nmi_interface.cpp',
165    ],
166    dependencies: [
167        cxx.find_library('pdbg'),
168        dependency('phosphor-dbus-interfaces'),
169        dependency('phosphor-logging'),
170        dependency('sdbusplus'),
171   ],
172   install: true
173)
174
175if build_phal
176    executable(
177        'phal-export-devtree',
178        [
179            'extensions/phal/devtree_export.cpp',
180            'extensions/phal/fw_update_watch.cpp',
181            'extensions/phal/pdbg_utils.cpp',
182            'extensions/phal/create_pel.cpp',
183            'util.cpp',
184        ],
185        dependencies: [
186            dependency('phosphor-logging'),
187            dependency('sdbusplus'),
188            dependency('sdeventplus'),
189            dependency('fmt'),
190            dependency('phosphor-dbus-interfaces'),
191            cxx.find_library('pdbg'),
192            cxx.find_library('phal'),
193       ],
194       install: true
195   )
196endif
197
198unit_files = [
199    'service_files/pcie-poweroff@.service',
200    'service_files/xyz.openbmc_project.Control.Host.NMI.service',
201    'service_files/op-stop-instructions@.service',
202    'service_files/op-cfam-reset.service',
203    'service_files/op-continue-mpreboot@.service',
204    'service_files/op-enter-mpreboot@.service',
205] + extra_unit_files
206
207systemd_system_unit_dir = dependency('systemd').get_pkgconfig_variable(
208    'systemdsystemunitdir',
209    define_variable: ['prefix', get_option('prefix')])
210foreach u : unit_files
211    configure_file(
212        configuration: unit_subs,
213        input: u + '.in',
214        install: true,
215        install_dir: systemd_system_unit_dir,
216        output: '@BASENAME@'
217    )
218endforeach
219
220if not get_option('tests').disabled()
221    test(
222        'utest',
223        executable(
224            'utest',
225            'test/utest.cpp',
226            'targeting.cpp',
227            'filedescriptor.cpp',
228            dependencies: [
229                dependency('gtest', main: true),
230                dependency('phosphor-logging'),
231            ],
232            implicit_include_directories: false,
233            include_directories: '.',
234        )
235    )
236endif
237