1SUMMARY = "OpenGL driver testing framework"
2DESCRIPTION = "Piglit is an open-source test suite for OpenGL and OpenCL \
3implementations."
4HOMEPAGE = "https://gitlab.freedesktop.org/mesa/piglit"
5BUGTRACKER = "https://gitlab.freedesktop.org/mesa/piglit/-/issues"
6LICENSE = "MIT & LGPL-2.0-or-later & GPL-3.0-only & GPL-2.0-or-later & BSD-3-Clause"
7LIC_FILES_CHKSUM = "file://COPYING;md5=b2beded7103a3d8a442a2a0391d607b0"
8
9SRC_URI = "git://gitlab.freedesktop.org/mesa/piglit.git;protocol=https;branch=main \
10           file://0001-cmake-install-bash-completions-in-the-right-place.patch \
11           file://0001-cmake-use-proper-WAYLAND_INCLUDE_DIRS-variable.patch \
12           file://0002-tests-util-piglit-shader.c-do-not-hardcode-build-pat.patch \
13           file://0001-CMakeLists.txt-add-missing-endian.h-check.patch \
14           "
15UPSTREAM_CHECK_COMMITS = "1"
16
17SRCREV = "c107462e4e429fa1cf6daac39168674c1c0c9fd4"
18# (when PV goes above 1.0 remove the trailing r)
19PV = "1.0+gitr${SRCPV}"
20
21S = "${WORKDIR}/git"
22
23X11_DEPS = "${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'virtual/libx11 libxrender libglu', '', d)}"
24X11_RDEPS = "${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'mesa-demos', '', d)}"
25
26DEPENDS = "libpng waffle libxkbcommon python3-mako-native python3-numpy-native python3-six-native virtual/egl"
27
28inherit cmake pkgconfig python3native features_check bash-completion
29
30# depends on virtual/libgl
31REQUIRED_DISTRO_FEATURES += "opengl"
32
33# The built scripts go into the temporary directory according to tempfile
34# (typically /tmp) which can race if multiple builds happen on the same machine,
35# so tell it to use a directory in ${B} to avoid overwriting.
36export TEMP = "${B}/temp/"
37do_compile[dirs] =+ "${B}/temp/"
38
39PACKAGECONFIG ??= "${@bb.utils.filter('DISTRO_FEATURES', 'x11', d)}"
40PACKAGECONFIG[freeglut] = "-DPIGLIT_USE_GLUT=1,-DPIGLIT_USE_GLUT=0,freeglut,"
41PACKAGECONFIG[x11] = "-DPIGLIT_BUILD_GL_TESTS=ON,-DPIGLIT_BUILD_GL_TESTS=OFF,${X11_DEPS}, ${X11_RDEPS}"
42PACKAGECONFIG[vulkan] = "-DPIGLIT_BUILD_VK_TESTS=ON,-DPIGLIT_BUILD_VK_TESTS=OFF,vulkan-loader"
43
44export PIGLIT_BUILD_DIR = "../../../../git"
45
46do_configure:prepend() {
47   if [ "${@bb.utils.contains('PACKAGECONFIG', 'freeglut', 'yes', 'no', d)}" = "no" ]; then
48        sed -i -e "/^#.*include <GL\/freeglut_ext.h>$/d" ${S}/src/piglit/glut_wrap.h
49        sed -i -e "/^#.*include.*<GL\/glut.h>$/d" ${S}/src/piglit/glut_wrap.h
50   fi
51}
52
53# Forcibly strip because Piglit is *huge*
54OECMAKE_TARGET_INSTALL = "install/strip"
55
56RDEPENDS:${PN} = "waffle waffle-bin python3 python3-mako python3-json \
57	python3-misc \
58	python3-unixadmin python3-xml python3-multiprocessing \
59	python3-six python3-shell python3-io \
60	python3-netserver bash \
61	"
62
63INSANE_SKIP:${PN} += "dev-so already-stripped"
64
65# As nothing builds against Piglit we don't need to have anything in the
66# sysroot, especially when this is ~2GB of test suite
67SYSROOT_DIRS:remove = "${libdir}"
68
69# Can't be built with ccache
70CCACHE_DISABLE = "1"
71