1SUMMARY = "Software watchdog"
2DESCRIPTION = "Watchdog is a daemon that checks if your system is still \
3working. If programs in user space are not longer executed \
4it will reboot the system."
5HOMEPAGE = "http://watchdog.sourceforge.net/"
6BUGTRACKER = "http://sourceforge.net/tracker/?group_id=172030&atid=860194"
7
8LICENSE = "GPL-2.0+"
9LIC_FILES_CHKSUM = "file://COPYING;md5=084236108b1d4a9851bf5213fea586fd"
10
11SRC_URI = "${SOURCEFORGE_MIRROR}/watchdog/watchdog-${PV}.tar.gz \
12           file://0001-watchdog-remove-interdependencies-of-watchdog-and-wd.patch \
13           file://watchdog.init \
14           file://wd_keepalive.init \
15           file://0001-wd_keepalive.service-use-run-instead-of-var-run.patch \
16"
17
18SRC_URI[md5sum] = "1b4f51cabc64d1bee2fce7cdd626831f"
19SRC_URI[sha256sum] = "b8e7c070e1b72aee2663bdc13b5cc39f76c9232669cfbb1ac0adc7275a3b019d"
20
21# Can be dropped when the output next changes, avoids failures after
22# reproducibility issues
23PR = "r1"
24
25UPSTREAM_CHECK_URI = "http://sourceforge.net/projects/watchdog/files/watchdog/"
26UPSTREAM_CHECK_REGEX = "/watchdog/(?P<pver>(\d+[\.\-_]*)+)/"
27
28inherit autotools update-rc.d systemd pkgconfig
29
30DEPENDS += "libtirpc"
31CFLAGS += "-I${STAGING_INCDIR}/tirpc"
32LDFLAGS += "-ltirpc"
33
34EXTRA_OECONF += " --disable-nfs "
35CACHED_CONFIGUREVARS += "ac_cv_path_PATH_SENDMAIL=${sbindir}/sendmail"
36
37INITSCRIPT_PACKAGES = "${PN} ${PN}-keepalive"
38
39INITSCRIPT_NAME_${PN} = "watchdog"
40INITSCRIPT_PARAMS_${PN} = "start 25 1 2 3 4 5 . stop 85 0 6 ."
41
42INITSCRIPT_NAME_${PN}-keepalive = "wd_keepalive"
43INITSCRIPT_PARAMS_${PN}-keepalive = "start 25 1 2 3 4 5 . stop 85 0 6 ."
44
45SYSTEMD_PACKAGES = "${PN} ${PN}-keepalive"
46SYSTEMD_SERVICE_${PN} = "watchdog.service"
47SYSTEMD_SERVICE_${PN}-keepalive = "wd_keepalive.service"
48# When using systemd, consider making use of internal watchdog support of systemd.
49# See RuntimeWatchdogSec in /etc/systemd/system.conf.
50SYSTEMD_AUTO_ENABLE = "disable"
51
52do_install_append() {
53	install -d ${D}${systemd_system_unitdir}
54	install -m 0644 ${S}/debian/watchdog.service ${D}${systemd_system_unitdir}
55	install -m 0644 ${S}/debian/wd_keepalive.service ${D}${systemd_system_unitdir}
56
57	install -Dm 0755 ${WORKDIR}/watchdog.init ${D}/${sysconfdir}/init.d/watchdog
58	install -Dm 0755 ${WORKDIR}/wd_keepalive.init ${D}${sysconfdir}/init.d/wd_keepalive
59
60	# watchdog.conf is provided by the watchdog-config recipe
61	rm ${D}${sysconfdir}/watchdog.conf
62}
63
64PACKAGES =+ "${PN}-keepalive"
65
66FILES_${PN}-keepalive = " \
67    ${sysconfdir}/init.d/wd_keepalive \
68    ${systemd_system_unitdir}/wd_keepalive.service \
69    ${sbindir}/wd_keepalive \
70"
71
72RDEPENDS_${PN} += "${PN}-config"
73RRECOMMENDS_${PN} += "kernel-module-softdog"
74
75RDEPENDS_${PN}-keepalive += "${PN}-config"
76RCONFLICTS_${PN}-keepalive += "${PN}"
77RRECOMMENDS_${PN}-keepalive += "kernel-module-softdog"
78