1SUMMARY = "The X.Org X server"
2HOMEPAGE = "http://www.x.org"
3SECTION = "x11/base"
4LICENSE = "MIT-X"
5LIC_FILES_CHKSUM = "file://COPYING;md5=5df87950af51ac2c5822094553ea1880"
6
7# xf86-*-* packages depend on an X server built with the xfree86 DDX
8# so we have a virtual to represent that:
9# deprecated, we should use virtual/xserver instead
10PROVIDES = "virtual/xserver-xf86"
11
12# Other packages tend to just care that there is *an* X server:
13PROVIDES += "virtual/xserver"
14
15PE = "2"
16
17XORG_PN = "xorg-server"
18SRC_URI = "${XORG_MIRROR}/individual/xserver/${XORG_PN}-${PV}.tar.bz2"
19
20CVE_PRODUCT = "xorg-server"
21
22S = "${WORKDIR}/${XORG_PN}-${PV}"
23
24inherit autotools pkgconfig
25
26inherit features_check
27REQUIRED_DISTRO_FEATURES = "x11"
28
29LIB_DEPS = "pixman libxfont2 xtrans libxau libxext libxdmcp libdrm libxkbfile libpciaccess"
30DEPENDS = "xorgproto ${LIB_DEPS} font-util"
31
32# Split out some modules and extensions from the main package
33# These aren't needed for basic operations and only take up space:
34#  32.0k   libdri.so
35#  91.0k   libexa.so
36#  336.0k  libglx.so
37#  1360k   libint10.so
38#  180.0k  libwfb.so
39#  320.0k  libxaa.so
40#  124.0k  libxf1bpp.so
41#  84.0k   libxf4bpp.so
42#          librecord.so
43#          libextmod.so
44#          libdbe.so
45
46PACKAGES =+ "${PN}-sdl \
47             ${PN}-fbdev \
48             ${PN}-xvfb \
49             ${PN}-utils \
50             ${PN}-xephyr \
51             ${PN}-xwayland \
52             ${PN}-multimedia-modules \
53             ${PN}-extension-dri \
54             ${PN}-extension-dri2 \
55             ${PN}-extension-glx \
56             ${PN}-extension-record \
57             ${PN}-extension-extmod \
58             ${PN}-extension-dbe \
59             ${PN}-module-libint10 \
60             ${PN}-module-libafb \
61             ${PN}-module-libwfb  \
62             ${PN}-module-libmfb \
63             ${PN}-module-libcfb \
64             ${PN}-module-exa \
65             ${PN}-module-xaa \
66             ${PN}-module-libxf1bpp \
67             ${PN}-module-libxf4bpp \
68             xf86-video-modesetting"
69
70SUMMARY_xf86-video-modesetting = "X.Org X server -- modesetting display driver"
71INSANE_SKIP_${MLPREFIX}xf86-video-modesetting = "xorg-driver-abi"
72
73XSERVER_RRECOMMENDS = "xkeyboard-config rgb xserver-xf86-config xkbcomp xf86-input-libinput"
74RRECOMMENDS_${PN} += "${XSERVER_RRECOMMENDS}"
75RRECOMMENDS_${PN}-xwayland += "${XSERVER_RRECOMMENDS}"
76RDEPENDS_${PN}-xvfb += "xkeyboard-config"
77RDEPENDS_${PN}-module-exa = "${PN} (= ${EXTENDPKGV})"
78
79FILES_${PN} = "${bindir} ${libdir}/X11/Options ${libdir}/X11/Cards ${libdir}/X11/getconfig ${libdir}/X11/etc ${libdir}/modules/*.so ${libdir}/xorg/modules/*.so /etc/X11 ${libdir}/xorg/protocol.txt ${datadir}/X11/xorg.conf.d"
80FILES_${PN}-dev += "${libdir}/xorg/modules/*.la ${libdir}/xorg/modules/*/*.la"
81FILES_${PN}-doc += "${libdir}/X11/doc ${datadir}/X11/xkb/compiled/README.compiled ${localstatedir}/lib/xkb/README.compiled"
82FILES_${PN}-sdl = "${bindir}/Xsdl"
83FILES_${PN}-fbdev = "${bindir}/Xfbdev"
84FILES_${PN}-xvfb = "${bindir}/Xvfb"
85FILES_${PN}-utils = "${bindir}/scanpci ${bindir}/pcitweak ${bindir}/ioport ${bindir}/in[bwl] ${bindir}/out[bwl] ${bindir}/mmap[rw] ${bindir}/gtf ${bindir}/getconfig ${bindir}/getconfig.pl"
86FILES_${PN}-xephyr = "${bindir}/Xephyr"
87FILES_${PN}-xwayland = "${bindir}/Xwayland"
88FILES_${PN}-multimedia-modules = "${libdir}/xorg/modules/multimedia/*drv*"
89FILES_${PN}-extension-dri = "${libdir}/xorg/modules/extensions/libdri.so"
90FILES_${PN}-extension-dri2 = "${libdir}/xorg/modules/extensions/libdri2.so"
91FILES_${PN}-extension-glx = "${libdir}/xorg/modules/extensions/libglx.so"
92FILES_${PN}-extension-record = "${libdir}/xorg/modules/extensions/librecord.so"
93FILES_${PN}-extension-extmod = "${libdir}/xorg/modules/extensions/libextmod.so"
94FILES_${PN}-extension-dbe = "${libdir}/xorg/modules/extensions/libdbe.so"
95FILES_${PN}-module-libint10 = "${libdir}/xorg/modules/libint10.so"
96FILES_${PN}-module-libafb = "${libdir}/xorg/modules/libafb.so"
97FILES_${PN}-module-libwfb = "${libdir}/xorg/modules/libwfb.so"
98FILES_${PN}-module-libmfb = "${libdir}/xorg/modules/libmfb.so"
99FILES_${PN}-module-libcfb = "${libdir}/xorg/modules/libcfb.so"
100FILES_${PN}-module-exa = "${libdir}/xorg/modules/libexa.so"
101FILES_${PN}-module-xaa = "${libdir}/xorg/modules/libxaa.so"
102FILES_${PN}-module-libxf1bpp = "${libdir}/xorg/modules/libxf1bpp.so"
103FILES_${PN}-module-libxf4bpp = "${libdir}/xorg/modules/libxf4bpp.so"
104FILES_xf86-video-modesetting = "${libdir}/xorg/modules/drivers/modesetting_drv.so"
105
106EXTRA_OECONF += "--with-fop=no \
107                 --with-pic \
108                 --disable-static \
109                 --disable-record \
110                 --disable-dmx \
111                 --disable-xnest \
112                 --enable-xvfb \
113                 --enable-composite \
114                 --without-dtrace \
115                 --with-int10=x86emu \
116                 --sysconfdir=/etc/X11 \
117                 --localstatedir=/var \
118                 --with-xkb-output=/var/lib/xkb \
119                 --with-os-name=Linux \
120"
121
122OPENGL_PKGCONFIGS = "dri glx glamor dri3 xshmfence"
123PACKAGECONFIG ??= "dga dri2 udev ${XORG_CRYPTO} \
124                   ${@bb.utils.contains('DISTRO_FEATURES', 'opengl', '${OPENGL_PKGCONFIGS}', '', d)} \
125                   ${@bb.utils.contains('DISTRO_FEATURES', 'opengl wayland', 'xwayland', '', d)} \
126                   ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'systemd systemd-logind', '', d)} \
127"
128
129PACKAGECONFIG[udev] = "--enable-config-udev,--disable-config-udev,udev"
130PACKAGECONFIG[dga] = "--enable-dga,--disable-dga"
131PACKAGECONFIG[dri] = "--enable-dri,--disable-dri,virtual/mesa"
132PACKAGECONFIG[dri2] = "--enable-dri2,--disable-dri2"
133# DRI3 requires xshmfence to also be enabled
134PACKAGECONFIG[dri3] = "--enable-dri3,--disable-dri3"
135PACKAGECONFIG[glx] = "--enable-glx,--disable-glx,virtual/libgl virtual/libx11"
136PACKAGECONFIG[glamor] = "--enable-glamor,--disable-glamor,libepoxy virtual/libgbm,libegl"
137PACKAGECONFIG[unwind] = "--enable-libunwind,--disable-libunwind,libunwind"
138PACKAGECONFIG[xshmfence] = "--enable-xshmfence,--disable-xshmfence,libxshmfence"
139PACKAGECONFIG[xmlto] = "--with-xmlto, --without-xmlto, xmlto-native docbook-xml-dtd4-native docbook-xsl-stylesheets-native"
140PACKAGECONFIG[systemd-logind] = "--enable-systemd-logind=yes,--enable-systemd-logind=no,dbus,"
141PACKAGECONFIG[systemd] = "--with-systemd-daemon,--without-systemd-daemon,systemd"
142PACKAGECONFIG[xinerama] = "--enable-xinerama,--disable-xinerama"
143PACKAGECONFIG[xwayland] = "--enable-xwayland,--disable-xwayland,wayland wayland-native wayland-protocols libepoxy"
144
145# Xorg requires a SHA1 implementation, pick one
146XORG_CRYPTO ??= "openssl"
147PACKAGECONFIG[openssl] = "--with-sha1=libcrypto,,openssl"
148PACKAGECONFIG[nettle] = "--with-sha1=libnettle,,nettle"
149PACKAGECONFIG[gcrypt] = "--with-sha1=libgcrypt,,libgcrypt"
150
151do_install_append () {
152	# Its assumed base-files creates this for us
153	rmdir ${D}${localstatedir}/log/
154        sed -i -e 's,${libdir}/xorg/modules,${prefix}/lib*/xorg/modules,' ${D}${mandir}/man5/xorg.conf.5
155}
156
157# Add runtime provides for the ABI versions of the video and input subsystems,
158# so that drivers can depend on the relevant version.
159python populate_packages_prepend() {
160    import subprocess
161
162    # Set PKG_CONFIG_PATH so pkg-config looks at the .pc files that are going
163    # into the new package, not the staged ones.
164    newenv = dict(os.environ)
165    newenv["PKG_CONFIG_PATH"] = d.expand("${PKGD}${libdir}/pkgconfig/")
166
167    def get_abi(name):
168        abis = {
169          "video": "abi_videodrv",
170          "input": "abi_xinput"
171        }
172        p = subprocess.Popen(args="pkg-config --variable=%s xorg-server" % abis[name],
173                             shell=True, env=newenv, stdout=subprocess.PIPE)
174        stdout, stderr = p.communicate()
175        output = stdout.decode("utf-8").split(".")[0]
176        mlprefix = d.getVar('MLPREFIX') or ''
177        return "%sxorg-abi-%s-%s" % (mlprefix, name, output)
178
179    pn = d.getVar("PN")
180    d.appendVar("RPROVIDES_" + pn, " " + get_abi("input"))
181    d.appendVar("RPROVIDES_" + pn, " " + get_abi("video"))
182}
183