1SUMMARY = "OpenGL driver testing framework"
2LICENSE = "MIT & LGPLv2+ & GPLv3 & GPLv2+ & BSD-3-Clause"
3LIC_FILES_CHKSUM = "file://COPYING;md5=b2beded7103a3d8a442a2a0391d607b0"
4
5SRC_URI = "git://anongit.freedesktop.org/piglit \
6           file://0001-cmake-install-bash-completions-in-the-right-place.patch \
7           file://0001-tests-Use-FE_UPWARD-only-if-its-defined-in-fenv.h.patch \
8           file://0001-cmake-use-proper-WAYLAND_INCLUDE_DIRS-variable.patch \
9           file://format-fix.patch \
10           "
11UPSTREAM_CHECK_COMMITS = "1"
12
13# From 2018-10-26
14SRCREV = "b9066c7717af1d169a616c9e61706b99ff8515b5"
15# (when PV goes above 1.0 remove the trailing r)
16PV = "1.0+gitr${SRCPV}"
17
18S = "${WORKDIR}/git"
19
20X11_DEPS = "${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'virtual/libx11 libxrender libglu', '', d)}"
21X11_RDEPS = "${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'mesa-demos', '', d)}"
22
23DEPENDS = "libpng waffle libxkbcommon virtual/libgl python3-mako-native python3-numpy-native python3-six-native virtual/egl"
24
25inherit cmake pkgconfig python3native distro_features_check bash-completion
26
27# depends on virtual/libgl
28REQUIRED_DISTRO_FEATURES += "opengl"
29
30# The built scripts go into the temporary directory according to tempfile
31# (typically /tmp) which can race if multiple builds happen on the same machine,
32# so tell it to use a directory in ${B} to avoid overwriting.
33export TEMP = "${B}/temp/"
34do_compile[dirs] =+ "${B}/temp/"
35
36PACKAGECONFIG ??= "${@bb.utils.filter('DISTRO_FEATURES', 'x11', d)}"
37PACKAGECONFIG[freeglut] = "-DPIGLIT_USE_GLUT=1,-DPIGLIT_USE_GLUT=0,freeglut,"
38PACKAGECONFIG[x11] = "-DPIGLIT_BUILD_GL_TESTS=ON,-DPIGLIT_BUILD_GL_TESTS=OFF,${X11_DEPS}, ${X11_RDEPS}"
39
40
41do_configure_prepend() {
42   if [ "${@bb.utils.contains('PACKAGECONFIG', 'freeglut', 'yes', 'no', d)}" = "no" ]; then
43        sed -i -e "/^#.*include <GL\/freeglut_ext.h>$/d" ${S}/src/piglit/glut_wrap.h
44        sed -i -e "/^#.*include.*<GL\/glut.h>$/d" ${S}/src/piglit/glut_wrap.h
45   fi
46}
47
48OECMAKE_TARGET_INSTALL = "install/strip"
49
50RDEPENDS_${PN} = "waffle waffle-bin python3 python3-mako python3-json \
51	python3-misc \
52	python3-unixadmin python3-xml python3-multiprocessing \
53	python3-six python3-shell python3-io \
54	python3-netserver bash \
55	"
56
57INSANE_SKIP_${PN} += "dev-so already-stripped"
58
59# Can't be built with ccache
60CCACHE_DISABLE = "1"
61