1# Copyright (C) 2012 Khem Raj <raj.khem@gmail.com>
2# Released under the MIT license (see COPYING.MIT for the terms)
3
4SUMMARY = "Tools for managing Linux kernel modules"
5DESCRIPTION = "kmod is a set of tools to handle common tasks with Linux kernel modules like \
6               insert, remove, list, check properties, resolve dependencies and aliases."
7HOMEPAGE = "http://kernel.org/pub/linux/utils/kernel/kmod/"
8LICENSE = "GPL-2.0-or-later & LGPL-2.1-or-later"
9LICENSE:libkmod = "LGPL-2.1-or-later"
10SECTION = "base"
11
12LIC_FILES_CHKSUM = "file://COPYING;md5=a6f89e2100d9b6cdffcea4f398e37343 \
13                    file://libkmod/COPYING;md5=a6f89e2100d9b6cdffcea4f398e37343 \
14                    file://tools/COPYING;md5=751419260aa954499f7abaabaa882bbe \
15                   "
16inherit autotools bash-completion gtk-doc pkgconfig update-alternatives
17
18SRCREV = "e193aeb99a04fb4b63ce47eb2c7f119db59446a0"
19
20SRC_URI = "git://git.kernel.org/pub/scm/utils/kernel/kmod/kmod.git;branch=master;protocol=https \
21           file://depmod-search.conf \
22           file://avoid_parallel_tests.patch \
23           file://gtkdocdir.patch \
24           "
25
26S = "${WORKDIR}/git"
27
28EXTRA_OECONF += "--enable-tools"
29
30PACKAGECONFIG ??= "zlib xz openssl"
31PACKAGECONFIG[debug] = "--enable-debug,--disable-debug"
32PACKAGECONFIG[logging] = " --enable-logging,--disable-logging"
33PACKAGECONFIG[manpages] = "--enable-manpages, --disable-manpages, scdoc-native"
34PACKAGECONFIG[openssl] = "--with-openssl,--without-openssl,openssl"
35PACKAGECONFIG[xz] = "--with-xz,--without-xz,xz"
36PACKAGECONFIG[zlib] = "--with-zlib,--without-zlib,zlib"
37PACKAGECONFIG[zstd] = "--with-zstd,--without-zstd,zstd"
38
39PROVIDES += "module-init-tools-insmod-static module-init-tools-depmod module-init-tools"
40RPROVIDES:${PN} += "module-init-tools-insmod-static module-init-tools-depmod module-init-tools"
41RCONFLICTS:${PN} += "module-init-tools-insmod-static module-init-tools-depmod module-init-tools"
42RREPLACES:${PN} += "module-init-tools-insmod-static module-init-tools-depmod module-init-tools"
43
44# to force user to remove old module-init-tools and replace them with kmod variants
45RCONFLICTS:libkmod2 += "module-init-tools-insmod-static module-init-tools-depmod module-init-tools"
46
47# autotools set prefix to /usr, however we want them in /bin and /sbin
48EXTRA_OECONF += "--bindir=${base_bindir} --sbindir=${base_sbindir}"
49
50do_install:append () {
51        install -dm755 ${D}${base_bindir}
52        install -dm755 ${D}${base_sbindir}
53        # add symlinks to kmod
54        [ -e ${D}${base_bindir}/lsmod ] || ln -rs ${D}${base_bindir}/kmod ${D}${base_bindir}/lsmod
55        for tool in insmod rmmod depmod modinfo modprobe; do
56                rm -f ${D}${base_bindir}/${tool}
57                ln -rs ${D}${base_bindir}/kmod ${D}${base_sbindir}/${tool}
58        done
59        # configuration directories
60        install -dm755 ${D}${nonarch_base_libdir}/depmod.d
61        install -dm755 ${D}${nonarch_base_libdir}/modprobe.d
62        install -dm755 ${D}${sysconfdir}/depmod.d
63        install -dm755 ${D}${sysconfdir}/modprobe.d
64
65        # install depmod.d file for search/ dir
66        install -Dm644 "${UNPACKDIR}/depmod-search.conf" "${D}${nonarch_base_libdir}/depmod.d/search.conf"
67
68        # Add .debug to the exclude path for depmod
69        echo "exclude .debug" > ${D}${nonarch_base_libdir}/depmod.d/exclude.conf
70}
71
72ALTERNATIVE_PRIORITY = "70"
73
74ALTERNATIVE:kmod = "insmod modprobe rmmod modinfo bin-lsmod lsmod depmod"
75
76ALTERNATIVE_LINK_NAME[depmod] = "${base_sbindir}/depmod"
77ALTERNATIVE_LINK_NAME[insmod] = "${base_sbindir}/insmod"
78ALTERNATIVE_LINK_NAME[modprobe] = "${base_sbindir}/modprobe"
79ALTERNATIVE_LINK_NAME[rmmod] = "${base_sbindir}/rmmod"
80ALTERNATIVE_LINK_NAME[modinfo] = "${base_sbindir}/modinfo"
81ALTERNATIVE_LINK_NAME[bin-lsmod] = "${base_bindir}/lsmod"
82ALTERNATIVE_LINK_NAME[lsmod] = "${base_sbindir}/lsmod"
83ALTERNATIVE_TARGET[lsmod] = "${base_bindir}/lsmod.${BPN}"
84
85PACKAGES =+ "libkmod"
86FILES:libkmod = "${base_libdir}/libkmod*${SOLIBS} ${libdir}/libkmod*${SOLIBS}"
87FILES:${PN} += "${nonarch_base_libdir}/depmod.d ${nonarch_base_libdir}/modprobe.d"
88
89BBCLASSEXTEND = "native nativesdk"
90