1SUMMARY = "OpenGL driver testing framework"
2DESCRIPTION = "Piglit is an open-source test suite for OpenGL and OpenCL \
3implementations."
4LICENSE = "MIT & LGPLv2+ & GPLv3 & GPLv2+ & BSD-3-Clause"
5LIC_FILES_CHKSUM = "file://COPYING;md5=b2beded7103a3d8a442a2a0391d607b0"
6
7SRC_URI = "git://gitlab.freedesktop.org/mesa/piglit.git;protocol=https \
8           file://0001-cmake-install-bash-completions-in-the-right-place.patch \
9           file://0001-cmake-use-proper-WAYLAND_INCLUDE_DIRS-variable.patch \
10           "
11UPSTREAM_CHECK_COMMITS = "1"
12
13SRCREV = "7d76fca56e8ca72ab6809f6f0234b5971af5690a"
14# (when PV goes above 1.0 remove the trailing r)
15PV = "1.0+gitr${SRCPV}"
16
17S = "${WORKDIR}/git"
18
19X11_DEPS = "${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'virtual/libx11 libxrender libglu', '', d)}"
20X11_RDEPS = "${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'mesa-demos', '', d)}"
21
22DEPENDS = "libpng waffle libxkbcommon virtual/libgl python3-mako-native python3-numpy-native python3-six-native virtual/egl"
23
24inherit cmake pkgconfig python3native features_check bash-completion
25
26# depends on virtual/libgl
27REQUIRED_DISTRO_FEATURES += "opengl"
28
29# The built scripts go into the temporary directory according to tempfile
30# (typically /tmp) which can race if multiple builds happen on the same machine,
31# so tell it to use a directory in ${B} to avoid overwriting.
32export TEMP = "${B}/temp/"
33do_compile[dirs] =+ "${B}/temp/"
34
35PACKAGECONFIG ??= "${@bb.utils.filter('DISTRO_FEATURES', 'x11', d)}"
36PACKAGECONFIG[freeglut] = "-DPIGLIT_USE_GLUT=1,-DPIGLIT_USE_GLUT=0,freeglut,"
37PACKAGECONFIG[x11] = "-DPIGLIT_BUILD_GL_TESTS=ON,-DPIGLIT_BUILD_GL_TESTS=OFF,${X11_DEPS}, ${X11_RDEPS}"
38
39
40do_configure_prepend() {
41   if [ "${@bb.utils.contains('PACKAGECONFIG', 'freeglut', 'yes', 'no', d)}" = "no" ]; then
42        sed -i -e "/^#.*include <GL\/freeglut_ext.h>$/d" ${S}/src/piglit/glut_wrap.h
43        sed -i -e "/^#.*include.*<GL\/glut.h>$/d" ${S}/src/piglit/glut_wrap.h
44   fi
45}
46
47# Forcibly strip because Piglit is *huge*
48OECMAKE_TARGET_INSTALL = "install/strip"
49
50RDEPENDS_${PN} = "waffle waffle-bin python3 python3-mako python3-json \
51	python3-misc \
52	python3-unixadmin python3-xml python3-multiprocessing \
53	python3-six python3-shell python3-io \
54	python3-netserver bash \
55	"
56
57INSANE_SKIP_${PN} += "dev-so already-stripped"
58
59# As nothing builds against Piglit we don't need to have anything in the
60# sysroot, especially when this is ~2GB of test suite
61SYSROOT_DIRS_remove = "${libdir}"
62
63# Can't be built with ccache
64CCACHE_DISABLE = "1"
65