xref: /openbmc/openpower-proc-control/meson.build (revision 04553f30f3fbe896fc04e18dcd34027125994634) 
1project(
2    'openpower-proc-control',
3    'cpp',
4    default_options: [
5        'warning_level=3',
6        'werror=true',
7        'cpp_std=c++17',
8        'buildtype=debugoptimized',
9        'b_ndebug=if-release',
10    ],
11    license: 'Apache-2.0',
12    version: '1.0',
13)
14add_project_arguments('-Wno-psabi', language: 'cpp')
15
16if get_option('cpp_std') != 'c++17'
17    error('This project requires c++17')
18endif
19
20if(get_option('buildtype') == 'minsize')
21    add_project_arguments('-DNDEBUG', language : 'cpp')
22endif
23
24cxx = meson.get_compiler('cpp')
25
26extra_sources = []
27extra_dependencies = []
28extra_unit_files = []
29
30unit_subs = configuration_data()
31unit_subs.set('bindir', join_paths(get_option('prefix'), get_option('bindir')))
32unit_subs.set('ENABLE_PHAL_TRUE', '#')
33
34if get_option('phal').enabled() and get_option('p9').enabled()
35    error('phal and p9 cannot be selected at the same time')
36endif
37
38build_p9 = not get_option('p9').disabled()
39build_openfsi = not get_option('openfsi').disabled()
40build_phal = get_option('phal').enabled()
41
42if get_option('phal').enabled() and not get_option('p9').disabled()
43    build_p9 = false
44endif
45
46summary('building p9', build_p9)
47summary('building openfsi', build_openfsi)
48summary('building phal', build_phal)
49
50if build_p9
51    extra_sources += [
52        'procedures/p9/cleanup_pcie.cpp',
53        'procedures/p9/set_sync_fsi_clock_mode.cpp',
54        'procedures/p9/start_host.cpp',
55        'procedures/p9/start_host_mpreboot.cpp',
56    ]
57endif
58if build_openfsi
59    extra_sources += [
60        'procedures/openfsi/scan.cpp',
61    ]
62endif
63if build_phal
64    extra_sources += [
65        'procedures/phal/start_host.cpp',
66        'procedures/phal/set_SPI_mux.cpp',
67        'procedures/phal/proc_pre_poweroff.cpp',
68        'procedures/phal/common_utils.cpp',
69        'procedures/phal/check_host_running.cpp',
70        'phalerror/create_pel.cpp',
71        'phalerror/phal_error.cpp',
72    ]
73    extra_dependencies += [
74        dependency('libdt-api'),
75        cxx.find_library('ekb'),
76        cxx.find_library('ipl'),
77    ]
78    extra_unit_files = [
79        'service_files/set-spi-mux.service',
80        'service_files/phal-reinit-devtree.service',
81        'service_files/proc-pre-poweroff@.service',
82        'service_files/op-reset-host-check@.service',
83        'service_files/op-reset-host-clear.service',
84    ]
85    unit_subs.set('ENABLE_PHAL_TRUE', '')
86endif
87
88executable(
89    'openpower-proc-control',
90    [
91        'cfam_access.cpp',
92        'ext_interface.cpp',
93        'filedescriptor.cpp',
94        'proc_control.cpp',
95        'targeting.cpp',
96        'procedures/common/cfam_overrides.cpp',
97        'procedures/common/cfam_reset.cpp',
98        'procedures/common/enter_mpreboot.cpp',
99        'procedures/common/collect_sbe_hb_data.cpp',
100        'util.cpp',
101    ] + extra_sources,
102    dependencies: [
103        dependency('libgpiodcxx'),
104        cxx.find_library('pdbg'),
105        dependency('phosphor-dbus-interfaces'),
106        dependency('phosphor-logging'),
107        dependency('sdbusplus'),
108        dependency('threads'),
109        dependency('fmt'),
110    ] + extra_dependencies,
111    install: true
112)
113
114executable(
115    'openpower-proc-nmi',
116    [
117        'nmi_main.cpp',
118        'nmi_interface.cpp',
119    ],
120    dependencies: [
121        cxx.find_library('pdbg'),
122        dependency('phosphor-dbus-interfaces'),
123        dependency('phosphor-logging'),
124        dependency('sdbusplus'),
125   ],
126   install: true
127)
128
129unit_files = [
130    'service_files/pcie-poweroff@.service',
131    'service_files/xyz.openbmc_project.Control.Host.NMI.service',
132    'service_files/op-stop-instructions@.service',
133    'service_files/op-cfam-reset.service',
134    'service_files/op-continue-mpreboot@.service',
135    'service_files/op-enter-mpreboot@.service',
136] + extra_unit_files
137
138systemd_system_unit_dir = dependency('systemd').get_pkgconfig_variable(
139    'systemdsystemunitdir',
140    define_variable: ['prefix', get_option('prefix')])
141foreach u : unit_files
142    configure_file(
143        configuration: unit_subs,
144        input: u + '.in',
145        install: true,
146        install_dir: systemd_system_unit_dir,
147        output: '@BASENAME@'
148    )
149endforeach
150
151if not get_option('tests').disabled()
152    test(
153        'utest',
154        executable(
155            'utest',
156            'test/utest.cpp',
157            'targeting.cpp',
158            'filedescriptor.cpp',
159            dependencies: [
160                dependency('gtest', main: true),
161                dependency('phosphor-logging'),
162            ],
163            implicit_include_directories: false,
164            include_directories: '.',
165        )
166    )
167endif
168