1SUMMARY = "OpenGL driver testing framework"
2DESCRIPTION = "Piglit is an open-source test suite for OpenGL and OpenCL \
3implementations."
4HOMEPAGE = "https://gitlab.freedesktop.org/mesa/piglit"
5BUGTRACKER = "https://gitlab.freedesktop.org/mesa/piglit/-/issues"
6LICENSE = "MIT & LGPL-2.0-or-later & GPL-3.0-only & GPL-2.0-or-later & BSD-3-Clause"
7LIC_FILES_CHKSUM = "file://COPYING;md5=b2beded7103a3d8a442a2a0391d607b0"
8
9SRC_URI = "git://gitlab.freedesktop.org/mesa/piglit.git;protocol=https;branch=main \
10           file://0002-cmake-use-proper-WAYLAND_INCLUDE_DIRS-variable.patch \
11           file://0003-tests-util-piglit-shader.c-do-not-hardcode-build-pat.patch \
12           file://0001-tests-Fix-narrowing-errors-seen-with-clang.patch \
13           "
14UPSTREAM_CHECK_COMMITS = "1"
15
16SRCREV = "71c21b1157c4f9a96453bdfcb9f4dda091360afd"
17# (when PV goes above 1.0 remove the trailing r)
18PV = "1.0+gitr"
19
20S = "${WORKDIR}/git"
21
22X11_DEPS = "${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'virtual/libx11 libxrender libglu', '', d)}"
23X11_RDEPS = "${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'mesa-demos', '', d)}"
24
25DEPENDS = "libpng waffle libxkbcommon python3-mako-native python3-numpy-native python3-six-native virtual/egl"
26
27inherit cmake pkgconfig python3native features_check bash-completion
28
29# depends on virtual/libgl
30REQUIRED_DISTRO_FEATURES += "opengl"
31
32# The built scripts go into the temporary directory according to tempfile
33# (typically /tmp) which can race if multiple builds happen on the same machine,
34# so tell it to use a directory in ${B} to avoid overwriting.
35export TEMP = "${B}/temp/"
36do_compile[dirs] =+ "${B}/temp/"
37
38PACKAGECONFIG ??= "${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'x11 glx', '', d)}"
39PACKAGECONFIG[freeglut] = "-DPIGLIT_USE_GLUT=1,-DPIGLIT_USE_GLUT=0,freeglut,"
40PACKAGECONFIG[glx] = "-DPIGLIT_BUILD_GLX_TESTS=ON,-DPIGLIT_BUILD_GLX_TESTS=OFF"
41PACKAGECONFIG[opencl] = "-DPIGLIT_BUILD_CL_TESTS=ON,-DPIGLIT_BUILD_CL_TESTS=OFF,virtual/opencl-icd"
42PACKAGECONFIG[x11] = "-DPIGLIT_BUILD_GL_TESTS=ON,-DPIGLIT_BUILD_GL_TESTS=OFF,${X11_DEPS}, ${X11_RDEPS}"
43PACKAGECONFIG[vulkan] = "-DPIGLIT_BUILD_VK_TESTS=ON,-DPIGLIT_BUILD_VK_TESTS=OFF,glslang-native vulkan-loader,glslang"
44
45export PIGLIT_BUILD_DIR = "../../../../git"
46
47do_configure:prepend() {
48   if [ "${@bb.utils.contains('PACKAGECONFIG', 'freeglut', 'yes', 'no', d)}" = "no" ]; then
49        sed -i -e "/^#.*include <GL\/freeglut_ext.h>$/d" ${S}/src/piglit/glut_wrap.h
50        sed -i -e "/^#.*include.*<GL\/glut.h>$/d" ${S}/src/piglit/glut_wrap.h
51   fi
52}
53
54# Forcibly strip because Piglit is *huge*, and don't bother trying to split/strip the result.
55OECMAKE_TARGET_INSTALL = "install/strip"
56INHIBIT_PACKAGE_STRIP = "1"
57INHIBIT_PACKAGE_DEBUG_SPLIT = "1"
58
59RDEPENDS:${PN} = "waffle waffle-bin python3 python3-mako python3-json \
60	python3-misc \
61	python3-unixadmin python3-xml python3-multiprocessing \
62	python3-six python3-shell python3-io \
63	python3-netserver bash \
64	"
65
66INSANE_SKIP:${PN} += "dev-so already-stripped"
67
68# As nothing builds against Piglit we don't need to have anything in the
69# sysroot, especially when this is ~2GB of test suite
70SYSROOT_DIRS:remove = "${libdir}"
71
72# Can't be built with ccache
73CCACHE_DISABLE = "1"
74