1SUMMARY = "OpenGL driver testing framework"
2DESCRIPTION = "Piglit is an open-source test suite for OpenGL and OpenCL \
3implementations."
4HOMEPAGE = "https://gitlab.freedesktop.org/mesa/piglit"
5BUGTRACKER = "https://gitlab.freedesktop.org/mesa/piglit/-/issues"
6LICENSE = "MIT & LGPLv2+ & GPLv3 & GPLv2+ & BSD-3-Clause"
7LIC_FILES_CHKSUM = "file://COPYING;md5=b2beded7103a3d8a442a2a0391d607b0"
8
9SRC_URI = "git://gitlab.freedesktop.org/mesa/piglit.git;protocol=https \
10           file://0001-cmake-install-bash-completions-in-the-right-place.patch \
11           file://0001-cmake-use-proper-WAYLAND_INCLUDE_DIRS-variable.patch \
12           file://0001-Add-a-missing-include-for-htobe32-definition.patch \
13           file://0001-generated_tests-gen_tcs-tes_input_tests.py-do-not-ha.patch \
14           file://0002-tests-util-piglit-shader.c-do-not-hardcode-build-pat.patch \
15           file://0001-serializer.py-make-.gz-files-reproducible.patch \
16           file://0001-framework-profile.py-make-test-lists-reproducible.patch \
17           file://0001-tests-shader.py-sort-the-file-list-before-working-on.patch \
18           "
19UPSTREAM_CHECK_COMMITS = "1"
20
21SRCREV = "d4d9353b7290ed22cb7349226a8e4017402d3f02"
22# (when PV goes above 1.0 remove the trailing r)
23PV = "1.0+gitr${SRCPV}"
24
25S = "${WORKDIR}/git"
26
27X11_DEPS = "${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'virtual/libx11 libxrender libglu', '', d)}"
28X11_RDEPS = "${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'mesa-demos', '', d)}"
29
30DEPENDS = "libpng waffle libxkbcommon virtual/libgl python3-mako-native python3-numpy-native python3-six-native virtual/egl"
31
32inherit cmake pkgconfig python3native features_check bash-completion
33
34# depends on virtual/libgl
35REQUIRED_DISTRO_FEATURES += "opengl"
36
37# The built scripts go into the temporary directory according to tempfile
38# (typically /tmp) which can race if multiple builds happen on the same machine,
39# so tell it to use a directory in ${B} to avoid overwriting.
40export TEMP = "${B}/temp/"
41do_compile[dirs] =+ "${B}/temp/"
42
43PACKAGECONFIG ??= "${@bb.utils.filter('DISTRO_FEATURES', 'x11', d)}"
44PACKAGECONFIG[freeglut] = "-DPIGLIT_USE_GLUT=1,-DPIGLIT_USE_GLUT=0,freeglut,"
45PACKAGECONFIG[x11] = "-DPIGLIT_BUILD_GL_TESTS=ON,-DPIGLIT_BUILD_GL_TESTS=OFF,${X11_DEPS}, ${X11_RDEPS}"
46
47export PIGLIT_BUILD_DIR = "../../../../git"
48
49do_configure_prepend() {
50   if [ "${@bb.utils.contains('PACKAGECONFIG', 'freeglut', 'yes', 'no', d)}" = "no" ]; then
51        sed -i -e "/^#.*include <GL\/freeglut_ext.h>$/d" ${S}/src/piglit/glut_wrap.h
52        sed -i -e "/^#.*include.*<GL\/glut.h>$/d" ${S}/src/piglit/glut_wrap.h
53   fi
54}
55
56# Forcibly strip because Piglit is *huge*
57OECMAKE_TARGET_INSTALL = "install/strip"
58
59RDEPENDS_${PN} = "waffle waffle-bin python3 python3-mako python3-json \
60	python3-misc \
61	python3-unixadmin python3-xml python3-multiprocessing \
62	python3-six python3-shell python3-io \
63	python3-netserver bash \
64	"
65
66INSANE_SKIP_${PN} += "dev-so already-stripped"
67
68# As nothing builds against Piglit we don't need to have anything in the
69# sysroot, especially when this is ~2GB of test suite
70SYSROOT_DIRS_remove = "${libdir}"
71
72# Can't be built with ccache
73CCACHE_DISABLE = "1"
74