1# Copyright (c) 2018 Joshua Watt, Garmin International,Inc.
2# Released under the MIT license (see COPYING.MIT for the terms)
3SUMMARY = "Generates Icecream toolchain for SDK"
4DESCRIPTION = "${SUMMARY}"
5LICENSE = "MIT"
6LIC_FILES_CHKSUM = "file://${WORKDIR}/icecc-env.sh;beginline=2;endline=20;md5=dd6b68c1efed8a9fb04e409b3b287d47"
7
8INHIBIT_DEFAULT_DEPS = "1"
9
10SRC_URI = "\
11    file://icecc-env.sh \
12    file://icecc-setup.sh \
13    "
14
15inherit nativesdk
16
17ENV_NAME="${DISTRO}-${TCLIBC}-${SDK_ARCH}-@TARGET_PREFIX@${DISTRO_VERSION}.tar.gz"
18
19do_compile() {
20}
21
22do_install() {
23    install -d ${D}${SDKPATHNATIVE}${datadir}/icecream/bin
24
25    install -d ${D}${SDKPATHNATIVE}/environment-setup.d/
26    install -m 0644 ${WORKDIR}/icecc-env.sh ${D}${SDKPATHNATIVE}/environment-setup.d/
27    sed -i ${D}${SDKPATHNATIVE}/environment-setup.d/icecc-env.sh \
28        -e 's,@TOOLCHAIN_ENV@,${ENV_NAME},g'
29
30    install -d ${D}${SDKPATHNATIVE}/post-relocate-setup.d/
31    install -m 0755 ${WORKDIR}/icecc-setup.sh ${D}${SDKPATHNATIVE}/post-relocate-setup.d/
32    sed -i ${D}${SDKPATHNATIVE}/post-relocate-setup.d/icecc-setup.sh \
33        -e 's,@TOOLCHAIN_ENV@,${ENV_NAME},g'
34}
35
36PACKAGES = "${PN}"
37FILES:${PN} = "${SDKPATHNATIVE}"
38RDEPENDS:${PN} += "nativesdk-icecc-create-env"
39
40