1# This recipe tracks the linux-yocto-dev repository as its upstream source.
2# Since this tree is frequently updated, and periodically rebuilt, AUTOREV is
3# used to track its contents.
4#
5# This recipe is just like other linux-yocto variants, with the only difference
6# being that to avoid network access during initial parsing, static SRCREVs are
7# provided and overridden if the preferred kernel provider is linux-yocto-dev.
8#
9# To enable this recipe, set PREFERRED_PROVIDER_virtual/kernel = "linux-yocto-dev"
10
11inherit kernel
12require recipes-kernel/linux/linux-yocto.inc
13
14# provide this .inc to set specific revisions
15include recipes-kernel/linux/linux-yocto-dev-revisions.inc
16
17KBRANCH = "v6.12/standard/base"
18KMETA = "kernel-meta"
19
20SRC_URI = "git://git.yoctoproject.org/linux-yocto-dev.git;branch=${KBRANCH};name=machine;protocol=https \
21           git://git.yoctoproject.org/yocto-kernel-cache;type=kmeta;name=meta;branch=master;destsuffix=${KMETA};protocol=https"
22
23# Set default SRCREVs. Both the machine and meta SRCREVs are statically set
24# to the korg v3.7 tag, and hence prevent network access during parsing. If
25# linux-yocto-dev is the preferred provider, they will be overridden to
26# AUTOREV in following anonymous python routine and resolved when the
27# variables are finalized.
28SRCREV_machine ?= '${@oe.utils.conditional("PREFERRED_PROVIDER_virtual/kernel", "linux-yocto-dev", "${AUTOREV}", "29594404d7fe73cd80eaa4ee8c43dcc53970c60e", d)}'
29SRCREV_meta ?= '${@oe.utils.conditional("PREFERRED_PROVIDER_virtual/kernel", "linux-yocto-dev", "${AUTOREV}", "29594404d7fe73cd80eaa4ee8c43dcc53970c60e", d)}'
30
31LINUX_VERSION ?= "6.12"
32LINUX_VERSION_EXTENSION ?= "-yoctodev-${LINUX_KERNEL_TYPE}"
33PV = "${LINUX_VERSION}+git"
34
35LIC_FILES_CHKSUM = "file://COPYING;md5=6bc538ed5bd9a7fc9398086aedcd7e46"
36
37# yaml and dtschema are required for 5.16+ device tree validation, libyaml is checked
38# via pkgconfig, so must always be present, but we can wrap the others to make them
39# conditional
40DEPENDS += "libyaml-native"
41
42PACKAGECONFIG ??= ""
43PACKAGECONFIG[dt-validation] = ",,python3-dtschema-native"
44# we need the wrappers if validation isn't in the packageconfig
45DEPENDS += "${@bb.utils.contains('PACKAGECONFIG', 'dt-validation', '', 'python3-dtschema-wrapper-native', d)}"
46
47COMPATIBLE_MACHINE = "^(qemuarmv5|qemuarm|qemuarm64|qemux86|qemuppc|qemumips|qemumips64|qemux86-64|qemuriscv32|qemuriscv64|qemuloongarch64)$"
48
49KERNEL_DEVICETREE:qemuarmv5 = "arm/versatile-pb.dtb"
50
51# Functionality flags
52KERNEL_EXTRA_FEATURES ?= "features/netfilter/netfilter.scc features/taskstats/taskstats.scc"
53KERNEL_FEATURES:append = " ${KERNEL_EXTRA_FEATURES}"
54KERNEL_FEATURES:append:qemuall=" cfg/virtio.scc features/drm-bochs/drm-bochs.scc"
55KERNEL_FEATURES:append:qemux86=" cfg/sound.scc cfg/paravirt_kvm.scc"
56KERNEL_FEATURES:append:qemux86-64=" cfg/sound.scc cfg/paravirt_kvm.scc"
57KERNEL_FEATURES:append = " ${@bb.utils.contains("TUNE_FEATURES", "mx32", " cfg/x32.scc", "", d)}"
58KERNEL_FEATURES:append = " ${@bb.utils.contains("DISTRO_FEATURES", "ptest", " features/scsi/scsi-debug.scc", "", d)}"
59KERNEL_FEATURES:append = " ${@bb.utils.contains("DISTRO_FEATURES", "ptest", " features/gpio/mockup.scc features/gpio/sim.scc", "", d)}"
60
61KERNEL_VERSION_SANITY_SKIP = "1"
62