1require gstreamer1.0-plugins-common.inc
2
3SUMMARY = "'Good' GStreamer plugins"
4HOMEPAGE = "https://gstreamer.freedesktop.org/"
5BUGTRACKER = "https://gitlab.freedesktop.org/gstreamer/gst-plugins-good/-/issues"
6
7SRC_URI = "https://gstreamer.freedesktop.org/src/gst-plugins-good/gst-plugins-good-${PV}.tar.xz"
8
9SRC_URI[sha256sum] = "fce748fa66d7a8ee1fb261489e59d01e3fa787623d6d5c35068416fe7cd0acb3"
10
11S = "${WORKDIR}/gst-plugins-good-${PV}"
12
13LICENSE = "LGPL-2.1-or-later"
14LIC_FILES_CHKSUM = "file://COPYING;md5=a6f89e2100d9b6cdffcea4f398e37343 \
15                    file://gst/replaygain/rganalysis.c;beginline=1;endline=23;md5=b60ebefd5b2f5a8e0cab6bfee391a5fe"
16
17DEPENDS += "gstreamer1.0-plugins-base libcap zlib"
18RPROVIDES:${PN}-pulseaudio += "${PN}-pulse"
19RPROVIDES:${PN}-soup += "${PN}-souphttpsrc"
20RDEPENDS:${PN}-soup += "${MLPREFIX}${@bb.utils.contains('PACKAGECONFIG', 'soup2', 'libsoup-2.4', 'libsoup', d)}"
21
22PACKAGECONFIG_SOUP ?= "soup3"
23
24PACKAGECONFIG ??= " \
25    ${GSTREAMER_ORC} \
26    ${PACKAGECONFIG_SOUP} \
27    ${@bb.utils.filter('DISTRO_FEATURES', 'pulseaudio x11', d)} \
28    ${@bb.utils.contains('TUNE_FEATURES', 'm64', 'asm', '', d)} \
29    bz2 cairo flac gdk-pixbuf gudev jpeg lame libpng mpg123 speex taglib v4l2 \
30"
31
32X11DEPENDS = "virtual/libx11 libsm libxrender libxfixes libxdamage"
33X11ENABLEOPTS = "-Dximagesrc=enabled -Dximagesrc-xshm=enabled -Dximagesrc-xfixes=enabled -Dximagesrc-xdamage=enabled"
34X11DISABLEOPTS = "-Dximagesrc=disabled -Dximagesrc-xshm=disabled -Dximagesrc-xfixes=disabled -Dximagesrc-xdamage=disabled"
35
36QT5WAYLANDDEPENDS = "${@bb.utils.contains("DISTRO_FEATURES", "wayland", "qtwayland", "", d)}"
37
38PACKAGECONFIG[amrnb]      = "-Damrnb=enabled,-Damrnb=disabled,opencore-amr"
39PACKAGECONFIG[amrwb]      = "-Damrwbdec=enabled,-Damrwbdec=disabled,opencore-amr"
40PACKAGECONFIG[asm]        = "-Dasm=enabled,-Dasm=disabled,nasm-native"
41PACKAGECONFIG[bz2]        = "-Dbz2=enabled,-Dbz2=disabled,bzip2"
42PACKAGECONFIG[cairo]      = "-Dcairo=enabled,-Dcairo=disabled,cairo"
43PACKAGECONFIG[dv1394]     = "-Ddv1394=enabled,-Ddv1394=disabled,libiec61883 libavc1394 libraw1394"
44PACKAGECONFIG[flac]       = "-Dflac=enabled,-Dflac=disabled,flac"
45PACKAGECONFIG[gdk-pixbuf] = "-Dgdk-pixbuf=enabled,-Dgdk-pixbuf=disabled,gdk-pixbuf"
46PACKAGECONFIG[gtk]        = "-Dgtk3=enabled,-Dgtk3=disabled,gtk+3"
47PACKAGECONFIG[gudev]      = "-Dv4l2-gudev=enabled,-Dv4l2-gudev=disabled,libgudev"
48PACKAGECONFIG[jack]       = "-Djack=enabled,-Djack=disabled,jack"
49PACKAGECONFIG[jpeg]       = "-Djpeg=enabled,-Djpeg=disabled,jpeg"
50PACKAGECONFIG[lame]       = "-Dlame=enabled,-Dlame=disabled,lame"
51PACKAGECONFIG[libpng]     = "-Dpng=enabled,-Dpng=disabled,libpng"
52PACKAGECONFIG[libv4l2]    = "-Dv4l2-libv4l2=enabled,-Dv4l2-libv4l2=disabled,v4l-utils"
53PACKAGECONFIG[mpg123]     = "-Dmpg123=enabled,-Dmpg123=disabled,mpg123"
54PACKAGECONFIG[pulseaudio] = "-Dpulse=enabled,-Dpulse=disabled,pulseaudio"
55PACKAGECONFIG[qt5]        = "-Dqt5=enabled,-Dqt5=disabled,qtbase qtdeclarative qtbase-native qttools-native ${QT5WAYLANDDEPENDS}"
56PACKAGECONFIG[soup2]      = "-Dsoup=enabled,,libsoup-2.4,,,soup3"
57PACKAGECONFIG[soup3]      = "-Dsoup=enabled,,libsoup,,,soup2"
58PACKAGECONFIG[speex]      = "-Dspeex=enabled,-Dspeex=disabled,speex"
59PACKAGECONFIG[rpi]        = "-Drpicamsrc=enabled,-Drpicamsrc=disabled,userland"
60PACKAGECONFIG[taglib]     = "-Dtaglib=enabled,-Dtaglib=disabled,taglib"
61PACKAGECONFIG[v4l2]       = "-Dv4l2=enabled -Dv4l2-probe=true,-Dv4l2=disabled -Dv4l2-probe=false"
62PACKAGECONFIG[vpx]        = "-Dvpx=enabled,-Dvpx=disabled,libvpx"
63PACKAGECONFIG[wavpack]    = "-Dwavpack=enabled,-Dwavpack=disabled,wavpack"
64PACKAGECONFIG[x11]        = "${X11ENABLEOPTS},${X11DISABLEOPTS},${X11DEPENDS}"
65
66EXTRA_OEMESON += " \
67    -Ddoc=disabled \
68    -Daalib=disabled \
69    -Ddirectsound=disabled \
70    -Ddv=disabled \
71    -Dlibcaca=disabled \
72    -Doss=enabled \
73    -Doss4=disabled \
74    -Dosxaudio=disabled \
75    -Dosxvideo=disabled \
76    -Dshout2=disabled \
77    -Dtwolame=disabled \
78    -Dwaveform=disabled \
79"
80
81FILES:${PN}-equalizer += "${datadir}/gstreamer-1.0/presets/*.prs"
82