1SUMMARY = "Matchbox virtual keyboard for X11"
2DESCRIPTION = "An on screen 'virtual' or 'software' keyboard."
3HOMEPAGE = "http://matchbox-project.org"
4BUGTRACKER = "http://bugzilla.yoctoproject.org/"
5SECTION = "x11"
6
7LICENSE = "LGPL-2.1-only"
8LIC_FILES_CHKSUM = "file://COPYING;md5=4fbd65380cdd255951079008b364516c \
9                    file://src/matchbox-keyboard.h;endline=17;md5=9d6586c69e4a926f3cb0b4425f24ba3c \
10                    file://applet/applet.c;endline=18;md5=4a0f721724746b14d95b51ddd42b95e7"
11
12DEPENDS = "libfakekey expat libxft"
13
14#SRCREV for 0.1.1
15SRCREV = "630d89068dc0a1e9199306d405cb32f892dfa4d3"
16SRC_URI = "git://git.yoctoproject.org/${BPN};branch=matchbox-keyboard-0-1 \
17           file://0001-desktop-file-Hide-the-keyboard-from-app-list.patch \
18           file://80matchboxkeyboard.sh"
19
20S = "${WORKDIR}/git"
21
22inherit autotools pkgconfig gettext gtk-immodules-cache features_check
23
24# The libxft, libfakekey and matchbox-panel-2 requires x11 in DISTRO_FEATURES
25REQUIRED_DISTRO_FEATURES = "x11"
26
27EXTRA_OECONF = "--disable-cairo"
28
29PACKAGECONFIG ??= "gtk3-im applet"
30PACKAGECONFIG[applet] = "--enable-applet,--disable-applet,matchbox-panel-2"
31PACKAGECONFIG[gtk2-im] = "--enable-gtk-im,--disable-gtk-im,gtk+"
32PACKAGECONFIG[gtk3-im] = "--enable-gtk3-im,--disable-gtk3-im,gtk+3"
33
34PACKAGES += "${PN}-im ${PN}-applet"
35
36FILES:${PN} = "${bindir}/ \
37	       ${sysconfdir} \
38	       ${datadir}/applications \
39	       ${datadir}/pixmaps \
40	       ${datadir}/matchbox-keyboard"
41
42FILES:${PN}-im = "${libdir}/gtk-2.0/*/immodules/*.so \
43                  ${libdir}/gtk-3.0/*/immodules/*.so"
44
45FILES:${PN}-applet = "${libdir}/matchbox-panel/*.so"
46
47
48do_install:append () {
49	install -d ${D}/${sysconfdir}/X11/Xsession.d/
50	install -m 755 ${WORKDIR}/80matchboxkeyboard.sh ${D}/${sysconfdir}/X11/Xsession.d/
51
52	rm -f ${D}${libdir}/gtk-2.0/*/immodules/*.la
53	rm -f ${D}${libdir}/gtk-3.0/*/immodules/*.la
54	rm -f ${D}${libdir}/matchbox-panel/*.la
55}
56
57GTKIMMODULES_PACKAGES = "${PN}-im"
58
59RDEPENDS:${PN} = "formfactor dbus-wait"
60RRECOMMENDS:${PN} = "${PN}-applet"
61