1SUMMARY = "IGT GPU Tools"
2DESCRIPTION = "IGT GPU Tools is a collection of tools for development and testing of the DRM drivers"
3HOMEPAGE = "https://gitlab.freedesktop.org/drm/igt-gpu-tools"
4BUGTRACKER = "https://gitlab.freedesktop.org/drm/igt-gpu-tools/-/issues"
5
6LIC_FILES_CHKSUM = "file://COPYING;md5=67bfee4df38fa6ecbe3a675c552d4c08"
7
8LICENSE = "MIT"
9
10inherit meson
11
12SRCREV = "d16ad07e7f2a028e14d61f570931c87fa5ce404c"
13PV = "1.25+git${SRCPV}"
14
15SRC_URI = "git://gitlab.freedesktop.org/drm/igt-gpu-tools.git;protocol=https \
16           file://0001-lib-igt_edid-Allocate-raw-8-bytes-for-VSDB.patch \
17           file://reproducibility.patch"
18
19S = "${WORKDIR}/git"
20
21DEPENDS += "libdrm libpciaccess cairo udev glib-2.0 procps libunwind kmod openssl elfutils alsa-lib json-c bison-native"
22RDEPENDS_${PN} += "bash"
23RDEPENDS_${PN}-tests += "bash"
24
25PACKAGE_BEFORE_PN = "${PN}-benchmarks ${PN}-tests"
26
27PACKAGECONFIG[chamelium] = "-Dchamelium=enabled,-Dchamelium=disabled,gsl xmlrpc-c"
28
29EXTRA_OEMESON = "-Ddocs=disabled -Drunner=enabled -Dsrcdir=/usr/src/debug/${PN}/${PV}-${PR}/git/"
30COMPATIBLE_HOST = "(x86_64.*|i.86.*|arm.*|aarch64).*-linux"
31COMPATIBLE_HOST_libc-musl_class-target = "null"
32SECURITY_LDFLAGS = "${SECURITY_X_LDFLAGS}"
33
34gputools_sysroot_preprocess() {
35	rm -f ${SYSROOT_DESTDIR}${libdir}/pkgconfig/intel-gen4asm.pc
36}
37SYSROOT_PREPROCESS_FUNCS += "gputools_sysroot_preprocess"
38
39do_install_append() {
40    install -d ${D}/usr/share/${BPN}/scripts
41    install ${S}/scripts/run-tests.sh ${D}/usr/share/${BPN}/scripts
42    install -d ${D}/usr/share/${BPN}/runner
43    install -D ${B}/runner/igt_runner ${D}/usr/share/${BPN}/runner
44    install -D ${B}/runner/igt_resume ${D}/usr/share/${BPN}/runner
45}
46
47FILES_${PN}-benchmarks += "${libexecdir}/${BPN}/benchmarks"
48FILES_${PN}-tests += "\
49        ${libexecdir}/${BPN}/*\
50        ${datadir}/${BPN}/1080p-right.png\
51        ${datadir}/${BPN}/1080p-left.png\
52        ${datadir}/${BPN}/pass.png\
53        ${datadir}/${BPN}/test-list.txt"
54