1SUMMARY = "Standard GNU compressor"
2DESCRIPTION = "GNU Gzip is a popular data compression program originally written by Jean-loup Gailly for the GNU \
3project. Mark Adler wrote the decompression part"
4HOMEPAGE = "http://www.gnu.org/software/gzip/"
5SECTION = "console/utils"
6
7inherit autotools texinfo
8export DEFS="NO_ASM"
9
10EXTRA_OEMAKE:class-target = "GREP=${base_bindir}/grep"
11EXTRA_OECONF:append:libc-musl = " gl_cv_func_fflush_stdin=yes "
12
13do_install:append () {
14	if [ "${base_bindir}" != "${bindir}" ]; then
15		# Rename and move files into /bin (FHS), which is typical place for gzip
16		install -d ${D}${base_bindir}
17		mv ${D}${bindir}/gunzip ${D}${base_bindir}/gunzip
18		mv ${D}${bindir}/gzip ${D}${base_bindir}/gzip
19		mv ${D}${bindir}/zcat ${D}${base_bindir}/zcat
20		mv ${D}${bindir}/uncompress ${D}${base_bindir}/uncompress
21	fi
22}
23
24inherit update-alternatives
25
26ALTERNATIVE_PRIORITY = "100"
27ALTERNATIVE:${PN} = "gunzip gzip zcat"
28ALTERNATIVE_LINK_NAME[gunzip] = "${base_bindir}/gunzip"
29ALTERNATIVE_LINK_NAME[gzip] = "${base_bindir}/gzip"
30ALTERNATIVE_LINK_NAME[zcat] = "${base_bindir}/zcat"
31
32export CONFIG_SHELL="/bin/sh"
33