1SUMMARY = "XSL stylesheets for processing DocBook XML to various output formats"
2HOMEPAGE = "http://docbook.sourceforge.net"
3LICENSE = "XSL"
4LIC_FILES_CHKSUM = "file://COPYING;md5=6beadd98f9c54ab0c387e14211ee4d0e"
5
6SRC_URI = "${SOURCEFORGE_MIRROR}/docbook/docbook-xsl-${PV}.tar.bz2 \
7           file://docbook-xsl-stylesheets-no-bashism-in-docbook-xsl-up.patch \
8"
9
10SRC_URI[md5sum] = "b48cbf929a2ad85e6672f710777ca7bc"
11SRC_URI[sha256sum] = "725f452e12b296956e8bfb876ccece71eeecdd14b94f667f3ed9091761a4a968"
12
13UPSTREAM_CHECK_URI = "http://sourceforge.net/projects/docbook/files/docbook-xsl/"
14# Reject versions ending in .0 as those are release candidates
15UPSTREAM_CHECK_REGEX = "/docbook-xsl/(?P<pver>(\d+[\.\-_]*)+(?!\.0)\.\d+)/"
16
17S = "${WORKDIR}/docbook-xsl-${PV}"
18
19inherit allarch xmlcatalog
20
21do_configure (){
22	:
23}
24
25do_compile (){
26	:
27}
28
29do_install () {
30	install -v -m755 -d ${D}${datadir}/xml/docbook/xsl-stylesheets-${PV}
31	ln -s xsl-stylesheets-${PV} ${D}${datadir}/xml/docbook/xsl-stylesheets
32
33	cp -v -R VERSION assembly common eclipse epub epub3 fo \
34		highlighting html htmlhelp images javahelp lib manpages \
35		params profiling roundtrip slides template webhelp website \
36		xhtml xhtml-1_1 xhtml5 catalog.xml \
37		${D}${datadir}/xml/docbook/xsl-stylesheets-${PV}
38
39	ln -s VERSION ${D}/${datadir}/xml/docbook/xsl-stylesheets-${PV}/VERSION.xsl
40
41	install -d ${D}${docdir}/${BPN}
42	install -v -m644 README RELEASE-NOTES* NEWS* ${D}${docdir}/${BPN}
43}
44
45RDEPENDS:${PN} += "perl"
46FILES:${PN} = "${datadir}/xml/* ${sysconfdir}/xml/docbook-xsl.xml"
47FILES:${PN}-doc = "${datadir}/doc/*"
48
49XMLCATALOGS = "${datadir}/xml/docbook/xsl-stylesheets-${PV}/catalog.xml"
50
51BBCLASSEXTEND = "native"
52