1project(
2    'openpower-proc-control',
3    'cpp',
4    default_options: [
5        'warning_level=3',
6        'werror=true',
7        'cpp_std=c++20',
8        'buildtype=debugoptimized',
9        'b_ndebug=if-release',
10    ],
11    license: 'Apache-2.0',
12    version: '1.0',
13    meson_version: '>=0.57.0',
14)
15add_project_arguments('-Wno-psabi', language: 'cpp')
16
17if get_option('cpp_std') != 'c++20'
18    error('This project requires c++20')
19endif
20
21if(get_option('buildtype') == 'minsize')
22    add_project_arguments('-DNDEBUG', language : 'cpp')
23endif
24
25cxx = meson.get_compiler('cpp')
26
27extra_sources = []
28extra_dependencies = []
29extra_unit_files = []
30
31# Configuration header file(config.h) generation
32conf_data = configuration_data()
33
34conf_data.set_quoted('DEVTREE_EXPORT_FILTER_FILE', get_option('DEVTREE_EXPORT_FILTER_FILE'),
35                      description : 'Path to the phal devtree export filter file'
36                    )
37
38conf_data.set_quoted('DEVTREE_EXP_FILE', get_option('DEVTREE_EXP_FILE'),
39                      description : 'Path to the devtree export copy file'
40                    )
41
42configure_file(configuration : conf_data,
43               output : 'config.h'
44              )
45
46unit_subs = configuration_data()
47unit_subs.set('bindir', join_paths(get_option('prefix'), get_option('bindir')))
48unit_subs.set('ENABLE_PHAL_TRUE', '#')
49
50if get_option('phal').enabled() and get_option('p9').enabled()
51    error('phal and p9 cannot be selected at the same time')
52endif
53
54build_p9 = not get_option('p9').disabled()
55build_openfsi = not get_option('openfsi').disabled()
56build_phal = get_option('phal').enabled()
57
58if get_option('phal').enabled() and not get_option('p9').disabled()
59    build_p9 = false
60endif
61
62summary('building p9', build_p9)
63summary('building openfsi', build_openfsi)
64summary('building phal', build_phal)
65
66if build_p9
67    extra_sources += [
68        'procedures/p9/cleanup_pcie.cpp',
69        'procedures/p9/set_sync_fsi_clock_mode.cpp',
70        'procedures/p9/start_host.cpp',
71        'procedures/p9/start_host_mpreboot.cpp',
72        'procedures/p9/enter_mpreboot.cpp',
73    ]
74endif
75if build_openfsi
76    extra_sources += [
77        'procedures/openfsi/scan.cpp',
78    ]
79endif
80if build_phal
81    extra_sources += [
82        'procedures/phal/start_host.cpp',
83        'procedures/phal/set_SPI_mux.cpp',
84        'procedures/phal/proc_pre_poweroff.cpp',
85        'procedures/phal/check_host_running.cpp',
86        'procedures/phal/import_devtree.cpp',
87        'procedures/phal/enter_mpreboot.cpp',
88        'extensions/phal/common_utils.cpp',
89        'extensions/phal/pdbg_utils.cpp',
90        'extensions/phal/create_pel.cpp',
91        'extensions/phal/phal_error.cpp',
92        'extensions/phal/dump_utils.cpp',
93        'temporary_file.cpp',
94    ]
95    extra_dependencies += [
96        dependency('libdt-api'),
97        cxx.find_library('ekb'),
98        cxx.find_library('ipl'),
99        cxx.find_library('phal'),
100    ]
101    extra_unit_files = [
102        'service_files/set-spi-mux.service',
103        'service_files/phal-reinit-devtree.service',
104        'service_files/proc-pre-poweroff@.service',
105        'service_files/op-reset-host-check@.service',
106        'service_files/op-reset-host-clear.service',
107        'service_files/phal-import-devtree@.service',
108        'service_files/phal-export-devtree@.service',
109    ]
110    unit_subs.set('ENABLE_PHAL_TRUE', '')
111endif
112
113executable(
114    'openpower-proc-control',
115    [
116        'cfam_access.cpp',
117        'ext_interface.cpp',
118        'filedescriptor.cpp',
119        'proc_control.cpp',
120        'targeting.cpp',
121        'procedures/common/cfam_overrides.cpp',
122        'procedures/common/cfam_reset.cpp',
123        'procedures/common/collect_sbe_hb_data.cpp',
124        'util.cpp',
125    ] + extra_sources,
126    dependencies: [
127        dependency('libgpiodcxx'),
128        cxx.find_library('pdbg'),
129        dependency('phosphor-dbus-interfaces'),
130        dependency('phosphor-logging'),
131        dependency('sdbusplus'),
132        dependency('threads'),
133        dependency('fmt'),
134    ] + extra_dependencies,
135    install: true
136)
137
138executable(
139    'openpower-proc-nmi',
140    [
141        'nmi_main.cpp',
142        'nmi_interface.cpp',
143    ],
144    dependencies: [
145        cxx.find_library('pdbg'),
146        dependency('phosphor-dbus-interfaces'),
147        dependency('phosphor-logging'),
148        dependency('sdbusplus'),
149   ],
150   install: true
151)
152
153if build_phal
154    executable(
155        'phal-export-devtree',
156        [
157            'extensions/phal/devtree_export.cpp',
158            'extensions/phal/fw_update_watch.cpp',
159            'extensions/phal/pdbg_utils.cpp',
160            'extensions/phal/create_pel.cpp',
161            'util.cpp',
162        ],
163        dependencies: [
164            dependency('phosphor-logging'),
165            dependency('sdbusplus'),
166            dependency('sdeventplus'),
167            dependency('fmt'),
168            dependency('phosphor-dbus-interfaces'),
169            cxx.find_library('pdbg'),
170       ],
171       install: true
172   )
173endif
174
175unit_files = [
176    'service_files/pcie-poweroff@.service',
177    'service_files/xyz.openbmc_project.Control.Host.NMI.service',
178    'service_files/op-stop-instructions@.service',
179    'service_files/op-cfam-reset.service',
180    'service_files/op-continue-mpreboot@.service',
181    'service_files/op-enter-mpreboot@.service',
182] + extra_unit_files
183
184systemd_system_unit_dir = dependency('systemd').get_pkgconfig_variable(
185    'systemdsystemunitdir',
186    define_variable: ['prefix', get_option('prefix')])
187foreach u : unit_files
188    configure_file(
189        configuration: unit_subs,
190        input: u + '.in',
191        install: true,
192        install_dir: systemd_system_unit_dir,
193        output: '@BASENAME@'
194    )
195endforeach
196
197if not get_option('tests').disabled()
198    test(
199        'utest',
200        executable(
201            'utest',
202            'test/utest.cpp',
203            'targeting.cpp',
204            'filedescriptor.cpp',
205            dependencies: [
206                dependency('gtest', main: true),
207                dependency('phosphor-logging'),
208            ],
209            implicit_include_directories: false,
210            include_directories: '.',
211        )
212    )
213endif
214