1SUMMARY = "Software watchdog"
2DESCRIPTION = "Watchdog is a daemon that checks if your system is still \
3working. If programs in user space are not longer executed \
4it will reboot the system."
5HOMEPAGE = "http://watchdog.sourceforge.net/"
6BUGTRACKER = "http://sourceforge.net/tracker/?group_id=172030&atid=860194"
7
8LICENSE = "GPL-2.0-or-later"
9LIC_FILES_CHKSUM = "file://COPYING;md5=084236108b1d4a9851bf5213fea586fd"
10
11SRC_URI = "${SOURCEFORGE_MIRROR}/watchdog/watchdog-${PV}.tar.gz \
12           file://0001-watchdog-remove-interdependencies-of-watchdog-and-wd.patch \
13           file://watchdog.init \
14           file://wd_keepalive.init \
15           file://0001-wd_keepalive.service-use-run-instead-of-var-run.patch \
16           file://0001-shutdown-Do-not-guard-sys-quota.h-sys-swap.h-and-sys.patch \
17"
18
19SRC_URI[md5sum] = "1b4f51cabc64d1bee2fce7cdd626831f"
20SRC_URI[sha256sum] = "b8e7c070e1b72aee2663bdc13b5cc39f76c9232669cfbb1ac0adc7275a3b019d"
21
22# Can be dropped when the output next changes, avoids failures after
23# reproducibility issues
24
25UPSTREAM_CHECK_URI = "http://sourceforge.net/projects/watchdog/files/watchdog/"
26UPSTREAM_CHECK_REGEX = "/watchdog/(?P<pver>(\d+[\.\-_]*)+)/"
27
28inherit autotools update-rc.d systemd pkgconfig
29
30EXTRA_OECONF += " --disable-nfs "
31CACHED_CONFIGUREVARS += "ac_cv_path_PATH_SENDMAIL=${sbindir}/sendmail"
32
33INITSCRIPT_PACKAGES = "${PN} ${PN}-keepalive"
34
35INITSCRIPT_NAME:${PN} = "watchdog"
36INITSCRIPT_PARAMS:${PN} = "start 25 1 2 3 4 5 . stop 85 0 6 ."
37
38INITSCRIPT_NAME:${PN}-keepalive = "wd_keepalive"
39INITSCRIPT_PARAMS:${PN}-keepalive = "start 25 1 2 3 4 5 . stop 85 0 6 ."
40
41SYSTEMD_PACKAGES = "${PN} ${PN}-keepalive"
42SYSTEMD_SERVICE:${PN} = "watchdog.service"
43SYSTEMD_SERVICE:${PN}-keepalive = "wd_keepalive.service"
44# When using systemd, consider making use of internal watchdog support of systemd.
45# See RuntimeWatchdogSec in /etc/systemd/system.conf.
46SYSTEMD_AUTO_ENABLE = "disable"
47
48do_install:append() {
49	install -d ${D}${systemd_system_unitdir}
50	install -m 0644 ${S}/debian/watchdog.service ${D}${systemd_system_unitdir}
51	install -m 0644 ${S}/debian/wd_keepalive.service ${D}${systemd_system_unitdir}
52
53	install -Dm 0755 ${WORKDIR}/watchdog.init ${D}/${sysconfdir}/init.d/watchdog
54	install -Dm 0755 ${WORKDIR}/wd_keepalive.init ${D}${sysconfdir}/init.d/wd_keepalive
55
56	# watchdog.conf is provided by the watchdog-config recipe
57	rm ${D}${sysconfdir}/watchdog.conf
58}
59
60PACKAGES =+ "${PN}-keepalive"
61
62FILES:${PN}-keepalive = " \
63    ${sysconfdir}/init.d/wd_keepalive \
64    ${systemd_system_unitdir}/wd_keepalive.service \
65    ${sbindir}/wd_keepalive \
66"
67
68RDEPENDS:${PN} += "${PN}-config"
69RRECOMMENDS:${PN} += "kernel-module-softdog"
70
71RDEPENDS:${PN}-keepalive += "${PN}-config"
72RCONFLICTS:${PN}-keepalive += "${PN}"
73RRECOMMENDS:${PN}-keepalive += "kernel-module-softdog"
74