1SUMMARY = "An asynchronous event notification library"
2DESCRIPTION = "A software library that provides asynchronous event \
3notification. The libevent API provides a mechanism to execute a callback \
4function when a specific event occurs on a file descriptor or after a \
5timeout has been reached. libevent also supports callbacks triggered \
6by signals and regular timeouts"
7HOMEPAGE = "http://libevent.org/"
8BUGTRACKER = "https://github.com/libevent/libevent/issues"
9SECTION = "libs"
10
11LICENSE = "BSD-3-Clause & MIT"
12LIC_FILES_CHKSUM = "file://LICENSE;md5=17f20574c0b154d12236d5fbe964f549"
13
14SRC_URI = "https://github.com/libevent/libevent/releases/download/release-${PV}-stable/${BP}-stable.tar.gz \
15           file://Makefile-missing-test-dir.patch \
16           file://run-ptest \
17           file://0001-test-regress_dns.c-patch-out-tests-that-require-a-wo.patch \
18           file://0002-test-regress.h-Increase-default-timeval-tolerance-50.patch \
19           "
20
21SRC_URI[sha256sum] = "92e6de1be9ec176428fd2367677e61ceffc2ee1cb119035037a27d346b0403bb"
22
23UPSTREAM_CHECK_URI = "http://libevent.org/"
24
25S = "${WORKDIR}/${BPN}-${PV}-stable"
26
27PACKAGECONFIG ??= ""
28PACKAGECONFIG[openssl] = "--enable-openssl,--disable-openssl,openssl"
29
30inherit autotools
31
32# Needed for Debian packaging
33LEAD_SONAME = "libevent-2.1.so"
34
35inherit ptest multilib_header
36
37DEPENDS = "zlib"
38
39PACKAGES_DYNAMIC = "^${PN}-.*$"
40python split_libevent_libs () {
41    do_split_packages(d, '${libdir}', r'^libevent_([a-z]*)-.*\.so\..*', '${PN}-%s', '${SUMMARY} (%s)', prepend=True, allow_links=True)
42}
43PACKAGESPLITFUNCS:prepend = "split_libevent_libs "
44
45BBCLASSEXTEND = "native nativesdk"
46
47do_install:append() {
48	rm ${D}${bindir}/event_rpcgen.py
49	rmdir ${D}${bindir}
50        oe_multilib_header event2/event-config.h
51}
52
53do_install_ptest() {
54	install -d ${D}${PTEST_PATH}/test
55	for file in ${B}/test/.libs/regress ${B}/test/.libs/test*
56	do
57		install -m 0755 $file ${D}${PTEST_PATH}/test
58	done
59
60        # handle multilib
61        sed -i s:@libdir@:${libdir}:g ${D}${PTEST_PATH}/run-ptest
62}
63