1SUMMARY = "A free implementation of the OpenGL API"
2DESCRIPTION = "Mesa is an open-source implementation of the OpenGL specification - \
3a system for rendering interactive 3D graphics.  \
4A variety of device drivers allows Mesa to be used in many different environments \
5ranging from software emulation to complete hardware acceleration for modern GPUs. \
6Mesa is used as part of the overall Direct Rendering Infrastructure and X.org \
7environment."
8
9HOMEPAGE = "http://mesa3d.org"
10BUGTRACKER = "https://bugs.freedesktop.org"
11SECTION = "x11"
12LICENSE = "MIT"
13LIC_FILES_CHKSUM = "file://docs/license.html;md5=c1843d93c460bbf778d6037ce324f9f7"
14
15PE = "2"
16
17SRC_URI = "https://mesa.freedesktop.org/archive/mesa-${PV}.tar.xz \
18           file://0001-meson.build-check-for-all-linux-host_os-combinations.patch \
19           file://0002-meson.build-make-TLS-ELF-optional.patch \
20           file://0003-Allow-enable-DRI-without-DRI-drivers.patch \
21           file://0004-Revert-mesa-Enable-asm-unconditionally-now-that-gen_.patch \
22           file://0005-vc4-use-intmax_t-for-formatted-output-of-timespec-me.patch \
23           file://0001-meson-misdetects-64bit-atomics-on-mips-clang.patch \
24           "
25
26SRC_URI[sha256sum] = "283dff72814c8a80ce1ff8271e3f055895d26f4da3f4362acc49193e635780cb"
27
28UPSTREAM_CHECK_GITTAGREGEX = "mesa-(?P<pver>\d+(\.\d+)+)"
29
30#because we cannot rely on the fact that all apps will use pkgconfig,
31#make eglplatform.h independent of MESA_EGL_NO_X11_HEADER
32do_install_append() {
33    if ${@bb.utils.contains('PACKAGECONFIG', 'egl', 'true', 'false', d)}; then
34        sed -i -e 's/^#elif defined(__unix__) && defined(EGL_NO_X11)$/#elif defined(__unix__) \&\& defined(EGL_NO_X11) || ${@bb.utils.contains('PACKAGECONFIG', 'x11', '0', '1', d)}/' ${D}${includedir}/EGL/eglplatform.h
35    fi
36}
37
38DEPENDS = "expat makedepend-native flex-native bison-native libxml2-native zlib chrpath-replacement-native python3-mako-native gettext-native"
39EXTRANATIVEPATH += "chrpath-native"
40PROVIDES = " \
41    ${@bb.utils.contains('PACKAGECONFIG', 'opengl', 'virtual/libgl', '', d)} \
42    ${@bb.utils.contains('PACKAGECONFIG', 'gles', 'virtual/libgles1 virtual/libgles2', '', d)} \
43    ${@bb.utils.contains('PACKAGECONFIG', 'egl', 'virtual/egl', '', d)} \
44    ${@bb.utils.contains('PACKAGECONFIG', 'gbm', 'virtual/libgbm', '', d)} \
45    virtual/mesa \
46    "
47
48inherit meson pkgconfig python3native gettext features_check
49
50# Unset these to stop python trying to report the target Python setup
51_PYTHON_SYSCONFIGDATA_NAME[unexport] = "1"
52STAGING_INCDIR[unexport] = "1"
53STAGING_LIBDIR[unexport] = "1"
54
55BBCLASSEXTEND = "native nativesdk"
56
57ANY_OF_DISTRO_FEATURES_class-target = "opengl vulkan"
58
59PLATFORMS ??= "${@bb.utils.filter('PACKAGECONFIG', 'x11 wayland', d)} \
60               ${@bb.utils.contains('PACKAGECONFIG', 'gbm', 'drm', '', d)} \
61               surfaceless"
62
63export YOCTO_ALTERNATE_EXE_PATH = "${STAGING_LIBDIR}/llvm${MESA_LLVM_RELEASE}/llvm-config"
64export YOCTO_ALTERNATE_MULTILIB_NAME = "${base_libdir}"
65export LLVM_CONFIG = "${STAGING_BINDIR_NATIVE}/llvm-config${MESA_LLVM_RELEASE}"
66export WANT_LLVM_RELEASE = "${MESA_LLVM_RELEASE}"
67
68MESA_LLVM_RELEASE ?= "${LLVMVERSION}"
69
70# set the MESA_BUILD_TYPE to either 'release' (default) or 'debug'
71# by default the upstream mesa sources build a debug release
72# here we assume the user will want a release build by default
73MESA_BUILD_TYPE ?= "release"
74def check_buildtype(d):
75    _buildtype = d.getVar('MESA_BUILD_TYPE')
76    if _buildtype not in ['release', 'debug']:
77        bb.fatal("unknown build type (%s), please set MESA_BUILD_TYPE to either 'release' or 'debug'" % _buildtype)
78    if _buildtype == 'debug':
79        return 'debugoptimized'
80    return 'plain'
81MESON_BUILDTYPE = "${@check_buildtype(d)}"
82
83EXTRA_OEMESON = " \
84    -Dshared-glapi=true \
85    -Dgallium-opencl=disabled \
86    -Dglx-read-only-text=true \
87    -Dplatforms='${@",".join("${PLATFORMS}".split())}' \
88"
89
90PACKAGECONFIG_class-target ??= "${@bb.utils.filter('DISTRO_FEATURES', 'wayland vulkan', d)} \
91                   ${@bb.utils.contains('DISTRO_FEATURES', 'opengl', 'opengl egl gles gbm dri gallium virgl', '', d)} \
92                   ${@bb.utils.contains('DISTRO_FEATURES', 'x11 opengl', 'x11 dri3', '', d)} \
93                   ${@bb.utils.contains('DISTRO_FEATURES', 'x11 vulkan', 'dri3', '', d)} \
94                   elf-tls \
95		   "
96PACKAGECONFIG_class-native ?= "gbm dri egl opengl elf-tls x11"
97PACKAGECONFIG_class-nativesdk ?= "gbm dri egl opengl elf-tls x11"
98
99PACKAGECONFIG_remove_libc-musl = "elf-tls"
100
101# "gbm" requires "dri", "opengl"
102PACKAGECONFIG[gbm] = "-Dgbm=true,-Dgbm=false"
103
104X11_DEPS = "xorgproto virtual/libx11 libxext libxxf86vm libxdamage libxfixes xrandr"
105# "x11" requires "opengl"
106PACKAGECONFIG[x11] = ",-Dglx=disabled,${X11_DEPS}"
107PACKAGECONFIG[elf-tls] = "-Delf-tls=true, -Delf-tls=false"
108PACKAGECONFIG[xvmc] = "-Dgallium-xvmc=true,-Dgallium-xvmc=false,libxvmc"
109PACKAGECONFIG[wayland] = ",,wayland-native wayland libdrm wayland-protocols"
110
111DRIDRIVERS_class-native = "swrast"
112DRIDRIVERS_class-nativesdk = "swrast"
113DRIDRIVERS_append_x86_class-target = ",r100,r200,nouveau,i965,i915"
114DRIDRIVERS_append_x86-64_class-target = ",r100,r200,nouveau,i965,i915"
115# "dri" requires "opengl"
116PACKAGECONFIG[dri] = "-Ddri=true -Ddri-drivers=${DRIDRIVERS}, -Ddri=false -Ddri-drivers='', xorgproto libdrm"
117PACKAGECONFIG[dri3] = "-Ddri3=true, -Ddri3=false, xorgproto libxshmfence"
118
119# Vulkan drivers need dri3 enabled
120# radeon could be enabled as well but requires gallium-llvm with llvm >= 3.9
121VULKAN_DRIVERS = ""
122VULKAN_DRIVERS_append_x86_class-target = ",intel"
123VULKAN_DRIVERS_append_x86-64_class-target = ",intel"
124PACKAGECONFIG[vulkan] = "-Dvulkan-drivers=${VULKAN_DRIVERS}, -Dvulkan-drivers='',"
125
126PACKAGECONFIG[opengl] = "-Dopengl=true, -Dopengl=false"
127
128# "gles" requires "opengl"
129PACKAGECONFIG[gles] = "-Dgles1=true -Dgles2=true, -Dgles1=false -Dgles2=false"
130
131# "egl" requires "dri", "opengl"
132PACKAGECONFIG[egl] = "-Degl=true, -Degl=false"
133
134PACKAGECONFIG[etnaviv] = ""
135PACKAGECONFIG[freedreno] = ""
136PACKAGECONFIG[kmsro] = ""
137PACKAGECONFIG[vc4] = ""
138PACKAGECONFIG[v3d] = ""
139
140GALLIUMDRIVERS = "swrast"
141# gallium swrast was found to crash Xorg on startup in x32 qemu
142GALLIUMDRIVERS_x86-x32 = ""
143
144GALLIUMDRIVERS_append ="${@bb.utils.contains('PACKAGECONFIG', 'etnaviv', ',etnaviv', '', d)}"
145GALLIUMDRIVERS_append ="${@bb.utils.contains('PACKAGECONFIG', 'freedreno', ',freedreno', '', d)}"
146GALLIUMDRIVERS_append ="${@bb.utils.contains('PACKAGECONFIG', 'kmsro', ',kmsro', '', d)}"
147GALLIUMDRIVERS_append ="${@bb.utils.contains('PACKAGECONFIG', 'vc4', ',vc4', '', d)}"
148GALLIUMDRIVERS_append ="${@bb.utils.contains('PACKAGECONFIG', 'v3d', ',v3d', '', d)}"
149
150# radeonsi requires LLVM
151GALLIUMDRIVERS_LLVM33 = "${@bb.utils.contains('PACKAGECONFIG', 'r600', ',radeonsi', '', d)}"
152GALLIUMDRIVERS_LLVM33_ENABLED = "${@oe.utils.version_less_or_equal('MESA_LLVM_RELEASE', '3.2', False, len('${GALLIUMDRIVERS_LLVM33}') > 0, d)}"
153GALLIUMDRIVERS_LLVM = "r300,svga,nouveau${@',${GALLIUMDRIVERS_LLVM33}' if ${GALLIUMDRIVERS_LLVM33_ENABLED} else ''}"
154
155PACKAGECONFIG[r600] = ""
156PACKAGECONFIG[virgl] = ""
157
158GALLIUMDRIVERS_append = "${@bb.utils.contains('PACKAGECONFIG', 'gallium-llvm', ',${GALLIUMDRIVERS_LLVM}', '', d)}"
159GALLIUMDRIVERS_append = "${@bb.utils.contains('PACKAGECONFIG', 'r600', ',r600', '', d)}"
160GALLIUMDRIVERS_append = "${@bb.utils.contains('PACKAGECONFIG', 'virgl', ',virgl', '', d)}"
161
162PACKAGECONFIG[gallium] = "-Dgallium-drivers=${GALLIUMDRIVERS}, -Dgallium-drivers=''"
163PACKAGECONFIG[gallium-llvm] = "-Dllvm=true -Dshared-llvm=true, -Dllvm=false, llvm${MESA_LLVM_RELEASE} llvm-native \
164                               ${@'elfutils' if ${GALLIUMDRIVERS_LLVM33_ENABLED} else ''}"
165PACKAGECONFIG[xa]  = "-Dgallium-xa=true, -Dgallium-xa=false"
166PACKAGECONFIG[va] = "-Dgallium-va=true,-Dgallium-va=false,libva-initial"
167
168PACKAGECONFIG[vdpau] = "-Dgallium-vdpau=true,-Dgallium-vdpau=false,libvdpau"
169
170PACKAGECONFIG[lima] = ""
171GALLIUMDRIVERS_append ="${@bb.utils.contains('PACKAGECONFIG', 'lima', ',lima', '', d)}"
172
173PACKAGECONFIG[panfrost] = ""
174GALLIUMDRIVERS_append ="${@bb.utils.contains('PACKAGECONFIG', 'panfrost', ',panfrost', '', d)}"
175
176OSMESA = "${@bb.utils.contains('PACKAGECONFIG', 'gallium', 'gallium', 'classic', d)}"
177PACKAGECONFIG[osmesa] = "-Dosmesa=${OSMESA},-Dosmesa=none"
178
179PACKAGECONFIG[unwind] = "-Dlibunwind=true,-Dlibunwind=false,libunwind"
180
181# mesa tries to run cross-built gen_matypes on build machine to get struct size information
182EXTRA_OEMESON_append = " -Dasm=false"
183
184# llvmpipe is slow if compiled with -fomit-frame-pointer (e.g. -O2)
185FULL_OPTIMIZATION_append = " -fno-omit-frame-pointer"
186
187CFLAGS_append_armv5 = " -DMISSING_64BIT_ATOMICS"
188CFLAGS_append_armv6 = " -DMISSING_64BIT_ATOMICS"
189
190# Remove the mesa dependency on mesa-dev, as mesa is empty
191RDEPENDS_${PN}-dev = ""
192
193# Add dependency so that GLES3 header don't need to be added manually
194RDEPENDS_libgles2-mesa-dev += "libgles3-mesa-dev"
195
196PACKAGES =+ "libegl-mesa libegl-mesa-dev \
197             libosmesa libosmesa-dev \
198             libgl-mesa libgl-mesa-dev \
199             libglapi libglapi-dev \
200             libgbm libgbm-dev \
201             libgles1-mesa libgles1-mesa-dev \
202             libgles2-mesa libgles2-mesa-dev \
203             libgles3-mesa libgles3-mesa-dev \
204             libxatracker libxatracker-dev \
205             mesa-megadriver mesa-vulkan-drivers \
206             mesa-vdpau-drivers \
207            "
208
209do_install_append () {
210    # Drivers never need libtool .la files
211    rm -f ${D}${libdir}/dri/*.la
212    rm -f ${D}${libdir}/egl/*.la
213    rm -f ${D}${libdir}/gallium-pipe/*.la
214    rm -f ${D}${libdir}/gbm/*.la
215
216    # it was packaged in libdricore9.1.3-1 and preventing upgrades when debian.bbclass was used
217    chrpath --delete ${D}${libdir}/dri/*_dri.so || true
218
219    # libwayland-egl has been moved to wayland 1.15+
220    rm -f ${D}${libdir}/libwayland-egl*
221    rm -f ${D}${libdir}/pkgconfig/wayland-egl.pc
222}
223
224# For the packages that make up the OpenGL interfaces, inject variables so that
225# they don't get Debian-renamed (which would remove the -mesa suffix), and
226# RPROVIDEs/RCONFLICTs on the generic libgl name.
227python __anonymous() {
228    pkgconfig = (d.getVar('PACKAGECONFIG') or "").split()
229    for p in (("egl", "libegl", "libegl1"),
230              ("dri", "libgl", "libgl1"),
231              ("gles", "libgles1", "libglesv1-cm1"),
232              ("gles", "libgles2", "libglesv2-2"),
233              ("gles", "libgles3",)):
234        if not p[0] in pkgconfig:
235            continue
236        mlprefix = d.getVar("MLPREFIX")
237        fullp = mlprefix + p[1] + "-mesa"
238        mlprefix = d.getVar("MLPREFIX")
239        pkgs = " ".join(mlprefix + x for x in p[1:])
240        d.setVar("DEBIAN_NOAUTONAME_" + fullp, "1")
241        d.appendVar("RREPLACES_" + fullp, pkgs)
242        d.appendVar("RPROVIDES_" + fullp, pkgs)
243        d.appendVar("RCONFLICTS_" + fullp, pkgs)
244
245        d.appendVar("RRECOMMENDS_" + fullp, " ${MLPREFIX}mesa-megadriver")
246
247        # For -dev, the first element is both the Debian and original name
248        fullp += "-dev"
249        pkgs = mlprefix + p[1] + "-dev"
250        d.setVar("DEBIAN_NOAUTONAME_" + fullp, "1")
251        d.appendVar("RREPLACES_" + fullp, pkgs)
252        d.appendVar("RPROVIDES_" + fullp, pkgs)
253        d.appendVar("RCONFLICTS_" + fullp, pkgs)
254}
255
256python mesa_populate_packages() {
257    pkgs = ['mesa', 'mesa-dev', 'mesa-dbg']
258    for pkg in pkgs:
259        d.setVar("RPROVIDES_%s" % pkg, pkg.replace("mesa", "mesa-dri", 1))
260        d.setVar("RCONFLICTS_%s" % pkg, pkg.replace("mesa", "mesa-dri", 1))
261        d.setVar("RREPLACES_%s" % pkg, pkg.replace("mesa", "mesa-dri", 1))
262
263    import re
264    dri_drivers_root = oe.path.join(d.getVar('PKGD'), d.getVar('libdir'), "dri")
265    if os.path.isdir(dri_drivers_root):
266        dri_pkgs = os.listdir(dri_drivers_root)
267        lib_name = d.expand("${MLPREFIX}mesa-megadriver")
268        for p in dri_pkgs:
269            m = re.match(r'^(.*)_dri\.so$', p)
270            if m:
271                pkg_name = " ${MLPREFIX}mesa-driver-%s" % legitimize_package_name(m.group(1))
272                d.appendVar("RPROVIDES_%s" % lib_name, pkg_name)
273                d.appendVar("RCONFLICTS_%s" % lib_name, pkg_name)
274                d.appendVar("RREPLACES_%s" % lib_name, pkg_name)
275
276    pipe_drivers_root = os.path.join(d.getVar('libdir'), "gallium-pipe")
277    do_split_packages(d, pipe_drivers_root, r'^pipe_(.*)\.so$', 'mesa-driver-pipe-%s', 'Mesa %s pipe driver', extra_depends='')
278}
279
280PACKAGESPLITFUNCS_prepend = "mesa_populate_packages "
281
282PACKAGES_DYNAMIC += "^mesa-driver-.*"
283
284FILES_mesa-megadriver = "${libdir}/dri/* ${datadir}/drirc.d/00-mesa-defaults.conf"
285FILES_mesa-vulkan-drivers = "${libdir}/libvulkan_*.so ${datadir}/vulkan"
286FILES_${PN}-vdpau-drivers = "${libdir}/vdpau/*.so.*"
287FILES_libegl-mesa = "${libdir}/libEGL.so.*"
288FILES_libgbm = "${libdir}/libgbm.so.*"
289FILES_libgles1-mesa = "${libdir}/libGLESv1*.so.*"
290FILES_libgles2-mesa = "${libdir}/libGLESv2.so.*"
291FILES_libgl-mesa = "${libdir}/libGL.so.*"
292FILES_libglapi = "${libdir}/libglapi.so.*"
293FILES_libosmesa = "${libdir}/libOSMesa.so.*"
294FILES_libxatracker = "${libdir}/libxatracker.so.*"
295
296FILES_${PN}-dev = "${libdir}/pkgconfig/dri.pc ${includedir}/vulkan ${libdir}/vdpau/*.so"
297FILES_libegl-mesa-dev = "${libdir}/libEGL.* ${includedir}/EGL ${includedir}/KHR ${libdir}/pkgconfig/egl.pc"
298FILES_libgbm-dev = "${libdir}/libgbm.* ${libdir}/pkgconfig/gbm.pc ${includedir}/gbm.h"
299FILES_libgl-mesa-dev = "${libdir}/libGL.* ${includedir}/GL ${libdir}/pkgconfig/gl.pc"
300FILES_libglapi-dev = "${libdir}/libglapi.*"
301FILES_libgles1-mesa-dev = "${libdir}/libGLESv1*.* ${includedir}/GLES ${libdir}/pkgconfig/glesv1*.pc"
302FILES_libgles2-mesa-dev = "${libdir}/libGLESv2.* ${includedir}/GLES2 ${libdir}/pkgconfig/glesv2.pc"
303FILES_libgles3-mesa-dev = "${includedir}/GLES3"
304FILES_libosmesa-dev = "${libdir}/libOSMesa.* ${includedir}/GL/osmesa.h ${libdir}/pkgconfig/osmesa.pc"
305FILES_libxatracker-dev = "${libdir}/libxatracker.so ${libdir}/libxatracker.la \
306                          ${includedir}/xa_tracker.h ${includedir}/xa_composite.h ${includedir}/xa_context.h \
307                          ${libdir}/pkgconfig/xatracker.pc"
308
309# Fix upgrade path from mesa to mesa-megadriver
310RREPLACES_mesa-megadriver = "mesa"
311RCONFLICTS_mesa-megadriver = "mesa"
312RPROVIDES_mesa-megadriver = "mesa"
313