1SUMMARY = "Multi-platform toolkit for creating GUIs"
2DESCRIPTION = "GTK is a multi-platform toolkit for creating graphical user interfaces. Offering a complete \
3set of widgets, GTK is suitable for projects ranging from small one-off projects to complete application suites."
4HOMEPAGE = "http://www.gtk.org"
5BUGTRACKER = "https://bugzilla.gnome.org/"
6SECTION = "libs"
7
8DEPENDS = " \
9    atk \
10    cairo \
11    fribidi \
12    gdk-pixbuf \
13    gdk-pixbuf-native \
14    gi-docgen \
15    glib-2.0 \
16    graphene \
17    harfbuzz \
18    jpeg \
19    libepoxy \
20    libpng \
21    librsvg \
22    libxkbcommon \
23    pango \
24    tiff \
25"
26
27LICENSE = "LGPL-2.0-only & LGPL-2.0-or-later & LGPL-2.1-or-later"
28LIC_FILES_CHKSUM = " \
29    file://COPYING;md5=5f30f0716dfdd0d91eb439ebec522ec2 \
30    file://gtk/gtk.h;endline=25;md5=61900d77e8d5bc67cf15ad93de9a3490 \
31    file://gdk/gdk.h;endline=25;md5=a0fb26c1f6b94e66d148279e192c333f \
32    file://tests/testgtk.c;endline=25;md5=49d06770681b8322466b52ed19d29fb2 \
33"
34
35MAJ_VER = "${@oe.utils.trim_version("${PV}", 2)}"
36
37UPSTREAM_CHECK_REGEX = "gtk-(?P<pver>\d+\.(\d*[02468])+(\.\d+)+)\.tar.xz"
38
39SRC_URI = "http://ftp.gnome.org/pub/gnome/sources/gtk/${MAJ_VER}/gtk-${PV}.tar.xz"
40SRC_URI[sha256sum] = "fcefb3f132f8cc4711a9efa5b353c9ae9bb5eeff0246fa74dbc2f2f839b9e308"
41
42S = "${WORKDIR}/gtk-${PV}"
43
44CVE_PRODUCT = "gnome:gtk"
45
46inherit meson gettext pkgconfig gi-docgen update-alternatives gsettings features_check gobject-introspection
47
48# TBD: nativesdk
49# gobject-introspection.bbclass pins introspection off for nativesk. As long as
50# we do not remove this wisdom or hack gtk4, it is not possible to build
51# nativesdk-gtk4
52BBCLASSEXTEND = "native"
53
54GSETTINGS_PACKAGE:class-native = ""
55
56ANY_OF_DISTRO_FEATURES = "${GTK3DISTROFEATURES}"
57REQUIRED_DISTRO_FEATURES = "opengl"
58GTKDOC_MESON_OPTION = "documentation"
59GIR_MESON_ENABLE_FLAG = 'enabled'
60GIR_MESON_DISABLE_FLAG = 'disabled'
61
62EXTRA_OEMESON = " -Dbuild-tests=false -Dbuild-testsuite=false -Dbuild-demos=false"
63
64PACKAGECONFIG ??= "gstreamer ${@bb.utils.filter('DISTRO_FEATURES', 'wayland x11 vulkan', d)}"
65PACKAGECONFIG:class-native = "${@bb.utils.filter('DISTRO_FEATURES', 'x11', d)}"
66PACKAGECONFIG:class-nativesdk = "${@bb.utils.filter('DISTRO_FEATURES', 'x11', d)}"
67
68PACKAGECONFIG[x11] = "-Dx11-backend=true,-Dx11-backend=false,at-spi2-atk fontconfig libx11 libxext libxcursor libxi libxdamage libxrandr libxrender libxcomposite libxfixes xinerama"
69PACKAGECONFIG[wayland] = "-Dwayland-backend=true,-Dwayland-backend=false,wayland wayland-protocols virtual/egl virtual/libgles2 wayland-native"
70PACKAGECONFIG[cloudproviders] = "-Dcloudproviders=enabled,-Dcloudproviders=disabled,libcloudproviders"
71PACKAGECONFIG[cups] = "-Dprint-cups=enabled,-Dprint-cups=disabled,cups,cups gtk4-printbackend-cups"
72PACKAGECONFIG[colord] = "-Dcolord=enabled,-Dcolord=disabled,colord"
73PACKAGECONFIG[iso-codes] = ",,iso-codes,iso-codes"
74# gtk4 wants gstreamer-player-1.0 -> gstreamer1.0-plugins-bad
75PACKAGECONFIG[gstreamer] = "-Dmedia-gstreamer=enabled,-Dmedia-gstreamer=disabled,gstreamer1.0-plugins-bad"
76PACKAGECONFIG[tracker] = "-Dtracker=enabled,-Dtracker=disabled,tracker,tracker-miners"
77PACKAGECONFIG[vulkan] = "-Dvulkan=enabled,-Dvulkan=disabled, vulkan-loader vulkan-headers shaderc-native"
78
79LIBV = "4.0.0"
80
81FILES:${PN}:append = " \
82    ${datadir}/glib-2.0/schemas/ \
83    ${datadir}/gtk-4.0/emoji/ \
84    ${datadir}/metainfo/ \
85    ${datadir}/icons/hicolor/*/apps/org.gtk.PrintEditor4*.* \
86    ${libdir}/gtk-4.0/${LIBV}/media \
87    ${bindir}/gtk4-update-icon-cache \
88    ${bindir}/gtk4-launch \
89"
90
91FILES:${PN}-dev += " \
92    ${datadir}/gtk-4.0/gtk4builder.rng \
93    ${datadir}/gtk-4.0/include \
94    ${datadir}/gtk-4.0/valgrind \
95    ${datadir}/gettext/its \
96    ${bindir}/gtk4-builder-tool \
97    ${bindir}/gtk4-encode-symbolic-svg \
98    ${bindir}/gtk4-query-settings \
99"
100
101GTKBASE_RRECOMMENDS ?= " \
102    liberation-fonts \
103    gdk-pixbuf-loader-png \
104    gdk-pixbuf-loader-jpeg \
105    gdk-pixbuf-loader-gif \
106    gdk-pixbuf-loader-xpm \
107    shared-mime-info \
108    adwaita-icon-theme-symbolic \
109"
110
111GTKBASE_RRECOMMENDS:class-native ?= ""
112
113GTKGLIBC_RRECOMMENDS ?= "${GTKBASE_RRECOMMENDS} glibc-gconv-iso8859-1"
114
115RRECOMMENDS:${PN} = "${GTKBASE_RRECOMMENDS}"
116RRECOMMENDS:${PN}:libc-glibc = "${GTKGLIBC_RRECOMMENDS}"
117RDEPENDS:${PN}-dev += "${@bb.utils.contains("PACKAGECONFIG", "wayland", "wayland-protocols", "", d)}"
118
119PACKAGES_DYNAMIC += "^gtk4-printbackend-.*"
120python populate_packages:prepend () {
121    import os.path
122
123    gtk_libdir = d.expand('${libdir}/gtk-4.0/${LIBV}')
124    printmodules_root = os.path.join(gtk_libdir, 'printbackends');
125
126    do_split_packages(d, printmodules_root, r'^libprintbackend-(.*)\.so$', 'gtk4-printbackend-%s', 'GTK printbackend module for %s')
127
128    if (d.getVar('DEBIAN_NAMES')):
129        d.setVar(d.expand('PKG:${PN}'), '${MLPREFIX}libgtk-4.0')
130}
131