1# Note, we can probably remove the lzma option as it has be replaced with xz,
2# and I don't think the kernel supports it any more.
3SUMMARY = "Tools for manipulating SquashFS filesystems"
4SECTION = "base"
5LICENSE = "GPL-2"
6LIC_FILES_CHKSUM = "file://../COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263"
7
8PV = "4.4"
9SRCREV = "52eb4c279cd283ed9802dd1ceb686560b22ffb67"
10SRC_URI = "git://github.com/plougher/squashfs-tools.git;protocol=https \
11"
12
13S = "${WORKDIR}/git/squashfs-tools"
14
15EXTRA_OEMAKE = "${PACKAGECONFIG_CONFARGS}"
16
17PACKAGECONFIG ??= "gzip xz lzo lz4 lzma xattr reproducible"
18PACKAGECONFIG[gzip] = "GZIP_SUPPORT=1,GZIP_SUPPORT=0,zlib"
19PACKAGECONFIG[xz] = "XZ_SUPPORT=1,XZ_SUPPORT=0,xz"
20PACKAGECONFIG[lzo] = "LZO_SUPPORT=1,LZO_SUPPORT=0,lzo"
21PACKAGECONFIG[lz4] = "LZ4_SUPPORT=1,LZ4_SUPPORT=0,lz4"
22PACKAGECONFIG[lzma] = "LZMA_XZ_SUPPORT=1,LZMA_XZ_SUPPORT=0,xz"
23PACKAGECONFIG[xattr] = "XATTR_SUPPORT=1,XATTR_SUPPORT=0,attr"
24PACKAGECONFIG[zstd] = "ZSTD_SUPPORT=1,ZSTD_SUPPORT=0,zstd"
25PACKAGECONFIG[reproducible] = "REPRODUCIBLE_DEFAULT=1,REPRODUCIBLE_DEFAULT=0,"
26
27do_compile() {
28	oe_runmake all
29}
30
31do_install() {
32	oe_runmake install INSTALL_DIR=${D}${sbindir}
33}
34
35ARM_INSTRUCTION_SET_armv4 = "arm"
36ARM_INSTRUCTION_SET_armv5 = "arm"
37ARM_INSTRUCTION_SET_armv6 = "arm"
38
39BBCLASSEXTEND = "native nativesdk"
40
41CVE_PRODUCT = "squashfs"
42