1SUMMARY = "Fast open source processor emulator"
2DESCRIPTION = "QEMU is a hosted virtual machine monitor: it emulates the \
3machine's processor through dynamic binary translation and provides a set \
4of different hardware and device models for the machine, enabling it to run \
5a variety of guest operating systems"
6HOMEPAGE = "http://qemu.org"
7LICENSE = "GPL-2.0-only & LGPL-2.1-only"
8
9RDEPENDS:${PN}-ptest = "bash"
10
11require qemu-targets.inc
12inherit pkgconfig ptest python3-dir
13
14LIC_FILES_CHKSUM = "file://COPYING;md5=441c28d2cf86e15a37fa47e15a72fbac \
15                    file://COPYING.LIB;endline=24;md5=8c5efda6cf1e1b03dcfd0e6c0d271c7f"
16
17SRC_URI = "https://download.qemu.org/${BPN}-${PV}.tar.xz \
18           file://powerpc_rom.bin \
19           file://run-ptest \
20           file://0001-qemu-Add-missing-wacom-HID-descriptor.patch \
21           file://0003-qemu-Add-addition-environment-space-to-boot-loader-q.patch \
22           file://0006-chardev-connect-socket-to-a-spawned-command.patch \
23           file://0007-apic-fixup-fallthrough-to-PIC.patch \
24           file://0010-configure-Add-pkg-config-handling-for-libgcrypt.patch \
25           file://0001-qemu-Do-not-include-file-if-not-exists.patch \
26           file://mmap2.patch \
27           file://determinism.patch \
28           file://0001-tests-meson.build-use-relative-path-to-refer-to-file.patch \
29           file://0001-riscv-Set-5.4-as-minimum-kernel-version-for-riscv32.patch \
30           file://0001-acpi-tpm-Add-missing-device-identification-objects.patch \
31           file://0001-ppc-Include-asm-ptrace.h-for-pt_regs-struct-definiti.patch \
32           file://0001-Define-MAP_SYNC-and-MAP_SHARED_VALIDATE-on-needed-li.patch \
33           file://0001-vhost-vsock-detach-the-virqueue-element-in-case-of-e.patch \
34           file://0002-virtio-net-fix-map-leaking-on-error-during-receive.patch \
35           file://pvrdma.patch \
36           file://no-ps2.patch \
37           "
38UPSTREAM_CHECK_REGEX = "qemu-(?P<pver>\d+(\.\d+)+)\.tar"
39
40SRC_URI[sha256sum] = "68e15d8e45ac56326e0b9a4afa8b49a3dfe8aba3488221d098c84698bca65b45"
41
42SRC_URI:append:class-target = " file://cross.patch"
43SRC_URI:append:class-nativesdk = " file://cross.patch"
44
45# Applies against virglrender < 0.6.0 and not qemu itself
46CVE_CHECK_IGNORE += "CVE-2017-5957"
47
48# The VNC server can expose host files uder some circumstances. We don't
49# enable it by default.
50CVE_CHECK_IGNORE += "CVE-2007-0998"
51
52# 'The issues identified by this CVE were determined to not constitute a vulnerability.'
53# https://bugzilla.redhat.com/show_bug.cgi?id=1609015#c11
54CVE_CHECK_IGNORE += "CVE-2018-18438"
55
56COMPATIBLE_HOST:mipsarchn32 = "null"
57COMPATIBLE_HOST:mipsarchn64 = "null"
58COMPATIBLE_HOST:riscv32 = "null"
59
60# Per https://lists.nongnu.org/archive/html/qemu-devel/2020-09/msg03873.html
61# upstream states qemu doesn't work without optimization
62DEBUG_BUILD = "0"
63
64do_install:append() {
65    # Prevent QA warnings about installed ${localstatedir}/run
66    if [ -d ${D}${localstatedir}/run ]; then rmdir ${D}${localstatedir}/run; fi
67}
68
69do_install_ptest() {
70	cp -rL ${B}/tests ${D}${PTEST_PATH}
71	find ${D}${PTEST_PATH}/tests -type f -name "*.[Sshcodp]" | xargs -i rm -rf {}
72
73	# Don't check the file genreated by configure
74	sed -i -e "1s,#!/usr/bin/bash,#!${base_bindir}/bash," ${D}${PTEST_PATH}/tests/data/acpi/disassemle-aml.sh
75
76	# Strip the paths from the QEMU variable, we can use PATH
77	sed -i -e "s#^QEMU=.*/qemu-#QEMU=qemu-#g" ${D}${PTEST_PATH}/tests/tcg/*.mak
78
79        # Strip compiler flags as they break reproducibility
80        sed -i -e "s,CROSS_CC_GUEST=.*,CROSS_CC_GUEST=," ${D}${PTEST_PATH}/tests/tcg/*.mak
81}
82
83# QEMU_TARGETS is overridable variable
84QEMU_TARGETS ?= "arm aarch64 i386 mips mipsel mips64 mips64el ppc ppc64 ppc64le riscv32 riscv64 sh4 x86_64"
85
86EXTRA_OECONF = " \
87    --prefix=${prefix} \
88    --bindir=${bindir} \
89    --includedir=${includedir} \
90    --libdir=${libdir} \
91    --mandir=${mandir} \
92    --datadir=${datadir} \
93    --docdir=${docdir}/${BPN} \
94    --sysconfdir=${sysconfdir} \
95    --libexecdir=${libexecdir} \
96    --localstatedir=${localstatedir} \
97    --with-suffix=${BPN} \
98    --disable-strip \
99    --disable-werror \
100    --extra-cflags='${CFLAGS}' \
101    --extra-ldflags='${LDFLAGS}' \
102    --with-git=/bin/false \
103    --with-git-submodules=ignore \
104    --meson=meson \
105    ${PACKAGECONFIG_CONFARGS} \
106    "
107
108B = "${WORKDIR}/build"
109
110#EXTRA_OECONF:append = " --python=${HOSTTOOLS_DIR}/python3"
111
112do_configure:prepend:class-native() {
113	# Append build host pkg-config paths for native target since the host may provide sdl
114	BHOST_PKGCONFIG_PATH=$(PATH=/usr/bin:/bin pkg-config --variable pc_path pkg-config || echo "")
115	if [ ! -z "$BHOST_PKGCONFIG_PATH" ]; then
116		export PKG_CONFIG_PATH=$PKG_CONFIG_PATH:$BHOST_PKGCONFIG_PATH
117	fi
118}
119
120do_configure() {
121	# This is taken from meson.bbclass to avoid errors when updating to a
122	# new version of meson.
123	rmdir ${STAGING_LIBDIR_NATIVE}/${PYTHON_DIR}/site-packages/*.egg-info 2>/dev/null || :
124
125	${S}/configure ${EXTRA_OECONF}
126}
127do_configure[cleandirs] += "${B}"
128
129do_install () {
130	export STRIP=""
131	oe_runmake 'DESTDIR=${D}' install
132}
133
134# The following fragment will create a wrapper for qemu-mips user emulation
135# binary in order to work around a segmentation fault issue. Basically, by
136# default, the reserved virtual address space for 32-on-64 bit is set to 4GB.
137# This will trigger a MMU access fault in the virtual CPU. With this change,
138# the qemu-mips works fine.
139# IMPORTANT: This piece needs to be removed once the root cause is fixed!
140do_install:append() {
141	if [ -e "${D}/${bindir}/qemu-mips" ]; then
142		create_wrapper ${D}/${bindir}/qemu-mips \
143			QEMU_RESERVED_VA=0x0
144	fi
145}
146# END of qemu-mips workaround
147
148# Disable kvm/virgl/mesa on targets that do not support it
149PACKAGECONFIG:remove:darwin = "kvm virglrenderer epoxy gtk+"
150PACKAGECONFIG:remove:mingw32 = "kvm virglrenderer epoxy gtk+"
151
152PACKAGECONFIG[sdl] = "--enable-sdl,--disable-sdl,libsdl2"
153PACKAGECONFIG[virtfs] = "--enable-virtfs --enable-attr --enable-cap-ng,--disable-virtfs,libcap-ng attr,"
154PACKAGECONFIG[aio] = "--enable-linux-aio,--disable-linux-aio,libaio,"
155PACKAGECONFIG[xfs] = "--enable-xfsctl,--disable-xfsctl,xfsprogs,"
156PACKAGECONFIG[xen] = "--enable-xen,--disable-xen,xen-tools,xen-tools-libxenstore xen-tools-libxenctrl xen-tools-libxenguest"
157PACKAGECONFIG[vnc-sasl] = "--enable-vnc --enable-vnc-sasl,--disable-vnc-sasl,cyrus-sasl,"
158PACKAGECONFIG[vnc-jpeg] = "--enable-vnc --enable-vnc-jpeg,--disable-vnc-jpeg,jpeg,"
159PACKAGECONFIG[vnc-png] = "--enable-vnc --enable-vnc-png,--disable-vnc-png,libpng,"
160PACKAGECONFIG[libcurl] = "--enable-curl,--disable-curl,curl,"
161PACKAGECONFIG[nss] = "--enable-smartcard,--disable-smartcard,nss,"
162PACKAGECONFIG[curses] = "--enable-curses,--disable-curses,ncurses,"
163PACKAGECONFIG[gtk+] = "--enable-gtk,--disable-gtk,gtk+3 gettext-native"
164PACKAGECONFIG[vte] = "--enable-vte,--disable-vte,vte gettext-native"
165PACKAGECONFIG[libcap-ng] = "--enable-cap-ng,--disable-cap-ng,libcap-ng,"
166PACKAGECONFIG[ssh] = "--enable-libssh,--disable-libssh,libssh,"
167PACKAGECONFIG[gcrypt] = "--enable-gcrypt,--disable-gcrypt,libgcrypt,"
168PACKAGECONFIG[nettle] = "--enable-nettle,--disable-nettle,nettle"
169PACKAGECONFIG[libusb] = "--enable-libusb,--disable-libusb,libusb1"
170PACKAGECONFIG[fdt] = "--enable-fdt,--disable-fdt,dtc"
171PACKAGECONFIG[alsa] = "--audio-drv-list=default,,alsa-lib"
172PACKAGECONFIG[epoxy] = "--enable-opengl,--disable-opengl,libepoxy"
173PACKAGECONFIG[lzo] = "--enable-lzo,--disable-lzo,lzo"
174PACKAGECONFIG[numa] = "--enable-numa,--disable-numa,numactl"
175PACKAGECONFIG[gnutls] = "--enable-gnutls,--disable-gnutls,gnutls"
176PACKAGECONFIG[bzip2] = "--enable-bzip2,--disable-bzip2,bzip2"
177PACKAGECONFIG[libiscsi] = "--enable-libiscsi,--disable-libiscsi"
178PACKAGECONFIG[kvm] = "--enable-kvm,--disable-kvm"
179PACKAGECONFIG[virglrenderer] = "--enable-virglrenderer,--disable-virglrenderer,virglrenderer"
180# spice will be in meta-networking layer
181PACKAGECONFIG[spice] = "--enable-spice,--disable-spice,spice"
182# usbredir will be in meta-networking layer
183PACKAGECONFIG[usb-redir] = "--enable-usb-redir,--disable-usb-redir,usbredir"
184PACKAGECONFIG[snappy] = "--enable-snappy,--disable-snappy,snappy"
185PACKAGECONFIG[glusterfs] = "--enable-glusterfs,--disable-glusterfs,glusterfs"
186PACKAGECONFIG[xkbcommon] = "--enable-xkbcommon,--disable-xkbcommon,libxkbcommon"
187PACKAGECONFIG[libudev] = "--enable-libudev,--disable-libudev,eudev"
188PACKAGECONFIG[libxml2] = "--enable-libxml2,--disable-libxml2,libxml2"
189PACKAGECONFIG[attr] = "--enable-attr,--disable-attr,attr,"
190PACKAGECONFIG[rbd] = "--enable-rbd,--disable-rbd,ceph,ceph"
191PACKAGECONFIG[vhost] = "--enable-vhost-net,--disable-vhost-net,,"
192PACKAGECONFIG[ust] = "--enable-trace-backend=ust,--enable-trace-backend=nop,lttng-ust,"
193PACKAGECONFIG[pie] = "--enable-pie,--disable-pie,,"
194PACKAGECONFIG[seccomp] = "--enable-seccomp,--disable-seccomp,libseccomp"
195# libnfs is currently provided by meta-kodi
196PACKAGECONFIG[libnfs] = "--enable-libnfs,--disable-libnfs,libnfs"
197PACKAGECONFIG[pmem] = "--enable-libpmem,--disable-libpmem,pmdk"
198PACKAGECONFIG[pulsedio] = "--enable-pa,--disable-pa,pulseaudio"
199PACKAGECONFIG[selinux] = "--enable-selinux,--disable-selinux"
200
201INSANE_SKIP:${PN} = "arch"
202
203FILES:${PN} += "${datadir}/icons"
204