1project(
2    'openpower-proc-control',
3    'cpp',
4    default_options: [
5        'warning_level=3',
6        'werror=true',
7        'cpp_std=c++17',
8        'buildtype=debugoptimized',
9        'b_ndebug=if-release',
10    ],
11    license: 'Apache-2.0',
12    version: '1.0',
13)
14add_project_arguments('-Wno-psabi', language: 'cpp')
15
16if get_option('cpp_std') != 'c++17'
17    error('This project requires c++17')
18endif
19
20if(get_option('buildtype') == 'minsize')
21    add_project_arguments('-DNDEBUG', language : 'cpp')
22endif
23
24cxx = meson.get_compiler('cpp')
25
26extra_sources = []
27extra_dependencies = []
28extra_unit_files = []
29
30# Configuration header file(config.h) generation
31conf_data = configuration_data()
32
33conf_data.set_quoted('DEVTREE_EXPORT_FILTER_FILE', get_option('DEVTREE_EXPORT_FILTER_FILE'),
34                      description : 'Path to the phal devtree export filter file'
35                    )
36
37conf_data.set_quoted('DEVTREE_EXP_FILE', get_option('DEVTREE_EXP_FILE'),
38                      description : 'Path to the devtree export copy file'
39                    )
40
41configure_file(configuration : conf_data,
42               output : 'config.h'
43              )
44
45unit_subs = configuration_data()
46unit_subs.set('bindir', join_paths(get_option('prefix'), get_option('bindir')))
47unit_subs.set('ENABLE_PHAL_TRUE', '#')
48
49if get_option('phal').enabled() and get_option('p9').enabled()
50    error('phal and p9 cannot be selected at the same time')
51endif
52
53build_p9 = not get_option('p9').disabled()
54build_openfsi = not get_option('openfsi').disabled()
55build_phal = get_option('phal').enabled()
56
57if get_option('phal').enabled() and not get_option('p9').disabled()
58    build_p9 = false
59endif
60
61summary('building p9', build_p9)
62summary('building openfsi', build_openfsi)
63summary('building phal', build_phal)
64
65if build_p9
66    extra_sources += [
67        'procedures/p9/cleanup_pcie.cpp',
68        'procedures/p9/set_sync_fsi_clock_mode.cpp',
69        'procedures/p9/start_host.cpp',
70        'procedures/p9/start_host_mpreboot.cpp',
71    ]
72endif
73if build_openfsi
74    extra_sources += [
75        'procedures/openfsi/scan.cpp',
76    ]
77endif
78if build_phal
79    extra_sources += [
80        'procedures/phal/start_host.cpp',
81        'procedures/phal/set_SPI_mux.cpp',
82        'procedures/phal/proc_pre_poweroff.cpp',
83        'extensions/phal/common_utils.cpp',
84        'extensions/phal/pdbg_utils.cpp',
85        'procedures/phal/check_host_running.cpp',
86        'extensions/phal/create_pel.cpp',
87        'extensions/phal/phal_error.cpp',
88    ]
89    extra_dependencies += [
90        dependency('libdt-api'),
91        cxx.find_library('ekb'),
92        cxx.find_library('ipl'),
93    ]
94    extra_unit_files = [
95        'service_files/set-spi-mux.service',
96        'service_files/phal-reinit-devtree.service',
97        'service_files/proc-pre-poweroff@.service',
98        'service_files/op-reset-host-check@.service',
99        'service_files/op-reset-host-clear.service',
100    ]
101    unit_subs.set('ENABLE_PHAL_TRUE', '')
102endif
103
104executable(
105    'openpower-proc-control',
106    [
107        'cfam_access.cpp',
108        'ext_interface.cpp',
109        'filedescriptor.cpp',
110        'proc_control.cpp',
111        'targeting.cpp',
112        'procedures/common/cfam_overrides.cpp',
113        'procedures/common/cfam_reset.cpp',
114        'procedures/common/enter_mpreboot.cpp',
115        'procedures/common/collect_sbe_hb_data.cpp',
116        'util.cpp',
117    ] + extra_sources,
118    dependencies: [
119        dependency('libgpiodcxx'),
120        cxx.find_library('pdbg'),
121        dependency('phosphor-dbus-interfaces'),
122        dependency('phosphor-logging'),
123        dependency('sdbusplus'),
124        dependency('threads'),
125        dependency('fmt'),
126    ] + extra_dependencies,
127    install: true
128)
129
130executable(
131    'openpower-proc-nmi',
132    [
133        'nmi_main.cpp',
134        'nmi_interface.cpp',
135    ],
136    dependencies: [
137        cxx.find_library('pdbg'),
138        dependency('phosphor-dbus-interfaces'),
139        dependency('phosphor-logging'),
140        dependency('sdbusplus'),
141   ],
142   install: true
143)
144
145if build_phal
146    executable(
147        'phal-export-devtree',
148        [
149            'extensions/phal/devtree_export.cpp',
150            'extensions/phal/fw_update_watch.cpp',
151            'extensions/phal/pdbg_utils.cpp',
152            'extensions/phal/create_pel.cpp',
153            'util.cpp',
154        ],
155        dependencies: [
156            dependency('phosphor-logging'),
157            dependency('sdbusplus'),
158            dependency('sdeventplus'),
159            dependency('fmt'),
160            dependency('phosphor-dbus-interfaces'),
161            cxx.find_library('pdbg'),
162       ],
163       install: true
164   )
165endif
166
167unit_files = [
168    'service_files/pcie-poweroff@.service',
169    'service_files/xyz.openbmc_project.Control.Host.NMI.service',
170    'service_files/op-stop-instructions@.service',
171    'service_files/op-cfam-reset.service',
172    'service_files/op-continue-mpreboot@.service',
173    'service_files/op-enter-mpreboot@.service',
174] + extra_unit_files
175
176systemd_system_unit_dir = dependency('systemd').get_pkgconfig_variable(
177    'systemdsystemunitdir',
178    define_variable: ['prefix', get_option('prefix')])
179foreach u : unit_files
180    configure_file(
181        configuration: unit_subs,
182        input: u + '.in',
183        install: true,
184        install_dir: systemd_system_unit_dir,
185        output: '@BASENAME@'
186    )
187endforeach
188
189if not get_option('tests').disabled()
190    test(
191        'utest',
192        executable(
193            'utest',
194            'test/utest.cpp',
195            'targeting.cpp',
196            'filedescriptor.cpp',
197            dependencies: [
198                dependency('gtest', main: true),
199                dependency('phosphor-logging'),
200            ],
201            implicit_include_directories: false,
202            include_directories: '.',
203        )
204    )
205endif
206