1SUMMARY = "Fast open source processor emulator"
2DESCRIPTION = "QEMU is a hosted virtual machine monitor: it emulates the \
3machine's processor through dynamic binary translation and provides a set \
4of different hardware and device models for the machine, enabling it to run \
5a variety of guest operating systems"
6HOMEPAGE = "http://qemu.org"
7LICENSE = "GPL-2.0-only & LGPL-2.1-only"
8
9RDEPENDS:${PN}-ptest = "bash"
10
11require qemu-targets.inc
12inherit pkgconfig ptest update-rc.d systemd
13
14LIC_FILES_CHKSUM = "file://COPYING;md5=441c28d2cf86e15a37fa47e15a72fbac \
15                    file://COPYING.LIB;endline=24;md5=8c5efda6cf1e1b03dcfd0e6c0d271c7f"
16
17SRC_URI = "https://download.qemu.org/${BPN}-${PV}.tar.xz \
18           file://powerpc_rom.bin \
19           file://run-ptest \
20           file://0001-qemu-Add-addition-environment-space-to-boot-loader-q.patch \
21           file://0002-chardev-connect-socket-to-a-spawned-command.patch \
22           file://0003-apic-fixup-fallthrough-to-PIC.patch \
23           file://0004-configure-Add-pkg-config-handling-for-libgcrypt.patch \
24           file://0005-qemu-Do-not-include-file-if-not-exists.patch \
25           file://0006-qemu-Add-some-user-space-mmap-tweaks-to-address-musl.patch \
26           file://0007-qemu-Determinism-fixes.patch \
27           file://0008-tests-meson.build-use-relative-path-to-refer-to-file.patch \
28           file://0009-Define-MAP_SYNC-and-MAP_SHARED_VALIDATE-on-needed-li.patch \
29           file://0010-hw-pvrdma-Protect-against-buggy-or-malicious-guest-d.patch \
30           file://0001-contrib-vhost-user-blk-Replace-lseek64-with-lseek.patch \
31           file://0002-linux-user-Replace-use-of-lfs64-related-functions-an.patch \
32           file://0001-configure-Fix-check-tcg-not-executing-any-tests.patch \
33           file://0001-Revert-linux-user-add-more-compat-ioctl-definitions.patch \
34           file://0002-Revert-linux-user-fix-compat-with-glibc-2.36-sys-mou.patch \
35           file://qemu-guest-agent.init \
36           file://qemu-guest-agent.udev \
37           "
38UPSTREAM_CHECK_REGEX = "qemu-(?P<pver>\d+(\.\d+)+)\.tar"
39
40SRC_URI[sha256sum] = "5b49ce2687744dad494ae90a898c52204a3406e84d072482a1e1be854eeb2157"
41
42SRC_URI:append:class-target = " file://cross.patch"
43SRC_URI:append:class-nativesdk = " file://cross.patch"
44
45# Applies against virglrender < 0.6.0 and not qemu itself
46CVE_CHECK_IGNORE += "CVE-2017-5957"
47
48# The VNC server can expose host files uder some circumstances. We don't
49# enable it by default.
50CVE_CHECK_IGNORE += "CVE-2007-0998"
51
52# 'The issues identified by this CVE were determined to not constitute a vulnerability.'
53# https://bugzilla.redhat.com/show_bug.cgi?id=1609015#c11
54CVE_CHECK_IGNORE += "CVE-2018-18438"
55
56COMPATIBLE_HOST:mipsarchn32 = "null"
57COMPATIBLE_HOST:mipsarchn64 = "null"
58COMPATIBLE_HOST:riscv32 = "null"
59
60# Per https://lists.nongnu.org/archive/html/qemu-devel/2020-09/msg03873.html
61# upstream states qemu doesn't work without optimization
62DEBUG_BUILD = "0"
63
64do_install:append() {
65    # Prevent QA warnings about installed ${localstatedir}/run
66    if [ -d ${D}${localstatedir}/run ]; then rmdir ${D}${localstatedir}/run; fi
67}
68
69do_install_ptest() {
70	cp -rL ${B}/tests ${D}${PTEST_PATH}
71	find ${D}${PTEST_PATH}/tests -type f -name "*.[Sshcodp]" | xargs -i rm -rf {}
72
73	# Don't check the file genreated by configure
74	sed -i -e "1s,#!/usr/bin/bash,#!${base_bindir}/bash," ${D}${PTEST_PATH}/tests/data/acpi/disassemle-aml.sh
75
76	# Strip the paths from the QEMU variable, we can use PATH
77	makfiles=$(find ${D}${PTEST_PATH} -name "*.mak")
78	sed -i -e "s#^QEMU=.*/qemu-#QEMU=qemu-#g" $makfiles
79
80	# Strip compiler flags as they break reproducibility
81	sed -i -e "s,^CC=.*,CC=gcc," \
82	       -e "s,^CCAS=.*,CCAS=gcc," \
83	       -e "s,^LD=.*,LD=ld," $makfiles
84
85	# Update SRC_PATH variable to the right place on target
86	sed -i -e "s#^SRC_PATH=.*#SRC_PATH=${PTEST_PATH}#g" $makfiles
87
88	# https://gitlab.com/qemu-project/qemu/-/issues/1403
89	rm ${D}${PTEST_PATH}/tests/unit/test-io-channel-command
90}
91
92# QEMU_TARGETS is overridable variable
93QEMU_TARGETS ?= "arm aarch64 i386 loongarch64 mips mipsel mips64 mips64el ppc ppc64 ppc64le riscv32 riscv64 sh4 x86_64"
94
95EXTRA_OECONF = " \
96    --prefix=${prefix} \
97    --bindir=${bindir} \
98    --includedir=${includedir} \
99    --libdir=${libdir} \
100    --mandir=${mandir} \
101    --datadir=${datadir} \
102    --docdir=${docdir}/${BPN} \
103    --sysconfdir=${sysconfdir} \
104    --libexecdir=${libexecdir} \
105    --localstatedir=${localstatedir} \
106    --with-suffix=${BPN} \
107    --disable-strip \
108    --disable-werror \
109    --extra-cflags='${CFLAGS}' \
110    --extra-ldflags='${LDFLAGS}' \
111    --with-git=/bin/false \
112    --with-git-submodules=ignore \
113    --meson=meson \
114    ${PACKAGECONFIG_CONFARGS} \
115    "
116
117B = "${WORKDIR}/build"
118
119#EXTRA_OECONF:append = " --python=${HOSTTOOLS_DIR}/python3"
120
121do_configure:prepend:class-native() {
122	# Append build host pkg-config paths for native target since the host may provide sdl
123	BHOST_PKGCONFIG_PATH=$(PATH=/usr/bin:/bin pkg-config --variable pc_path pkg-config || echo "")
124	if [ ! -z "$BHOST_PKGCONFIG_PATH" ]; then
125		export PKG_CONFIG_PATH=$PKG_CONFIG_PATH:$BHOST_PKGCONFIG_PATH
126	fi
127}
128
129do_configure() {
130    ${S}/configure ${EXTRA_OECONF}
131}
132do_configure[cleandirs] += "${B}"
133
134do_install () {
135	export STRIP=""
136	oe_runmake 'DESTDIR=${D}' install
137
138	# If we built the guest agent, also install startup/udev rules
139	if [ -e "${D}${bindir}/qemu-ga" ]; then
140		install -d ${D}${sysconfdir}/init.d/
141		install -m 0755 ${WORKDIR}/qemu-guest-agent.init ${D}${sysconfdir}/init.d/qemu-guest-agent
142		sed -i 's:@bindir@:${bindir}:' ${D}${sysconfdir}/init.d/qemu-guest-agent
143
144		install -d ${D}${sysconfdir}/udev/rules.d/
145		install -m 0644 ${WORKDIR}/qemu-guest-agent.udev ${D}${sysconfdir}/udev/rules.d/60-qemu-guest-agent.rules
146
147		install -d ${D}${systemd_unitdir}/system/
148		install -m 0644 ${S}/contrib/systemd/qemu-guest-agent.service ${D}${systemd_unitdir}/system
149		sed -i -e 's,-/usr/bin/,-${bindir}/,g' ${D}${systemd_unitdir}/system/qemu-guest-agent.service
150	fi
151}
152
153# The following fragment will create a wrapper for qemu-mips user emulation
154# binary in order to work around a segmentation fault issue. Basically, by
155# default, the reserved virtual address space for 32-on-64 bit is set to 4GB.
156# This will trigger a MMU access fault in the virtual CPU. With this change,
157# the qemu-mips works fine.
158# IMPORTANT: This piece needs to be removed once the root cause is fixed!
159do_install:append() {
160	if [ -e "${D}/${bindir}/qemu-mips" ]; then
161		create_wrapper ${D}/${bindir}/qemu-mips \
162			QEMU_RESERVED_VA=0x0
163	fi
164}
165# END of qemu-mips workaround
166
167# Disable kvm/virgl/mesa on targets that do not support it
168PACKAGECONFIG:remove:darwin = "kvm virglrenderer epoxy gtk+"
169PACKAGECONFIG:remove:mingw32 = "kvm virglrenderer epoxy gtk+"
170
171PACKAGECONFIG[sdl] = "--enable-sdl,--disable-sdl,libsdl2"
172PACKAGECONFIG[png] = "--enable-png,--disable-png,libpng"
173PACKAGECONFIG[virtfs] = "--enable-virtfs --enable-attr --enable-cap-ng,--disable-virtfs,libcap-ng attr,"
174PACKAGECONFIG[aio] = "--enable-linux-aio,--disable-linux-aio,libaio,"
175PACKAGECONFIG[uring] = "--enable-linux-io-uring,--disable-linux-io-uring,liburing"
176PACKAGECONFIG[xen] = "--enable-xen,--disable-xen,xen-tools,xen-tools-libxenstore xen-tools-libxenctrl xen-tools-libxenguest"
177PACKAGECONFIG[vnc-sasl] = "--enable-vnc --enable-vnc-sasl,--disable-vnc-sasl,cyrus-sasl,"
178PACKAGECONFIG[vnc-jpeg] = "--enable-vnc --enable-vnc-jpeg,--disable-vnc-jpeg,jpeg,"
179PACKAGECONFIG[libcurl] = "--enable-curl,--disable-curl,curl,"
180PACKAGECONFIG[nss] = "--enable-smartcard,--disable-smartcard,nss,"
181PACKAGECONFIG[curses] = "--enable-curses,--disable-curses,ncurses,"
182PACKAGECONFIG[gtk+] = "--enable-gtk,--disable-gtk,gtk+3 gettext-native"
183PACKAGECONFIG[vte] = "--enable-vte,--disable-vte,vte gettext-native"
184PACKAGECONFIG[libcap-ng] = "--enable-cap-ng,--disable-cap-ng,libcap-ng,"
185PACKAGECONFIG[ssh] = "--enable-libssh,--disable-libssh,libssh,"
186PACKAGECONFIG[gcrypt] = "--enable-gcrypt,--disable-gcrypt,libgcrypt,"
187PACKAGECONFIG[nettle] = "--enable-nettle,--disable-nettle,nettle"
188PACKAGECONFIG[libusb] = "--enable-libusb,--disable-libusb,libusb1"
189PACKAGECONFIG[fdt] = "--enable-fdt,--disable-fdt,dtc"
190PACKAGECONFIG[alsa] = "--audio-drv-list=default,,alsa-lib"
191PACKAGECONFIG[epoxy] = "--enable-opengl,--disable-opengl,libepoxy"
192PACKAGECONFIG[lzo] = "--enable-lzo,--disable-lzo,lzo"
193PACKAGECONFIG[numa] = "--enable-numa,--disable-numa,numactl"
194PACKAGECONFIG[gnutls] = "--enable-gnutls,--disable-gnutls,gnutls"
195PACKAGECONFIG[bzip2] = "--enable-bzip2,--disable-bzip2,bzip2"
196PACKAGECONFIG[libiscsi] = "--enable-libiscsi,--disable-libiscsi"
197PACKAGECONFIG[kvm] = "--enable-kvm,--disable-kvm"
198PACKAGECONFIG[virglrenderer] = "--enable-virglrenderer,--disable-virglrenderer,virglrenderer"
199# spice will be in meta-networking layer
200PACKAGECONFIG[spice] = "--enable-spice,--disable-spice,spice"
201# usbredir will be in meta-networking layer
202PACKAGECONFIG[usb-redir] = "--enable-usb-redir,--disable-usb-redir,usbredir"
203PACKAGECONFIG[snappy] = "--enable-snappy,--disable-snappy,snappy"
204PACKAGECONFIG[glusterfs] = "--enable-glusterfs,--disable-glusterfs,glusterfs"
205PACKAGECONFIG[xkbcommon] = "--enable-xkbcommon,--disable-xkbcommon,libxkbcommon"
206PACKAGECONFIG[libudev] = "--enable-libudev,--disable-libudev,eudev"
207PACKAGECONFIG[attr] = "--enable-attr,--disable-attr,attr,"
208PACKAGECONFIG[rbd] = "--enable-rbd,--disable-rbd,ceph,ceph"
209PACKAGECONFIG[vhost] = "--enable-vhost-net,--disable-vhost-net,,"
210PACKAGECONFIG[ust] = "--enable-trace-backend=ust,--enable-trace-backend=nop,lttng-ust,"
211PACKAGECONFIG[pie] = "--enable-pie,--disable-pie,,"
212PACKAGECONFIG[seccomp] = "--enable-seccomp,--disable-seccomp,libseccomp"
213# libnfs is currently provided by meta-kodi
214PACKAGECONFIG[libnfs] = "--enable-libnfs,--disable-libnfs,libnfs"
215PACKAGECONFIG[pmem] = "--enable-libpmem,--disable-libpmem,pmdk"
216PACKAGECONFIG[pulsedio] = "--enable-pa,--disable-pa,pulseaudio"
217PACKAGECONFIG[selinux] = "--enable-selinux,--disable-selinux"
218PACKAGECONFIG[bpf] = "--enable-bpf,--disable-bpf,libbpf"
219PACKAGECONFIG[capstone] = "--enable-capstone,--disable-capstone"
220PACKAGECONFIG[rdma] = "--enable-rdma,--disable-rdma"
221PACKAGECONFIG[vde] = "--enable-vde,--disable-vde"
222PACKAGECONFIG[slirp] = "--enable-slirp,--disable-slirp,libslirp"
223PACKAGECONFIG[brlapi] = "--enable-brlapi,--disable-brlapi"
224PACKAGECONFIG[jack] = "--enable-jack,--disable-jack,jack,"
225
226INSANE_SKIP:${PN} = "arch"
227
228FILES:${PN} += "${datadir}/icons"
229
230# Put the guest agent in a separate package
231PACKAGES =+ "${PN}-guest-agent"
232SUMMARY:${PN}-guest-agent = "QEMU guest agent"
233FILES:${PN}-guest-agent += " \
234    ${bindir}/qemu-ga \
235    ${sysconfdir}/udev/rules.d/60-qemu-guest-agent.rules \
236    ${sysconfdir}/init.d/qemu-guest-agent \
237    ${systemd_unitdir}/system/qemu-guest-agent.service \
238"
239
240INITSCRIPT_PACKAGES = "${PN}-guest-agent"
241INITSCRIPT_NAME:${PN}-guest-agent = "qemu-guest-agent"
242INITSCRIPT_PARAMS:${PN}-guest-agent = "defaults"
243
244SYSTEMD_PACKAGES = "${PN}-guest-agent"
245SYSTEMD_SERVICE:${PN}-guest-agent = "qemu-guest-agent.service"
246