1require sudo.inc
2
3SRC_URI = "https://www.sudo.ws/dist/sudo-${PV}.tar.gz \
4           ${@bb.utils.contains('DISTRO_FEATURES', 'pam', '${PAM_SRC_URI}', '', d)} \
5           file://0001-sudo.conf.in-fix-conflict-with-multilib.patch \
6           "
7
8PAM_SRC_URI = "file://sudo.pam"
9
10SRC_URI[sha256sum] = "976aa56d3e3b2a75593307864288addb748c9c136e25d95a9cc699aafa77239c"
11
12DEPENDS += " virtual/crypt ${@bb.utils.contains('DISTRO_FEATURES', 'pam', 'libpam', '', d)}"
13RDEPENDS:${PN} += " ${@bb.utils.contains('DISTRO_FEATURES', 'pam', 'pam-plugin-limits pam-plugin-keyinit', '', d)}"
14
15CACHED_CONFIGUREVARS = " \
16        ac_cv_type_rsize_t=no \
17        ac_cv_path_MVPROG=${base_bindir}/mv \
18        ac_cv_path_BSHELLPROG=${base_bindir}/sh \
19        ac_cv_path_SENDMAILPROG=${sbindir}/sendmail \
20        ac_cv_path_VIPROG=${base_bindir}/vi \
21        "
22
23EXTRA_OECONF += " \
24             ${@bb.utils.contains('DISTRO_FEATURES', 'pam', '--with-pam', '--without-pam', d)} \
25             ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', '--enable-tmpfiles.d=${nonarch_libdir}/tmpfiles.d', '--disable-tmpfiles.d', d)} \
26             --with-rundir=/run/sudo \
27             --with-vardir=/var/lib/sudo \
28             --libexecdir=${libdir} \
29             "
30
31do_install:append () {
32	if [ "${@bb.utils.filter('DISTRO_FEATURES', 'pam', d)}" ]; then
33		install -D -m 644 ${UNPACKDIR}/sudo.pam ${D}/${sysconfdir}/pam.d/sudo
34		if ${@bb.utils.contains('PACKAGECONFIG', 'pam-wheel', 'true', 'false', d)} ; then
35			echo 'auth       required     pam_wheel.so use_uid' >>${D}${sysconfdir}/pam.d/sudo
36			sed -i 's/# \(%wheel ALL=(ALL) ALL\)/\1/' ${D}${sysconfdir}/sudoers
37		fi
38	fi
39
40	chmod 4111 ${D}${bindir}/sudo
41	chmod 0440 ${D}${sysconfdir}/sudoers
42
43	# Explicitly remove the /sudo directory to avoid QA error
44	rmdir -p --ignore-fail-on-non-empty ${D}/run/sudo
45}
46
47FILES:${PN}-dev += "${libdir}/${BPN}/lib*${SOLIBSDEV} ${libdir}/${BPN}/*.la \
48                    ${libdir}/lib*${SOLIBSDEV} ${libdir}/*.la"
49
50CONFFILES:${PN}-lib = "${sysconfdir}/sudoers"
51
52SUDO_PACKAGES = "${PN}-sudo\
53                 ${PN}-lib"
54
55PACKAGE_BEFORE_PN = "${SUDO_PACKAGES}"
56
57RDEPENDS:${PN}-sudo = "${PN}-lib"
58RDEPENDS:${PN} += "${SUDO_PACKAGES}"
59
60FILES:${PN}-sudo = "${bindir}/sudo ${bindir}/sudoedit"
61FILES:${PN}-lib = "${localstatedir} ${libexecdir} ${sysconfdir} ${libdir} ${nonarch_libdir}"
62