1# This recipe tracks the linux-yocto-dev repository as its upstream source.
2# Since this tree is frequently updated, and periodically rebuilt, AUTOREV is
3# used to track its contents.
4#
5# This recipe is just like other linux-yocto variants, with the only difference
6# being that to avoid network access during initial parsing, static SRCREVs are
7# provided and overridden if the preferred kernel provider is linux-yocto-dev.
8#
9# To enable this recipe, set PREFERRED_PROVIDER_virtual/kernel = "linux-yocto-dev"
10
11inherit kernel
12require recipes-kernel/linux/linux-yocto.inc
13# for ncurses tests
14inherit pkgconfig
15
16# provide this .inc to set specific revisions
17include recipes-kernel/linux/linux-yocto-dev-revisions.inc
18
19KBRANCH = "standard/base"
20KMETA = "kernel-meta"
21
22SRC_URI = "git://git.yoctoproject.org/linux-yocto-dev.git;branch=${KBRANCH};name=machine \
23           git://git.yoctoproject.org/yocto-kernel-cache;type=kmeta;name=meta;branch=master;destsuffix=${KMETA}"
24
25# Set default SRCREVs. Both the machine and meta SRCREVs are statically set
26# to the korg v3.7 tag, and hence prevent network access during parsing. If
27# linux-yocto-dev is the preferred provider, they will be overridden to
28# AUTOREV in following anonymous python routine and resolved when the
29# variables are finalized.
30SRCREV_machine ?= '${@oe.utils.conditional("PREFERRED_PROVIDER_virtual/kernel", "linux-yocto-dev", "${AUTOREV}", "29594404d7fe73cd80eaa4ee8c43dcc53970c60e", d)}'
31SRCREV_meta ?= '${@oe.utils.conditional("PREFERRED_PROVIDER_virtual/kernel", "linux-yocto-dev", "${AUTOREV}", "29594404d7fe73cd80eaa4ee8c43dcc53970c60e", d)}'
32
33LINUX_VERSION ?= "5.3-rc+"
34LINUX_VERSION_EXTENSION ?= "-yoctodev-${LINUX_KERNEL_TYPE}"
35PV = "${LINUX_VERSION}+git${SRCPV}"
36
37LIC_FILES_CHKSUM = "file://COPYING;md5=bbea815ee2795b2f4230826c0c6b8814"
38
39DEPENDS += "${@bb.utils.contains('ARCH', 'x86', 'elfutils-native', '', d)}"
40DEPENDS += "openssl-native util-linux-native"
41
42COMPATIBLE_MACHINE = "(qemuarm|qemux86|qemuppc|qemumips|qemumips64|qemux86-64|qemuriscv64)"
43
44KERNEL_DEVICETREE_qemuarmv5 = "versatile-pb.dtb"
45
46# Functionality flags
47KERNEL_EXTRA_FEATURES ?= "features/netfilter/netfilter.scc features/taskstats/taskstats.scc"
48KERNEL_FEATURES_append = " ${KERNEL_EXTRA_FEATURES}"
49KERNEL_FEATURES_append_qemuall=" cfg/virtio.scc features/drm-bochs/drm-bochs.scc"
50KERNEL_FEATURES_append_qemux86=" cfg/sound.scc cfg/paravirt_kvm.scc"
51KERNEL_FEATURES_append_qemux86-64=" cfg/sound.scc"
52KERNEL_FEATURES_append = " ${@bb.utils.contains("TUNE_FEATURES", "mx32", " cfg/x32.scc", "" ,d)}"
53
54KERNEL_VERSION_SANITY_SKIP = "1"
55