xref: /openbmc/openpower-hw-diags/meson.build (revision 5191bae9) 
1# See README.md for details.
2project('openpower-hw-diags', 'cpp',
3        version: '0.1', meson_version: '>=0.49.0',
4        default_options: [
5          'warning_level=3',
6          'werror=true',
7          'cpp_std=c++17',
8        ])
9
10# Package directory root, which will contain required data files.
11package_dir = join_paths( get_option('prefix'),
12                          get_option('datadir'),
13                          meson.project_name() )
14
15# Compiler option so that source knows the package directory.
16package_args = [ '-DPACKAGE_DIR="' + package_dir + '/"' ]
17
18#-------------------------------------------------------------------------------
19# Versioning
20#-------------------------------------------------------------------------------
21buildinfo = vcs_tag(command: ['git', 'describe', '--always', '--long'],
22                  input: 'buildinfo.hpp.in',
23                  output: 'buildinfo.hpp',
24                  replace_string:'@BUILDINFO@',
25                  fallback: '0')
26
27#-------------------------------------------------------------------------------
28# Compiler
29#-------------------------------------------------------------------------------
30
31cmplr = meson.get_compiler('cpp')
32
33#-------------------------------------------------------------------------------
34# Config file
35#-------------------------------------------------------------------------------
36
37conf = configuration_data()
38
39conf.set('CONFIG_PHAL_API', get_option('phal').enabled())
40
41configure_file(input: 'config.h.in', output: 'config.h', configuration: conf)
42
43#-------------------------------------------------------------------------------
44# Include directories
45#-------------------------------------------------------------------------------
46
47# Only using the base directory. All header includes should provide the full
48# path from the base directory.
49incdir = include_directories('.')
50
51#-------------------------------------------------------------------------------
52# External library dependencies
53#-------------------------------------------------------------------------------
54
55# Look if the libhei library has already been built and installed. If not,
56# default to the subproject.
57libhei_dep = dependency('hei', fallback : ['libhei', 'libhei_dep'])
58
59sdbusplus_dep       = dependency('sdbusplus', version : '>=1.0')
60dbus_interfaces_dep = dependency('phosphor-dbus-interfaces')
61
62libpdbg_dep = cmplr.find_library('pdbg')
63
64# See if phosphor-logging is available, if not use test case logging code. This
65# allows for local builds outside of CI test sandbox.
66h = 'phosphor-logging/log.hpp'
67if cmplr.compiles('#include <@0@>'.format(h), name : '#include <@0@>'.format(h))
68    test_arg = []
69    phosphor_logging = true
70else
71    test_arg = [
72        '-DTEST_TRACE',
73    ]
74    phosphor_logging = false
75endif
76
77pthread = declare_dependency(link_args : '-pthread')
78lrt = declare_dependency(link_args : '-lrt')
79
80# JSON parser
81if cmplr.has_header('nlohmann/json.hpp')
82    nlohmann_json_dep = declare_dependency()
83else
84    subproject('nlohmann', required: false)
85    nlohmann_json_dep = declare_dependency(
86        include_directories: [
87            'subprojects/nlohmann/single_include',
88            'subprojects/nlohmann/single_include/nlohmann',
89        ]
90    )
91    nlohmann_json_dep = nlohmann_json_dep.as_system('system')
92endif
93
94# JSON validator
95if cmplr.has_header('valijson/validator.hpp')
96    valijson_dep = declare_dependency()
97else
98    subproject('valijson', required: false)
99    valijson_dep = declare_dependency(
100        include_directories: 'subprojects/valijson/include'
101    )
102    valijson_dep = valijson_dep.as_system('system')
103endif
104
105#-------------------------------------------------------------------------------
106# Build the local static libraries
107#-------------------------------------------------------------------------------
108
109subdir('analyzer')
110subdir('attn')
111subdir('util')
112
113hwdiags_libs = [
114    analyzer_lib,
115    attn_lib,
116    util_lib,
117]
118
119#-------------------------------------------------------------------------------
120# Build the executable
121#-------------------------------------------------------------------------------
122
123no_listener_mode = get_option('nlmode')
124
125if not no_listener_mode.disabled()
126  executable('openpower-hw-diags',
127              sources : [ 'main_nl.cpp', 'cli.cpp', buildinfo ],
128              link_with : hwdiags_libs,
129              install : true)
130else
131  executable('openpower-hw-diags',
132              sources : [ 'main.cpp', 'cli.cpp', 'listener.cpp', buildinfo ],
133              dependencies : [lrt, pthread],
134              link_with : hwdiags_libs,
135              cpp_args : test_arg,
136              install : true)
137endif
138
139#-------------------------------------------------------------------------------
140# Test, if configured
141#-------------------------------------------------------------------------------
142
143build_tests = get_option('tests')
144
145if not build_tests.disabled()
146  subdir('test')
147endif
148