1inherit cross-canadian
2inherit python3-dir
3
4SUMMARY = "GNU debugger (cross-canadian gdb for ${TARGET_ARCH} target)"
5PN = "gdb-cross-canadian-${TRANSLATED_TARGET_ARCH}"
6BPN = "gdb"
7
8DEPENDS = "nativesdk-ncurses nativesdk-expat nativesdk-gettext \
9           virtual/${HOST_PREFIX}gcc-crosssdk virtual/${HOST_PREFIX}binutils-crosssdk virtual/nativesdk-libc"
10
11GDBPROPREFIX = "--program-prefix='${TARGET_PREFIX}'"
12
13# Overrides PACKAGECONFIG variables in gdb-common.inc
14PACKAGECONFIG ??= "python readline ${@bb.utils.filter('DISTRO_FEATURES', 'debuginfod', d)}"
15PACKAGECONFIG[python] = "--with-python=${WORKDIR}/python,--without-python,nativesdk-python3, \
16                         nativesdk-python3-core \
17                         nativesdk-python3-codecs nativesdk-python3-netclient \
18                         "
19PACKAGECONFIG[readline] = "--with-system-readline,--without-system-readline,nativesdk-readline"
20PACKAGECONFIG[debuginfod] = "--with-debuginfod, --without-debuginfod, nativesdk-elfutils"
21
22SSTATE_DUPWHITELIST += "${STAGING_DATADIR}/gdb"
23
24do_configure:prepend() {
25cat > ${WORKDIR}/python << EOF
26#! /bin/sh
27case "\$2" in
28        --includes) echo "-I${STAGING_INCDIR}/${PYTHON_DIR}${PYTHON_ABI}/" ;;
29        --ldflags) echo "-Wl,-rpath-link,${STAGING_LIBDIR}/.. -Wl,-rpath,${libdir}/.. -lpthread -ldl -lutil -lm -lpython${PYTHON_BASEVERSION}${PYTHON_ABI}" ;;
30        --exec-prefix) echo "${exec_prefix}" ;;
31        *) exit 1 ;;
32esac
33exit 0
34EOF
35        chmod +x ${WORKDIR}/python
36}
37
38# we don't want gdb to provide bfd/iberty/opcodes, which instead will override the
39# right bits installed by binutils.
40do_install:append() {
41	rm -rf ${D}${exec_prefix}/lib
42	cross_canadian_bindirlinks
43}
44