1SUMMARY = "Lossless data compression library"
2DESCRIPTION = "A portable lossless data compression library written in \
3ANSI C that offers pretty fast compression and *extremely* fast decompression. "
4HOMEPAGE = "http://www.oberhumer.com/opensource/lzo/"
5SECTION = "libs"
6LICENSE = "GPLv2+"
7LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263 \
8                    file://src/lzo_init.c;beginline=5;endline=25;md5=9ae697ca01829b0a383c5d2d163e0108"
9
10SRC_URI = "http://www.oberhumer.com/opensource/lzo/download/lzo-${PV}.tar.gz \
11           file://0001-Use-memcpy-instead-of-reinventing-it.patch \
12	   file://0001-Add-pkgconfigdir-to-solve-the-undefine-error.patch \
13           file://run-ptest \
14           "
15
16SRC_URI[md5sum] = "39d3f3f9c55c87b1e5d6888e1420f4b5"
17SRC_URI[sha256sum] = "c0f892943208266f9b6543b3ae308fab6284c5c90e627931446fb49b4221a072"
18
19inherit autotools ptest
20
21CVE_PRODUCT = "lzo oberhumer:lzo2"
22
23EXTRA_OECONF = "--enable-shared"
24
25do_install_ptest() {
26	t=${D}${PTEST_PATH}
27	cp ${S}/util/check.sh $t
28	cp ${B}/minilzo/testmini $t
29	for i in tests/align tests/chksum lzotest/lzotest examples/simple
30		do cp ${B}/`dirname $i`/.libs/`basename $i` $t; \
31	done
32}
33
34
35BBCLASSEXTEND = "native nativesdk"
36