1SUMMARY = "IGT GPU Tools"
2DESCRIPTION = "IGT GPU Tools is a collection of tools for development and testing of the DRM drivers"
3HOMEPAGE = "https://gitlab.freedesktop.org/drm/igt-gpu-tools"
4BUGTRACKER = "https://gitlab.freedesktop.org/drm/igt-gpu-tools/-/issues"
5
6LIC_FILES_CHKSUM = "file://COPYING;md5=67bfee4df38fa6ecbe3a675c552d4c08"
7
8LICENSE = "MIT"
9
10inherit meson pkgconfig
11
12SRCREV = "2b29e8ac07fbcfadc48b9d60e4d736a6e3b289ab"
13PV = "1.27.1"
14
15SRC_URI = "git://gitlab.freedesktop.org/drm/igt-gpu-tools.git;protocol=https;branch=master"
16
17S = "${WORKDIR}/git"
18
19DEPENDS += "libdrm libpciaccess cairo udev glib-2.0 procps libunwind kmod openssl elfutils alsa-lib json-c bison-native"
20RDEPENDS:${PN} += "bash perl"
21RDEPENDS:${PN}-tests += "bash"
22
23PACKAGE_BEFORE_PN = "${PN}-benchmarks ${PN}-tests"
24
25PACKAGECONFIG[chamelium] = "-Dchamelium=enabled,-Dchamelium=disabled,gsl xmlrpc-c"
26
27EXTRA_OEMESON = "-Ddocs=disabled -Drunner=enabled -Dsrcdir=/usr/src/debug/${PN}/${PV}-${PR}/git/"
28COMPATIBLE_HOST = "(x86_64.*|i.86.*|arm.*|aarch64).*-linux"
29COMPATIBLE_HOST:libc-musl:class-target = "null"
30SECURITY_LDFLAGS = "${SECURITY_X_LDFLAGS}"
31
32gputools_sysroot_preprocess() {
33	rm -f ${SYSROOT_DESTDIR}${libdir}/pkgconfig/intel-gen4asm.pc
34}
35SYSROOT_PREPROCESS_FUNCS += "gputools_sysroot_preprocess"
36
37do_install:append() {
38    install -d ${D}/usr/share/${BPN}/scripts
39    install ${S}/scripts/run-tests.sh ${D}/usr/share/${BPN}/scripts
40    install -d ${D}/usr/share/${BPN}/runner
41    install -D ${B}/runner/igt_runner ${D}/usr/share/${BPN}/runner
42    install -D ${B}/runner/igt_resume ${D}/usr/share/${BPN}/runner
43}
44
45FILES:${PN}-benchmarks += "${libexecdir}/${BPN}/benchmarks"
46FILES:${PN}-tests += "\
47        ${libexecdir}/${BPN}/*\
48        ${datadir}/${BPN}/1080p-right.png\
49        ${datadir}/${BPN}/1080p-left.png\
50        ${datadir}/${BPN}/pass.png\
51        ${datadir}/${BPN}/test-list.txt"
52