1SUMMARY = "Simon Tatham's Portable Puzzle Collection"
2HOMEPAGE = "http://www.chiark.greenend.org.uk/~sgtatham/puzzles/"
3LICENSE = "MIT"
4LIC_FILES_CHKSUM = "file://LICENCE;md5=6099f4981f9461d7f411091e69a7f07a"
5
6DEPENDS = "libxt"
7
8# The libxt requires x11 in DISTRO_FEATURES
9REQUIRED_DISTRO_FEATURES = "x11"
10
11SRC_URI = "git://git.tartarus.org/simon/puzzles.git \
12           file://fix-compiling-failure-with-option-g-O.patch \
13           file://0001-palisade-Fix-warnings-with-clang-on-arm.patch \
14           file://0001-Use-Wno-error-format-overflow-if-the-compiler-suppor.patch \
15           file://0001-pattern.c-Change-string-lenght-parameter-to-be-size_.patch \
16           file://fix-ki-uninitialized.patch \
17           "
18
19UPSTREAM_CHECK_COMMITS = "1"
20SRCREV = "79a5378b5adc46ee33ba34d55738f916fb8adfc9"
21PE = "2"
22PV = "0.0+git${SRCPV}"
23
24S = "${WORKDIR}/git"
25
26inherit autotools features_check pkgconfig
27
28PACKAGECONFIG ??= "gtk3"
29PACKAGECONFIG[gtk2] = "--with-gtk=2,,gtk+,"
30PACKAGECONFIG[gtk3] = "--with-gtk=3,,gtk+3,"
31
32CFLAGS_append = " -Wno-deprecated-declarations"
33
34ASNEEDED = ""
35
36do_configure_prepend () {
37    cd ${S}
38    ./mkfiles.pl
39    cd ${B}
40}
41
42do_install_append () {
43    # net conflicts with Samba, so rename it
44    mv ${D}${bindir}/net ${D}${bindir}/puzzles-net
45
46    # Create desktop shortcuts
47    install -d ${D}/${datadir}/applications/
48    cd ${D}/${prefix}/bin
49    for prog in *; do
50	if [ -x $prog ]; then
51            # Convert prog to Title Case
52            title=$(echo $prog | sed 's/puzzles-//' | sed 's/\(^\| \)./\U&/g')
53	    echo "making ${D}/${datadir}/applications/$prog.desktop"
54	    cat <<STOP > ${D}/${datadir}/applications/$prog.desktop
55[Desktop Entry]
56Name=$title
57Exec=${bindir}/$prog
58Icon=applications-games
59Terminal=false
60Type=Application
61Categories=Game;
62StartupNotify=true
63STOP
64        fi
65    done
66}
67
68PACKAGES += "${PN}-extra"
69
70FILES_${PN} = ""
71FILES_${PN}-extra = "${prefix}/bin ${datadir}/applications"
72
73python __anonymous () {
74    var = d.expand("FILES_${PN}")
75    data = d.getVar(var, False)
76    for name in ("bridges", "fifteen", "inertia", "map", "samegame", "slant"):
77        data = data + " ${bindir}/%s" % name
78        data = data + " ${datadir}/applications/%s.desktop" % name
79    d.setVar(var, data)
80}
81