1SUMMARY = "Boot performance graphing tool"
2DESCRIPTION = "For systemd-bootchart, several proc debug interfaces are required in the kernel config: \
3  CONFIG_SCHEDSTATS \
4below is optional, for additional info: \
5  CONFIG_SCHED_DEBUG"
6HOMEPAGE = "https://github.com/systemd/systemd-bootchart"
7LICENSE = "LGPL-2.1-only & GPL-2.0-only"
8LIC_FILES_CHKSUM = "file://LICENSE.LGPL2.1;md5=4fbd65380cdd255951079008b364516c \
9                    file://LICENSE.GPL2;md5=751419260aa954499f7abaabaa882bbe"
10
11SRC_URI = "git://github.com/systemd/systemd-bootchart.git;protocol=https;branch=main \
12           file://mips64.patch \
13           file://no_lto.patch \
14           file://0001-Add-riscv32-support.patch \
15"
16
17SRC_URI:append:libc-musl = " \
18    file://0001-comparison_fn_t-is-glibc-specific-use-raw-signature-.patch \
19    file://0002-musl-does-not-provide-printf-h.patch \
20    file://0003-musl-does-not-provide-canonicalize_file_name.patch \
21    file://0001-Define-portable-basename-function.patch \
22    "
23
24
25SRCREV = "8ab9680a1bd5eb8fe7a7dcc44897af7ee41e56e7"
26
27S = "${WORKDIR}/git"
28
29DEPENDS = "systemd libxslt-native xmlto-native docbook-xml-dtd4-native docbook-xsl-stylesheets-native intltool"
30
31inherit pkgconfig autotools systemd features_check
32
33REQUIRED_DISTRO_FEATURES = "systemd"
34
35SYSTEMD_SERVICE:${PN} = "systemd-bootchart.service"
36
37do_configure:prepend() {
38    # intltool.m4 is a soft link to /usr/share/aclocal/m4, delete it and use the one in our sysroot
39    rm -f ${S}/m4/intltool.m4
40}
41
42FILES:${PN} += "${systemd_unitdir}/systemd-bootchart"
43
44EXTRA_OECONF = " --with-rootprefix=${root_prefix} \
45                 --with-rootlibdir=${base_libdir}"
46