1SUMMARY = "Tools for managing memory technology devices"
2HOMEPAGE = "http://www.linux-mtd.infradead.org/"
3DESCRIPTION = "mtd-utils tool is a generic Linux subsystem for memory devices, especially Flash devices."
4SECTION = "base"
5LICENSE = "GPLv2+"
6LIC_FILES_CHKSUM = "file://COPYING;md5=0636e73ff0215e8d672dc4c32c317bb3 \
7                    file://include/common.h;beginline=1;endline=17;md5=ba05b07912a44ea2bf81ce409380049c"
8
9inherit autotools pkgconfig update-alternatives
10
11DEPENDS = "zlib e2fsprogs util-linux"
12RDEPENDS_mtd-utils-tests += "bash"
13
14PV = "2.1.2"
15
16SRCREV = "7b986779342021bda87c04da3bf729718736d8ab"
17SRC_URI = "git://git.infradead.org/mtd-utils.git \
18           file://add-exclusion-to-mkfs-jffs2-git-2.patch \
19           "
20
21S = "${WORKDIR}/git"
22
23EXTRA_OECONF += "--enable-install-tests"
24
25# xattr support creates an additional compile-time dependency on acl because
26# the sys/acl.h header is needed. libacl is not needed and thus enabling xattr
27# regardless whether acl is enabled or disabled in the distro should be okay.
28PACKAGECONFIG ??= "${@bb.utils.filter('DISTRO_FEATURES', 'xattr', d)} lzo jffs ubifs"
29PACKAGECONFIG[lzo] = "--with-lzo,--without-lzo,lzo"
30PACKAGECONFIG[xattr] = "--with-xattr,--without-xattr,acl"
31PACKAGECONFIG[crypto] = "--with-crypto,--without-crypto,openssl"
32PACKAGECONFIG[jffs] = "--with-jffs,--without-jffs"
33PACKAGECONFIG[ubifs] = "--with-ubifs,--without-ubifs"
34PACKAGECONFIG[zstd] = "--with-zstd,--without-zstd,zstd"
35
36CPPFLAGS_append_riscv64  = " -pthread -D_REENTRANT"
37
38EXTRA_OEMAKE = "'CC=${CC}' 'RANLIB=${RANLIB}' 'AR=${AR}' 'CFLAGS=${CFLAGS} ${@bb.utils.contains('PACKAGECONFIG', 'xattr', '', '-DWITHOUT_XATTR', d)} -I${S}/include' 'BUILDDIR=${S}'"
39
40# Use higher priority than corresponding BusyBox-provided applets
41ALTERNATIVE_PRIORITY = "100"
42
43ALTERNATIVE_${PN} = "flashcp flash_eraseall flash_lock flash_unlock nanddump nandwrite"
44ALTERNATIVE_${PN}-ubifs = "ubiattach ubidetach ubimkvol ubirename ubirmvol ubirsvol ubiupdatevol"
45
46ALTERNATIVE_LINK_NAME[nandwrite] = "${sbindir}/nandwrite"
47ALTERNATIVE_LINK_NAME[nanddump] = "${sbindir}/nanddump"
48ALTERNATIVE_LINK_NAME[ubiattach] = "${sbindir}/ubiattach"
49ALTERNATIVE_LINK_NAME[ubidetach] = "${sbindir}/ubidetach"
50ALTERNATIVE_LINK_NAME[ubimkvol] = "${sbindir}/ubimkvol"
51ALTERNATIVE_LINK_NAME[ubirename] = "${sbindir}/ubirename"
52ALTERNATIVE_LINK_NAME[ubirmvol] = "${sbindir}/ubirmvol"
53ALTERNATIVE_LINK_NAME[ubirsvol] = "${sbindir}/ubirsvol"
54ALTERNATIVE_LINK_NAME[ubiupdatevol] = "${sbindir}/ubiupdatevol"
55ALTERNATIVE_LINK_NAME[flash_eraseall] = "${sbindir}/flash_eraseall"
56ALTERNATIVE_LINK_NAME[flash_lock] = "${sbindir}/flash_lock"
57ALTERNATIVE_LINK_NAME[flash_unlock] = "${sbindir}/flash_unlock"
58ALTERNATIVE_LINK_NAME[flashcp] = "${sbindir}/flashcp"
59
60do_install () {
61	oe_runmake install DESTDIR=${D} SBINDIR=${sbindir} MANDIR=${mandir} INCLUDEDIR=${includedir}
62}
63
64PACKAGES =+ "mtd-utils-misc mtd-utils-tests"
65PACKAGES =+ "${@bb.utils.contains("PACKAGECONFIG", "jffs", "mtd-utils-jffs2", "", d)}"
66PACKAGES =+ "${@bb.utils.contains("PACKAGECONFIG", "ubifs", "mtd-utils-ubifs", "", d)}"
67
68FILES_mtd-utils-jffs2 = "${sbindir}/mkfs.jffs2 ${sbindir}/jffs2dump ${sbindir}/jffs2reader ${sbindir}/sumtool"
69FILES_mtd-utils-ubifs = "${sbindir}/mkfs.ubifs ${sbindir}/ubi*"
70FILES_mtd-utils-misc = "${sbindir}/nftl* ${sbindir}/ftl* ${sbindir}/rfd* ${sbindir}/doc* ${sbindir}/serve_image ${sbindir}/recv_image"
71FILES_mtd-utils-tests = "${libexecdir}/mtd-utils/*"
72
73BBCLASSEXTEND = "native nativesdk"
74
75# git/.compr.c.dep:46: warning: NUL character seen; rest of line ignored
76# git/.compr.c.dep:47: *** missing separator.  Stop.
77PARALLEL_MAKE = ""
78