1SUMMARY = "An sh-compatible command language interpreter"
2HOMEPAGE = "http://tiswww.case.edu/php/chet/bash/bashtop.html"
3SECTION = "base/shell"
4
5DEPENDS = "ncurses bison-native virtual/libiconv"
6
7inherit autotools gettext texinfo update-alternatives ptest
8
9EXTRA_AUTORECONF += "--exclude=autoheader --exclude=aclocal"
10EXTRA_OECONF = "--enable-job-control --without-bash-malloc"
11
12# If NON_INTERACTIVE_LOGIN_SHELLS is defined, all login shells read the
13# startup files, even if they are not interactive.
14# This is what other major distros do. And this is what we wanted. See bug#5359 and bug#7137.
15CFLAGS += "-DNON_INTERACTIVE_LOGIN_SHELLS"
16
17ALTERNATIVE_${PN} = "bash sh"
18ALTERNATIVE_LINK_NAME[bash] = "${base_bindir}/bash"
19ALTERNATIVE_TARGET[bash] = "${base_bindir}/bash"
20ALTERNATIVE_LINK_NAME[sh] = "${base_bindir}/sh"
21ALTERNATIVE_TARGET[sh] = "${base_bindir}/bash.${BPN}"
22ALTERNATIVE_PRIORITY = "100"
23
24RDEPENDS_${PN} += "base-files"
25RDEPENDS_${PN}_class-nativesdk = ""
26RDEPENDS_${PN}-ptest += "make"
27
28DEPENDS_append_libc-glibc = " virtual/libc-locale"
29RDEPENDS_${PN}-ptest_append_libc-glibc = " locale-base-fr-fr locale-base-de-de"
30
31USERADD_PACKAGES = "${PN}-ptest"
32USERADD_PARAM_${PN}-ptest = "--create-home --user-group test"
33
34CACHED_CONFIGUREVARS += "headersdir=${includedir}/${PN}"
35
36do_compile_ptest () {
37	oe_runmake buildtest
38}
39
40do_install_append () {
41	# Move /usr/bin/bash to /bin/bash, if need
42	if [ "${base_bindir}" != "${bindir}" ]; then
43		mkdir -p ${D}${base_bindir}
44		mv ${D}${bindir}/bash ${D}${base_bindir}
45	fi
46}
47do_install_append_class-target () {
48	# Clean buildhost references in bashbug
49	sed -i -e "s,--sysroot=${STAGING_DIR_TARGET},,g" \
50		-e "s,-I${WORKDIR}/\S* ,,g" \
51		-e 's|${DEBUG_PREFIX_MAP}||g' \
52		${D}${bindir}/bashbug
53
54	# Clean buildhost references in bash.pc
55	sed -i -e "s,--sysroot=${STAGING_DIR_TARGET},,g" \
56	     ${D}${libdir}/pkgconfig/bash.pc
57
58	# Clean buildhost references in Makefile.inc
59	sed -i -e "s,--sysroot=${STAGING_DIR_TARGET},,g" \
60		-e 's|${DEBUG_PREFIX_MAP}||g' \
61		-e 's:${HOSTTOOLS_DIR}/::g' \
62		-e 's:${BASE_WORKDIR}/${MULTIMACH_TARGET_SYS}::g' \
63		${D}${libdir}/bash/Makefile.inc
64}
65
66do_install_ptest () {
67	make INSTALL_TEST_DIR=${D}${PTEST_PATH}/tests install-test
68	cp ${B}/Makefile ${D}${PTEST_PATH}
69        sed -i -e 's/^Makefile/_Makefile/' -e "s,--sysroot=${STAGING_DIR_TARGET},,g" \
70	    -e 's|${DEBUG_PREFIX_MAP}||g' \
71	    -e "s,${S},,g" -e "s,${B},,g" -e "s,${STAGING_DIR_NATIVE},,g" \
72	    -e 's:${HOSTTOOLS_DIR}/::g' \
73	     ${D}${PTEST_PATH}/Makefile
74}
75
76pkg_postinst_${PN} () {
77	grep -q "^${base_bindir}/bash$" $D${sysconfdir}/shells || echo ${base_bindir}/bash >> $D${sysconfdir}/shells
78}
79
80pkg_postrm_${PN} () {
81	printf "$(grep -v "^${base_bindir}/bash$" $D${sysconfdir}/shells)\n" > $D${sysconfdir}/shells
82}
83
84PACKAGES += "${PN}-bashbug"
85FILES_${PN} = "${bindir}/bash ${base_bindir}/bash.bash"
86FILES_${PN}-bashbug = "${bindir}/bashbug"
87
88PACKAGE_BEFORE_PN += "${PN}-loadable"
89RDEPENDS_${PN}-loadable += "${PN}"
90FILES_${PN}-loadable += "${libdir}/bash/*"
91
92RPROVIDES_${PN} += "${@bb.utils.contains('DISTRO_FEATURES', 'usrmerge', '/bin/sh /bin/bash', '', d)}"
93