1SUMMARY = "New user to do specific job"
2DESCRIPTION = "This recipe create a new user named ${PN}, who is used for specific jobs like building. The task can be auto started via mini X"
3SECTION = "x11"
4PR = "r6"
5LICENSE = "MIT"
6LIC_FILES_CHKSUM = "file://builder_session.sh;endline=5;md5=84796c3c41785d86100fdabcbdade00e"
7
8SRC_URI = "file://builder_session.sh \
9          "
10
11S = "${WORKDIR}"
12
13RDEPENDS:${PN} = "mini-x-session"
14
15inherit useradd
16
17# builder user password is "builder"
18BUILDER_PASSWORD ?= ".gLibiNXn0P12"
19USERADD_PACKAGES = "${PN}"
20USERADD_PARAM:${PN} = "--system --create-home \
21                       --groups video,tty,audio \
22                       --password ${BUILDER_PASSWORD} \
23                       --user-group builder"
24
25do_install () {
26	install -d -m 755 ${D}${sysconfdir}/mini_x/session.d
27	install -p -m 755 builder_session.sh ${D}${sysconfdir}/mini_x/session.d/
28
29	chown  builder.builder ${D}${sysconfdir}/mini_x/session.d/builder_session.sh
30}
31
32CVE_STATUS[CVE-2008-4178] = "cpe-incorrect: This CVE is for an unrelated builder"
33