1SUMMARY = "Utility for viewing/manipulating IDE disk drive/driver parameters"
2HOMEPAGE = "http://sourceforge.net/projects/hdparm/"
3DESCRIPTION = "hdparm is a Linux shell utility for viewing \
4and manipulating various IDE drive and driver parameters."
5SECTION = "console/utils"
6
7LICENSE = "BSD-2-Clause & GPL-2.0-only & hdparm"
8LICENSE:${PN} = "BSD-2-Clause & hdparm"
9LICENSE:${PN}-dbg = "BSD-2-Clause & hdparm"
10LICENSE:wiper = "GPL-2.0-only"
11
12LIC_FILES_CHKSUM = "file://LICENSE.TXT;md5=495d03e50dc6c89d6a30107ab0df5b03 \
13                    file://debian/copyright;md5=a82d7ba3ade9e8ec902749db98c592f3 \
14                    file://wiper/GPLv2.txt;md5=fcb02dc552a041dee27e4b85c7396067 \
15                    file://wiper/wiper.sh;beginline=7;endline=31;md5=b7bc642addc152ea307505bf1a296f09"
16
17
18PACKAGES =+ "wiper"
19
20FILES:wiper = "${bindir}/wiper.sh"
21
22RDEPENDS:wiper = "bash gawk coreutils"
23
24SRC_URI = "${SOURCEFORGE_MIRROR}/hdparm/${BP}.tar.gz \
25           file://wiper.sh-fix-stat-path.patch \
26           "
27
28SRC_URI[sha256sum] = "d14929f910d060932e717e9382425d47c2e7144235a53713d55a94f7de535a4b"
29UPSTREAM_CHECK_URI = "https://sourceforge.net/projects/hdparm/files/hdparm/"
30
31EXTRA_OEMAKE = 'STRIP="echo" LDFLAGS="${LDFLAGS}"'
32
33inherit update-alternatives
34
35ALTERNATIVE:${PN} = "hdparm"
36ALTERNATIVE_LINK_NAME[hdparm] = "${base_sbindir}/hdparm"
37ALTERNATIVE_PRIORITY = "100"
38
39do_install () {
40	install -d ${D}/${base_sbindir} ${D}/${mandir}/man8 ${D}/${bindir}
41	oe_runmake 'DESTDIR=${D}' 'sbindir=${base_sbindir}' install
42	cp ${S}/wiper/wiper.sh ${D}/${bindir}
43}
44