1SUMMARY = "Utilities for manipulating filesystem extended attributes"
2DESCRIPTION = "Implement the ability for a user to attach name:value pairs to objects within the XFS filesystem."
3
4HOMEPAGE = "http://savannah.nongnu.org/projects/attr/"
5SECTION = "libs"
6
7DEPENDS = "virtual/libintl"
8
9LICENSE = "LGPL-2.1-or-later & GPL-2.0-or-later"
10LICENSE:${PN} = "GPL-2.0-or-later"
11LICENSE:lib${BPN} = "LGPL-2.1-or-later"
12LIC_FILES_CHKSUM = "file://doc/COPYING;md5=2d0aa14b3fce4694e4f615e30186335f \
13                    file://doc/COPYING.LGPL;md5=b8d31f339300bc239d73461d68e77b9c \
14                    file://tools/attr.c;endline=17;md5=be0403261f0847e5f43ed5b08d19593c \
15                    file://libattr/libattr.c;endline=17;md5=7970f77049f8fa1199fff62a7ab724fb"
16
17SRC_URI = "${SAVANNAH_GNU_MIRROR}/attr/${BP}.tar.gz \
18           file://run-ptest \
19"
20
21inherit ptest update-alternatives autotools gettext
22
23PACKAGES =+ "lib${BPN}"
24
25FILES:lib${BPN} = "${libdir}/lib*${SOLIBS} ${sysconfdir}"
26
27ALTERNATIVE_PRIORITY = "100"
28ALTERNATIVE:${PN} = "setfattr"
29ALTERNATIVE_TARGET[setfattr] = "${bindir}/setfattr"
30
31PTEST_BUILD_HOST_FILES = "builddefs"
32PTEST_BUILD_HOST_PATTERN = "^RPM"
33
34do_install_ptest() {
35        cp ${B}/Makefile ${D}${PTEST_PATH}
36        sed -e 's,--sysroot=${STAGING_DIR_TARGET},,g' \
37            -e 's|${DEBUG_PREFIX_MAP}||g' \
38            -e 's:${HOSTTOOLS_DIR}/::g' \
39            -e 's:${RECIPE_SYSROOT_NATIVE}::g' \
40            -e 's:${BASE_WORKDIR}/${MULTIMACH_TARGET_SYS}::g' \
41            -i ${D}${PTEST_PATH}/Makefile
42
43        sed -i "s|^srcdir =.*|srcdir = \.|g" ${D}${PTEST_PATH}/Makefile
44        sed -i "s|^abs_srcdir =.*|abs_srcdir = \.|g" ${D}${PTEST_PATH}/Makefile
45        sed -i "s|^abs_top_srcdir =.*|abs_top_srcdir = \.\.|g" ${D}${PTEST_PATH}/Makefile
46        sed -i "s|^Makefile:.*|Makefile:|g" ${D}${PTEST_PATH}/Makefile
47	cp -rf ${S}/build-aux/ ${D}${PTEST_PATH}
48	cp -rf ${S}/test/ ${D}${PTEST_PATH}
49}
50
51do_install_ptest:append:libc-musl() {
52        sed -i -e 's|f: Operation n|f: N|g' ${D}${PTEST_PATH}/test/attr.test
53}
54
55RDEPENDS:${PN}-ptest = "attr \
56                        bash \
57                        coreutils \
58                        perl-module-constant \
59                        perl-module-filehandle \
60                        perl-module-getopt-std \
61                        perl-module-posix \
62                        make \
63                        perl \
64                        gawk \
65                        perl-module-cwd \
66                        perl-module-file-basename \
67                        perl-module-file-path \
68                        perl-module-file-spec \
69                        "
70
71BBCLASSEXTEND = "native nativesdk"
72