1SUMMARY = "Key/value database library with extensible hashing"
2DESCRIPTION = "Library of database functions that use extensible hashing \
3and work similar to the standard UNIX dbm. These routines are provided \
4to a programmer needing to create and manipulate a hashed database."
5HOMEPAGE = "http://www.gnu.org/software/gdbm/"
6SECTION = "libs"
7LICENSE = "GPL-3.0-only"
8LIC_FILES_CHKSUM = "file://COPYING;md5=241da1b9fe42e642cbb2c24d5e0c4d24"
9
10
11SRC_URI = "${GNU_MIRROR}/gdbm/gdbm-${PV}.tar.gz \
12           file://run-ptest \
13           file://ptest.patch \
14          "
15
16SRC_URI[sha256sum] = "695e9827fdf763513f133910bc7e6cfdb9187943a4fec943e57449723d2b8dbf"
17
18inherit autotools gettext texinfo lib_package ptest
19
20# Needed for dbm python module
21EXTRA_OECONF = "--enable-libgdbm-compat --without-readline"
22
23# Stop presence of dbm/nbdm on the host contaminating builds
24CACHED_CONFIGUREVARS += "ac_cv_lib_ndbm_main=no ac_cv_lib_dbm_main=no"
25
26BBCLASSEXTEND = "native nativesdk"
27
28do_install:append () {
29    # Create a symlink to ndbm.h and gdbm.h in include/gdbm to let other packages to find
30    # these headers
31    install -d ${D}${includedir}/gdbm
32    ln -sf ../ndbm.h ${D}/${includedir}/gdbm/ndbm.h
33    ln -sf ../gdbm.h ${D}/${includedir}/gdbm/gdbm.h
34}
35
36RDEPENDS:${PN}-ptest += "diffutils ${PN}-bin"
37
38do_compile_ptest() {
39    oe_runmake -C tests buildtests
40}
41
42PACKAGES =+ "${PN}-compat \
43            "
44FILES:${PN}-compat = "${libdir}/libgdbm_compat${SOLIBS} \
45                     "
46