1SUMMARY = "H.264/MPEG-4 AVC video encoder"
2DESCRIPTION = "A free software library and application for encoding video streams into the H.264/MPEG-4 AVC format."
3HOMEPAGE = "http://www.videolan.org/developers/x264.html"
4
5LICENSE = "GPLv2"
6LICENSE_FLAGS = "commercial"
7LIC_FILES_CHKSUM = "file://COPYING;md5=94d55d512a9ba36caa9b7df079bae19f"
8
9DEPENDS = "nasm-native"
10
11SRC_URI = "git://github.com/mirror/x264;branch=stable \
12           file://don-t-default-to-cortex-a9-with-neon.patch \
13           file://Fix-X32-build-by-disabling-asm.patch \
14           "
15UPSTREAM_CHECK_COMMITS = "1"
16
17SRCREV = "296494a4011f58f32adc54304a2654627558c59a"
18
19PV = "r2991+git${SRCPV}"
20
21S = "${WORKDIR}/git"
22
23inherit lib_package pkgconfig
24
25X264_DISABLE_ASM = ""
26X264_DISABLE_ASM_x86 = "--disable-asm"
27X264_DISABLE_ASM_armv4 = "--disable-asm"
28X264_DISABLE_ASM_armv5 = "--disable-asm"
29X264_DISABLE_ASM_powerpc = "${@bb.utils.contains("TUNE_FEATURES", "spe", "--disable-asm", "", d)}"
30X264_DISABLE_ASM_mipsarch = "${@bb.utils.contains("TUNE_FEATURES", "r6", "", "--disable-asm", d)}"
31
32EXTRA_OECONF = '--prefix=${prefix} \
33                --host=${HOST_SYS} \
34                --libdir=${libdir} \
35                --cross-prefix=${TARGET_PREFIX} \
36                --sysroot=${STAGING_DIR_TARGET} \
37                --enable-shared \
38                --enable-static \
39                --disable-lavf \
40                --disable-swscale \
41                --disable-opencl \
42                --enable-pic \
43                ${X264_DISABLE_ASM} \
44               '
45
46do_configure() {
47    install -m 0755 ${STAGING_DATADIR_NATIVE}/gnu-config/config.guess ${S}
48    install -m 0755 ${STAGING_DATADIR_NATIVE}/gnu-config/config.sub ${S}
49    ./configure ${EXTRA_OECONF}
50}
51
52do_install() {
53    oe_runmake install DESTDIR=${D}
54}
55
56AS[unexport] = "1"
57