xref: /openbmc/openpower-occ-control/meson.build (revision a937491bfdc7df9dd0b5854a5b6e827ccf3e3dee) 
1project(
2    'openpower-occ-control', 'cpp',
3    version : '1.0.0',
4    meson_version: '>=1.1.1',
5    default_options: [
6        'warning_level=3',
7        'werror=true',
8        'cpp_std=c++23',
9        'buildtype=debugoptimized'
10    ]
11)
12
13cxx = meson.get_compiler('cpp')
14
15conf_data = configuration_data()
16conf_data.set_quoted('OCC_CONTROL_BUSNAME', 'org.open_power.OCC.Control')
17conf_data.set_quoted('OCC_CONTROL_ROOT', '/org/open_power/control')
18conf_data.set_quoted('OCC_SENSORS_ROOT', '/xyz/openbmc_project/sensors')
19conf_data.set_quoted('CPU_NAME', 'cpu')
20conf_data.set_quoted('OCC_NAME', 'occ')
21conf_data.set_quoted('OCC_MASTER_NAME', 'occ-hwmon.1')
22conf_data.set_quoted('OCC_DEV_PATH', '/dev/occ')
23conf_data.set_quoted('CPU_SUBPATH', '/xyz/openbmc_project/inventory/system/chassis/motherboard')
24conf_data.set_quoted('OCC_CONTROL_PERSIST_PATH', '/var/lib/openpower-occ-control')
25
26conf_data.set('MAX_CPUS', get_option('max-cpus'))
27conf_data.set('OCC_CPU_TEMP_SENSOR_TYPE', 0xC0)
28conf_data.set('OCC_DIMM_TEMP_SENSOR_TYPE', 0xD0)
29conf_data.set('PS_DERATING_FACTOR', get_option('ps-derating-factor'))
30
31if get_option('i2c-occ').allowed()
32    conf_data.set_quoted('OCC_HWMON_PATH', '/sys/bus/i2c/drivers/occ-hwmon/')
33    conf_data.set_quoted('DEV_PATH', '/sys/bus/i2c/devices')
34    conf_data.set_quoted('I2C_OCC_DEVICE_NAME', 'p8-occ-hwmon')
35else
36    conf_data.set_quoted('OCC_HWMON_PATH', '/sys/bus/platform/drivers/occ-hwmon/')
37    conf_data.set_quoted('DEV_PATH', '/sys/bus/platform/devices/')
38endif
39
40conf_data.set('I2C_OCC', get_option('i2c-occ').allowed())
41conf_data.set('READ_OCC_SENSORS', get_option('read-occ-sensors').allowed())
42conf_data.set('PLDM', get_option('with-host-communication-protocol')=='pldm')
43conf_data.set('POWER10', get_option('power10-support').allowed())
44
45configure_file(output: 'config.h',
46    configuration: conf_data
47)
48
49install_data('occ-active.sh',
50    install_mode: 'rwxr-xr-x',
51    install_dir: get_option('bindir')
52)
53
54systemd = dependency('systemd')
55systemd_system_unit_dir = systemd.get_variable(
56    'systemdsystemunitdir')
57subdir('service_files')
58
59sdbusplus_dep = dependency('sdbusplus')
60
61python_prog = find_program('python3', required: true)
62
63deps = []
64sources = []
65
66nlohmann_json_dep = dependency('nlohmann_json', include_type: 'system')
67sdeventplus_dep = dependency(
68    'sdeventplus',
69    fallback: [
70        'sdeventplus',
71        'sdeventplus_dep'
72    ],
73)
74phosphor_dbus_interfaces_dep = dependency(
75    'phosphor-dbus-interfaces',
76    fallback: [
77        'phosphor-dbus-interfaces',
78        'phosphor_dbus_interfaces_dep'
79    ],
80)
81phosphor_logging_dep = dependency(
82    'phosphor-logging',
83    fallback: [
84        'phosphor-logging',
85        'phosphor_logging_dep'
86    ],
87)
88
89deps += [
90    nlohmann_json_dep,
91    phosphor_dbus_interfaces_dep,
92    phosphor_logging_dep,
93    sdbusplus_dep,
94    sdeventplus_dep,
95]
96
97sources += [
98    'app.cpp',
99    'occ_pass_through.cpp',
100    'occ_manager.cpp',
101    'occ_status.cpp',
102    'occ_device.cpp',
103    'occ_errors.cpp',
104    'occ_ffdc.cpp',
105    'occ_presence.cpp',
106    'occ_command.cpp',
107    'occ_dbus.cpp',
108    'powercap.cpp',
109    'i2c_occ.cpp',
110    'utils.cpp',
111]
112
113if get_option('with-host-communication-protocol')=='pldm'
114    libpldm_dep = dependency(
115        'libpldm',
116        fallback: ['pldm', 'libpldm_dep'],
117        default_options: ['libpldm-only=enabled', 'oem-ibm=enabled'],
118    )
119    deps += [
120        libpldm_dep,
121        cxx.find_library('pdbg'),
122        cxx.find_library('phal'),
123    ]
124    sources += [
125        'pldm.cpp',
126    ]
127endif
128
129if get_option('power10-support').allowed()
130    sources += [
131        'powermode.cpp',
132    ]
133endif
134
135yamldir = get_option('yamldir')
136if yamldir == ''
137    yamldir = meson.project_source_root() / 'example'
138endif
139
140# Generate occ-sensor.hpp.
141occ_sensor_hpp = custom_target(
142    'occ-sensor.hpp',
143    command : [
144        python_prog,
145        meson.project_source_root() + '/sensor_gen.py',
146        '-i', yamldir,
147    ],
148    output : 'occ-sensor.hpp')
149    sources += [occ_sensor_hpp]
150
151    executable(
152        'openpower-occ-control',
153        sources,
154        include_directories: '.',
155        implicit_include_directories: true,
156        dependencies: deps,
157        install: true,
158        install_dir: get_option('bindir')
159    )
160
161if not get_option('tests').disabled()
162  subdir('test')
163endif
164